Question

不确定怎么做这个＆＃39; sum（）＆＃39;函数是在XML页面中添加所有值，而不是由＆＃39; if＆＃39;选择的值。言。

这是XML：

<book>
    <title type="non-fiction">Harry Potter and the Philosophers Stone</title>
    <author>J.K Rowling</author>
    <publisher>Bloomsbury</publisher>
    <year>1997</year>
    <price>12.99</price>
</book>

<book>
    <title type="fiction">The Lord of the Rings</title>
    <author>J. R. R. Tolkien</author>
    <publisher>George Allen and Unwin</publisher>
    <year>1954</year>
    <price>39.99</price>
</book>

<book>
    <title type="non-fiction">The Right Stuff</title>
    <author>Tom Wolfe</author>
    <publisher>Farra, Staus and Giroux</publisher>
    <year>1979</year>
    <price>29.99</price>
</book>

这是XSLT：

  <xsl:output 
method="html" 
indent="yes" 
version="4.0"
doctype-public="-//W3C//DTD HTML 4.01//EN"
doctype-system="http://www.w3.org/TR/html4/strict.dtd"/>

<xsl:template match="/library">
<html>
<body>
    <xsl:for-each select="book">
        <xsl:if test="title[@type='non-fiction']">
            <xsl:if test="price&lt;30" >
                <p class="title"> <xsl:value-of select="title"/></p>
                <p class="author"> <xsl:value-of select="author"/> </p>
                <p class="price"> <xsl:value-of select="price"/> </p>   
            </xsl:if>
        </xsl:if>
    </xsl:for-each>     
</body>

我想添加适用于所有条件的书籍总数。我假设sum函数会这样做，但它会添加所有的书籍，无论它是否通过了＆＃39; if＆＃39;语句。

Answer 1

一种可能性是定义

一个节点集变量，用于保存您要打印的所有书籍，
然后遍历该节点集以打印书籍，
并在最后使用sum函数计算总价格。

E.g。

<body>
    <xsl:variable name="books" select="book[title[@type='non-fiction']][price&lt;30]" />
    <xsl:for-each select="$books">
        <p class="title"> <xsl:value-of select="title"/></p>
        <p class="author"> <xsl:value-of select="author"/> </p>
        <p class="price"> <xsl:value-of select="price"/> </p>   
    </xsl:for-each>     
    <p class="total-price"> <xsl:value-of select="sum($books/price)"/> </p>   
</body>

Answer 2

你可以试试这个：

  <xsl:template match="/library" >
  <html>
  <body>
      <xsl:variable name="fiction_lt30" 
          select="book[title[@type='non-fiction'] and price &lt; 30] " />
      <xsl:for-each select="$fiction_lt30">
        <p class="title"> <xsl:value-of select="title"/></p>
        <p class="author"> <xsl:value-of select="author"/> </p>
        <p class="price"> <xsl:value-of select="price"/> </p>   
      </xsl:for-each>     
        <p>total: <xsl:value-of select="sum($fiction_lt30/price)" /></p>
    </body>
</html>
</xsl:template>

Answer 3

这是一个完整而简短的解决方案：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="/*">
  <xsl:variable name="vBooks" 
                select="book[title[@type='non-fiction'] and not(price >= 30)]"/>
    <html>
     <body>
       <xsl:apply-templates select="$vBooks"/>
       <p><strong>Total Cost:</strong><span><xsl:value-of 
                                                 select="sum($vBooks/price)"/></span></p>
     </body>
    </html>
  </xsl:template>

  <xsl:template match="book/*[self::title or self::author or self::price]">
   <p class="{name()}"> <xsl:value-of select="."/></p>
  </xsl:template>
</xsl:stylesheet>

XSLT在IF语句后添加书籍价格

3 个答案: