Question

我有像这样的x xml，

<doc>
<p>ABC Number 132, Decimal 321, AAB Double 983 DEF GHI 432 JKL</p>
</doc>

我的目标是，如果'Number'，'Decimal'，'Double'后跟一个空格（''）后跟一个数字，那么该中间空格值应该被*字符替换。

所以输出应该是，

<doc>
    <p>ABC Number*132, Decimal*321, AAB Double*983 DEF GHI 432 JKL</p>
</doc>

我已经关注了xsl，

<xsl:template match="p">
        <xsl:analyze-string select="text()" regex="(Number/s/d)|(Decimal/s/d)|(Double/s/d)">
            <xsl:matching-substring>
                <xsl:choose>
                    <xsl:when test="regex-group(1)">
                        <xsl:value-of select="'Number*'"/>
                    </xsl:when>
                    <xsl:when test="regex-group(2)">
                        <xsl:value-of select="'Decimal*'"/>
                    </xsl:when>
                    <xsl:when test="regex-group(3)">
                        <xsl:value-of select="'Double*'"/>
                    </xsl:when>
                </xsl:choose>
            </xsl:matching-substring>

            <xsl:non-matching-substring>
                <xsl:value-of select="."/>
            </xsl:non-matching-substring>
        </xsl:analyze-string>
    </xsl:template>

但它没有返回正确的结果..

有任何建议如何修改我的代码以获得正确的输出？

Answer 1

正则表达式中的主要问题是您尝试将空格和数字与/s和/d匹配。

应该是\s和\d。

然而，即使你修好了这个，你仍然会丢失数字，因为你没有抓住它。

您还失去了p元素。

我建议使用更简单的正则表达式并添加xsl:copy以保留p ...

XSLT 2.0

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output indent="yes"/>
  <xsl:strip-space elements="*"/>

  <xsl:template match="@*|node()">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="p">
    <xsl:copy>
      <xsl:analyze-string select="." regex="(Number|Decimal|Double)\s(\d)">
        <xsl:matching-substring>
          <xsl:value-of select="concat(regex-group(1),'*',regex-group(2))"/>
        </xsl:matching-substring>
        <xsl:non-matching-substring>
          <xsl:value-of select="."/>
        </xsl:non-matching-substring>
      </xsl:analyze-string>      
    </xsl:copy>
  </xsl:template>

</xsl:stylesheet>

<强>输出

<doc>
   <p>ABC Number*132, Decimal*321, AAB Double*983 DEF GHI 432 JKL</p>
</doc>

Answer 2

更简单，更短：

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

  <xsl:template match="node()|@*">
    <xsl:copy>
      <xsl:apply-templates select="node()|@*"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="p/text()">
    <xsl:value-of select="replace(., '(Number|Decimal|Double) (\d+)', '$1*$2')"/>
  </xsl:template>
</xsl:stylesheet>

XSLT - 通过使用正则表达式识别模式来替换文本节点

2 个答案: