Question

如何使用recur类似于尾部位置的东西？

看看我的代码：

(defn -main [& args]

  (println "Hi! Type a file name...")

  (defn readFile[])
    (let [fileName(read-line)]
    (let [rdr (reader fileName)]
      (if-not (.exists rdr) 
        ((println "Sorry, this file doesn't exists. Type a valid file name...")
         (recur)))
         (defn list '())
         (doseq [line (line-seq rdr)]
           (if-not (= "" line)
             (concat list '(line)))
             (list))))

(defn fileLinesList (readFile))
  ...
  ...)

我知道我不能在这里使用recur ......但我不知道怎样才能在clojure中使用它。

我是Clojure的新手，我来自OOP环境。所以......

在这种情况下有没有办法使用递归？ 什么是替代方案？

Answer 1

首先，您不应将函数定义嵌套在另一个defn中（在本例中为-main）。 defn或def始终在命名空间的顶层定义符号绑定，并且它们不会嵌套。如果要定义本地范围的函数，则需要使用let和fn，例如

(let [my-fn (fn [a b] (+ a b))]
  (my-fn 1 2))

在您的特定情况下，我认为将代码拆分为多个功能会更容易。这样它会更具可读性。

提示输入文件名是你逻辑的一部分。

(defn get-existing-filename []
  (let [filename (read-line)]
    (if (.exists (java.io.File. filename))
      filename
      (do
        (println "Sorry, this file doesn't exists. Type a valid file name...")
        (recur)))))

然后你可以用它来读取删除空行的文件：

(with-open [input (clojure.java.io/reader (get-existing-filename))]
  (->> (line-seq input)
       (remove empty?)
       (doall)))

对于包含以下内容的文件：

AAA

BBB
CCC

DDD

它会返回

("AAA" "BBB" "CCC" "DDD")

如果您真的希望它作为单一功能，以下内容将起作用：

(defn read-file []
  (let [filename (read-line)]
    (if (.exists (java.io.File. filename))
      (with-open [input (clojure.java.io/reader (get-existing-filename))]
        (->> (line-seq input)
             (remove empty?)
             (doall)))
      (do
        (println "Sorry, this file doesn't exists. Type a valid file name...")
        (recur)))))

最后，可以从-main调用此函数。

我还注意到示例代码中的另一个问题：

((println "Sorry, this file doesn't exists. Type a valid file name...")
 (recur))

if和if-not需要then和else分支的单个表达式。如果您想要多个表达式，则需要将它们嵌套在do：

中

(do
  (println "Sorry, this file doesn't exists. Type a valid file name...")
  (recur))

如果您需要if或if-not而没有其他分支，则可以使用when或when-not宏。然后你不需要包装多个表达式，因为when / when-not会将它们包装在do的内部。

(when true
  (println 1)
  (println 2))

相当于

(if true
  (do
    (println 1)
    (println 2)))

不在尾部位置

1 个答案: