Question

我的xml格式如下，

<SAMPLEFORM>
    <SAMPLE ID='1' TYPE='Normal'>
        <DATA>1</DATA>
    </SAMPLE>
    <SAMPLE TYPE='PageSplitter'>
        <DATA>N/A</DATA>
    </SAMPLE>
    <SAMPLE ID='2' TYPE='Normal'>
        <DATA>1</DATA>
    </SAMPLE>
</SAMPLEFORM>

我正在尝试通过定义起始位置将节点拆分为包含属性Type='Normal'的集合。节点集的结束位置将是包含属性Type='PageSplitter'的节点的下一个出现位置。

有没有办法在不经过for-each循环的情况下获取节点的位置？以及如何做到这一点？

Answer 1

您不需要两种标记 - 只需一种：

<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output omit-xml-declaration="yes" indent="yes"/>
    <xsl:strip-space elements="*"/>

    <xsl:key name="kPage" match="SAMPLE[not(@TYPE='Normal')]"
         use="generate-id(preceding-sibling::SAMPLE[@TYPE='Normal'][1])"/>

 <xsl:template match="node()|@*" name="identity">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match="SAMPLE[@TYPE='Normal']">
   <page>
     <xsl:copy-of select=".|key('kPage', generate-id())"/>
   </page>
 </xsl:template>

 <xsl:template match="SAMPLE[not(@TYPE='Normal')]"/>
</xsl:stylesheet>

将此转换应用于以下XML（提供的转换，格式良好，添加了一个元素，并且没有“PAGESPLITTER”）：

<SAMPLEFORM>
    <SAMPLE ID='1' TYPE='Normal'>
        <DATA>1</DATA>
    </SAMPLE>
    <SAMPLE ID='2'>
        <DATA>2</DATA>
    </SAMPLE>
    <SAMPLE ID='3' TYPE='Normal'>
        <DATA>3</DATA>
    </SAMPLE>
</SAMPLEFORM>

产生了想要的正确结果：

<SAMPLEFORM>
    <page>
        <SAMPLE ID="1" TYPE="Normal">
            <DATA>1</DATA>
        </SAMPLE>
        <SAMPLE ID="2">
            <DATA>2</DATA>
        </SAMPLE>
    </page>
    <page>
        <SAMPLE ID="3" TYPE="Normal">
            <DATA>3</DATA>
        </SAMPLE>
    </page>
</SAMPLEFORM>

在XSLT中将节点分解为页面

1 个答案: