Question

我正在学习Prolog，我确实想知道它如何用于真实世界的Web应用程序。在本地主机上一切都很完美，但是我的创作有些麻烦。

要在我遵循本教程的服务器上启动它：http://www.j-paine.org/dobbs/prolog_from_php.html

随着对php的一些更改，我将其改为活着。我的PHP代码：

<html>
<head>
<title>Calling SWI-Prolog from PHP (short)</title>
</head>
<body>
<? 
  $cmd = "swipl -f /path/to/myfile.pl -g test,halt -t 'halt(1)'";

  system( $cmd );
  echo "\n";

  $output = exec( $cmd );
  echo $output;
  echo "\n";
?> 
</body>
</html>

一切正常，结果如下：http://37.139.24.44/index.php

现在，我还有prolog代码，它在我的localhost上启动服务器，帮助：

server(Port) :-
        http_server(http_dispatch, [port(Port)]).

示例代码是：

:- module(upload, [ run/0]).
:- use_module(library(http/thread_httpd)).
:- use_module(library(http/http_dispatch)).
:- use_module(library(http/http_parameters)).
:- use_module(library(http/http_mime_plugin)).
:- use_module(library(http/http_client)).
:- use_module(library(http/html_write)).
:- use_module(library(lists)).

:- http_handler(root(.),    upload_form, []).
:- http_handler(root(upload),   upload,      []).

run :-
    http_server(http_dispatch, [port(8080)]).

upload_form(_Request) :-
    reply_html_page(
        title('Upload a file'),
        [ h1('Upload a file'),
          form([ method('POST'),
             action(location_by_id(upload)),
             enctype('multipart/form-data')
           ],
           table([],
             [ tr([td(input([type(file), name(file)]))]),
               tr([td(align(right),
                  input([type(submit), value('Upload!')]))])
             ]))
        ]).

upload(Request) :-
    (   memberchk(method(post), Request),
        http_read_data(Request, Parts, [form_data(mime)]),
        member(mime(Attributes, Data, []), Parts),
        memberchk(name(file), Attributes),
        memberchk(filename(Target), Attributes)
    ->  % process file here; this demo just prints the info gathered
        atom_length(Data, Len),
        format('Content-type: text/plain~n~n'),
        format('Need to store ~D characters into file \'~w\'~n',
           [ Len, Target ]),
        name(Data,Lis),
        write(Lis)
    ;   throw(http_reply(bad_request(bad_file_upload)))
    ).

:- multifile prolog:message//1.

prolog:message(bad_file_upload) -->
    [ 'A file upload must be submitted as multipart/form-data using', nl,
      'name=file and providing a file-name'
    ].

我想从php中调用这个，在现场服务器上不断运行它，而不需要终端中的任何命令。

我试图将我的php更改为

<? 
$cmd = "swipl -f /path/to/myfile.pl -g run,halt -t 'halt(1)'";
system( $cmd );
$output = exec( $cmd );
echo $output;
echo "\n";
?>

但它只给我一个空白的屏幕。我想这可能是因为我试图在已经存在的服务器上运行服务器？

如果我尝试从php调用其他谓词，它不适用于所需的http库（或者我只是不知道如何正确调用它）。

我不是那么好的系统管理员，所以我确实需要任何建议如何在php的服务器上运行表单。

或者，如果我可以调整它以使其作为服务器上的守护程序工作，只使用SWIPL，这对我来说也可能有用。

感谢。

Answer 1

我认为您的问题是您在生成服务器后立即调用halt/0，因此它甚至没有机会收听单个请求。

根据我的经验，Web服务器的最佳方法是将SWI作为Unix 守护程序运行，这也是您的建议。请参阅library(http/http_unix_daemon)的文档。

使用此库时，您只需运行服务器（例如）：

$ swipl server.pl --user=www --pidfile=/var/run/http.pid

它会不断听取请求并为客户提供服务。

请注意，如果您使用library(http/http_unix_daemon)，则甚至不需要像server/1这样的辅助谓词。所有这些都是隐含处理的。

在开发过程中，我建议您在启动服务器时使用--interactive命令行标志，以便您也可以在顶层与服务器进行交互。

完成后，您可以在系统启动时轻松运行服务器。

从php运行prolog（或使其成为守护进程）

1 个答案: