Question

我正在使用Atmel ARM核心处理器使用Atmel Studio提供的GCC工具编写嵌入式系统应用程序。我正在使用的生产编程设备可以在编程期间将序列号写入指定的ROM位置，这很好，因为它是一个自动化过程，避免了人为错误的可能性。

我想在我的二进制文件中留出空间，以确保给定地址始终可用于此目的，并且还可以使我的应用程序可以从Flash读取其序列号。

我已经查看了其他一些关于SO的问题，例如this one看起来与我的问题非常相似，但似乎忽略了答案的关键细节，因为我无法重现结果。

为我的处理器提供的链接描述文件如下：

OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
OUTPUT_ARCH(arm)
SEARCH_DIR(.)

/* Memory Spaces Definitions */
MEMORY
{
  rom (rx)  : ORIGIN = 0x00400000, LENGTH = 0x00800000
  ram (rwx) : ORIGIN = 0x20000000, LENGTH = 0x00020000
}

/* The stack size used by the application. NOTE: you need to adjust according to your application. */
__stack_size__ = DEFINED(__stack_size__) ? __stack_size__ : 0x3000;
__ram_end__ = ORIGIN(ram) + LENGTH(ram) - 4;

SECTIONS
{
    .text :
    {
        . = ALIGN(4);
        _sfixed = .;
        KEEP(*(.vectors .vectors.*))
        *(.text .text.* .gnu.linkonce.t.*)
        *(.glue_7t) *(.glue_7)
        *(.rodata .rodata* .gnu.linkonce.r.*)
        *(.ARM.extab* .gnu.linkonce.armextab.*)

        /* Support C constructors, and C destructors in both user code
           and the C library. This also provides support for C++ code. */
        . = ALIGN(4);
        KEEP(*(.init))
        . = ALIGN(4);
        __preinit_array_start = .;
        KEEP (*(.preinit_array))
        __preinit_array_end = .;

        . = ALIGN(4);
        __init_array_start = .;
        KEEP (*(SORT(.init_array.*)))
        KEEP (*(.init_array))
        __init_array_end = .;

        . = ALIGN(0x4);
        KEEP (*crtbegin.o(.ctors))
        KEEP (*(EXCLUDE_FILE (*crtend.o) .ctors))
        KEEP (*(SORT(.ctors.*)))
        KEEP (*crtend.o(.ctors))

        . = ALIGN(4);
        KEEP(*(.fini))

        . = ALIGN(4);
        __fini_array_start = .;
        KEEP (*(.fini_array))
        KEEP (*(SORT(.fini_array.*)))
        __fini_array_end = .;

        KEEP (*crtbegin.o(.dtors))
        KEEP (*(EXCLUDE_FILE (*crtend.o) .dtors))
        KEEP (*(SORT(.dtors.*)))
        KEEP (*crtend.o(.dtors))

        . = ALIGN(4);
        _efixed = .;            /* End of text section */
    } > rom

    /* .ARM.exidx is sorted, so has to go in its own output section.  */
    PROVIDE_HIDDEN (__exidx_start = .);
    .ARM.exidx :
    {
      *(.ARM.exidx* .gnu.linkonce.armexidx.*)
    } > rom
    PROVIDE_HIDDEN (__exidx_end = .);

    . = ALIGN(4);
    _etext = .;

    .relocate : AT (_etext)
    {
        . = ALIGN(4);
        _srelocate = .;
        *(.ramfunc .ramfunc.*);
        *(.data .data.*);
        . = ALIGN(4);
        _erelocate = .;
    } > ram

    /* .bss section which is used for uninitialized data */
    .bss (NOLOAD) :
    {
        . = ALIGN(4);
        _sbss = . ;
        _szero = .;
        *(.bss .bss.*)
        *(COMMON)
        . = ALIGN(4);
        _ebss = . ;
        _ezero = .;
    } > ram

    /* stack section */
    .stack (NOLOAD):
    {
        . = ALIGN(8);
        _sstack = .;
        . = . + __stack_size__;
        . = ALIGN(8);
        _estack = .;
    } > ram

    . = ALIGN(4);
    _end = . ;
}

此脚本无问题。我试图添加一小段内存来将序列号存储在Flash中，但总是最终让链接器很乐意将数据存储在指定的rom区域之外。

我尝试将代码添加到链接描述文件中，如下所示：

/* .ARM.exidx is sorted, so has to go in its own output section.  */
PROVIDE_HIDDEN (__exidx_start = .);
.ARM.exidx :
{
  *(.ARM.exidx* .gnu.linkonce.armexidx.*)
} > rom
PROVIDE_HIDDEN (__exidx_end = .);

/**** START ADDED CODE ****/    
_metastart = 0x47FF00;
.metadata :
{
    . = _metastart;
    *(.metadata)  
} > rom
/**** END ADDED CODE ****/

. = ALIGN(4);
_etext = .;

.relocate : AT (_etext)
{

和我的main.cpp一样：

static uint8_t nvSerial[4] __attribute__((used,section(".metadata"))) = { 0xDE, 0xAD, 0xBE, 0xEF };

但最终会得到一个巨大的二进制文件，其数据远高于0x00480000且低于0x200000000。我还尝试按如下方式编写链接器脚本添加（在与上面相同的位置）：

_metastart = 0x47FF00;
.metadata : AT(_metastart)
{
    *(.metadata)  
} > rom

但是我的序列号似乎完全被遗漏了（即0x47FF00处没有任何内容）。同样，如果我像这样设置链接器文件，则无法找到数据：

MEMORY
{
  rom (rx)  : ORIGIN = 0x00400000, LENGTH = 0x0007FF00
  meta (rx) : ORIGIN = 0x0047FF00, LENGTH = 0x00000100 /** ADDED **/
  ram (rwx) : ORIGIN = 0x20000000, LENGTH = 0x00020000
}
/** snip **/
.metadata :
{
    *(.metadata)  
} > meta

任何人都可以提出任何关于我做错的建议吗？

修改

所以＆＃34;解决方案＆＃34;问题是改变我的链接器以使用KEEP命令来描述metadata部分更新_etext之后的部分。如果我描述metadata之前_etext被分配，那么链接器由于某种原因在metadata之后存储一堆常量数据并进入未定义的内存区域。新链接器文件的相关部分如下：

OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
OUTPUT_ARCH(arm)
SEARCH_DIR(.)

/* Memory Spaces Definitions */
MEMORY
{
  rom (rx)  : ORIGIN = 0x00400000, LENGTH = 0x0007FF00
  meta (rx) : ORIGIN = 0x0047FF00, LENGTH = 0x00000100
  ram (rwx) : ORIGIN = 0x20000000, LENGTH = 0x00020000
}

/** snip **/

. = ALIGN(4);
_etext = .;

.metadata :
{
    KEEP(*(.metadata))
} > meta

.relocate : AT (_etext)
{
    . = ALIGN(4);
    _srelocate = .;
    *(.ramfunc .ramfunc.*);
    *(.data .data.*);
    . = ALIGN(4);
    _erelocate = .;
} > ram

所以这有效但我现在的问题是什么呢？

特定地址

0 个答案: