Question

我是Perl的新手，我有一段代码可以给我一个空的文件处理程序。

my $md5dir = "...plib/test/md5sum";    #IN MY PROG, IS THE FULL PATH
opendir( DIR, $md5dir ) or die "Can't open directory $md5dir: $!";
my @md5files = grep !/^\.\.?$/, readdir(DIR);
closedir(DIR);

if (  scalar @md5files < 1
   || scalar @md5files > 8
   || ( scalar @md5files % 2 != 0 ) )
{
   print "Incorrect amount of files in directory. Aborting.\n";
   exit 1;
}
else {
   for ( my $i = 0; ( $i < scalar @md5files / 2 ); $i++ ) {
      my $file1 = $md5files[$i];
      open( my $fh1, $file1 ) or die "Fail to open file $file1 $!";
      my $file2 = $md5files[ $i + 3 ];
      open( my $fh2, $file2 ) or die "Fail to open file $file2 $!";
      print "2.", $file1, " ", $file2, "\n";
      my $first1 = substr( $file1, 0, 4 );
      my $first2 = substr( $file2, 0, 4 );
      if ( ( $first1 cmp $first2 ) == 0 ) {
         if   ( eof $fh1 ) { print "No lines\n"; }
         else              { my $line1 = <$fh1>; print "$line1\n"; }
         if   ( eof $fh2 ) { print "No lines2\n"; }
         else              { my $line2 = <$fh2>; print "$line2\n"; }
         close $fh1;
         close $fh2;
      }
   }    # for
}    # else

输出是这样的：

2.SAM5_27-04-2016_11:21:20.md5 SAM5_27-04-2016_11:20:11.md5
No lines
No lines2
2.SAM6_27-04-2016_11:18:25.md5 SAM6_25-04-2016_10:38:38.md5
No lines
No lines2
2.SAM4_27-04-2016_11:19:06.md5 SAM4_27-04-2016_11:17:22.md5
No lines
No lines2

在md5sum的目录中：

:md5sum>ls -la
total 16
drwxrwxr-x   2 ateam    ateam       4096 Apr 27 11:24 ./
drwxrwxr-x   4 ateam    ateam       4096 Apr 27 11:24 ../
-rw-rw-r--   1 ateam    ateam         63 Apr 27 11:17 SAM4_27-04-2016_11:17:22.md5
-rw-rw-r--   1 ateam    ateam         63 Apr 27 11:19 SAM4_27-04 2016_11:19:06.md5
-rw-rw-r--   1 ateam    ateam         63 Apr 27 11:20 SAM5_27-04-2016_11:20:11.md5
-rw-rw-r--   1 ateam    ateam          0 Apr 27 11:21 SAM5_27-04-2016_11:21:20.md5
-rw-rw-r--   1 ateam    ateam         63 Apr 25 10:38 SAM6_25-04-2016_10:38:38.md5
-rw-rw-r--   1 ateam    ateam         63 Apr 27 11:18 SAM6_27-04-2016_11:18:25.md5

有人可以解释为什么文件处理程序空了吗？我验证了文件的打印。它们都打印到数组中并且文件处理程序正在打开......由于文件不是空的，还有什么可能是错的？（除了那个......以外的所有......）

只是为了查看文件......以防万一。打开我得到的第一个文件：

03c0cf2ab0da62832bfc6970d4505746  SAM4_27-04-2016_11:17:22.csv

EDIT ::: 我对文件稍作调整：

if (($first1 cmp $first2) == 0) {
            if (tell($fh1) == -1){ print "No lines\n";}
            else {my $line1= <$fh1>;  print "$line1\n"; }
            if (eof $fh2){ print "No lines2\n";}
            else { my $line2= <$fh2>; print "$line2\n"; }
            close $fh1;                     close $fh2;
}

而是得到了这个输出：

2.SAM5_27-04-2016_11:21:20.md5 SAM5_27-04-2016_11:20:11.md5
Use of uninitialized value in concatenation (.) or string at mulftptest line 53.

No lines2
2.SAM6_27-04-2016_11:18:25.md5 SAM6_25-04-2016_10:38:38.md5
Use of uninitialized value in concatenation (.) or string at mulftptest line 53.

No lines2
2.SAM4_27-04-2016_11:19:06.md5 SAM4_27-04-2016_11:17:22.md5
Use of uninitialized value in concatenation (.) or string at mulftptest line 53.

No lines2

基本上，我知道这告诉我，我试图使用＆＃34;空＆＃34;变量。但是，我不明白为什么它是空的。

Answer 1

主要问题是readdir仅返回文件名，没有任何路径信息

这意味着您在当前工作目录中打开SAM5_27-04-2016_11:21:20.md5，而不是在md5sum目录中打开。通常你的开放调用会失败，但似乎你的脚本目录中有相同名称的虚假空文件

如果你写这样的公开电话，那么它应该适合你

open my $fh1, '<', "$md5dir/$file1" or die "Fail to open file $file1: $!";

并且不要将tell用于此目的。无论文件是否为空，它都会在开始时返回零。你真的希望-s $fh1以字节为单位返回文件的大小，并且可以在文件名或打开的文件句柄上使用

Answer 2

我最好的猜测是你需要这样的东西。我很确定你有一个包含MD5校验和的文件目录，并想要比较它们

我已经通过这些方式使这更直接了

我在程序的顶部有use autodie。这是一个检查大多数Perl IO操作的编译指示，可以帮助您验证每个open调用是否成功。它被引入v5.10.1的核心perl并且是可靠的
我为MD5文件目录添加了use constant
我使用glob代替opendir / readdir来查找md5sum目录中以.md5结尾的所有文件。 glob永远不会返回伪目录.和..，但如果某人有些奇怪，xx.md5总是有可能成为目录。您可能需要添加支票

有一个循环来构建一个与每个＆＃34;前缀相关的散列＆＃34; （前缀是第一个下划线之前的文件名中的所有字符）到具有该前缀的每个文件

检查该哈希以确保每个前缀的目录中都有文件。这似乎与原始支票保持一致

现在有一个哈希将每个前缀与两个文件相关联，问题似乎已经解决了。我的代码显示每个前缀以及它们包含的两个文件的名称和MD5字符串

use strict;
use warnings 'all';
use autodie;

use constant MD5_DIR => '...plib/test/md5sum';    #IN YOUR PROG, IS THE FULL PATH
chdir MD5_DIR;

my %files;

# Build a hash of files collected by prefix
#
for my $file ( glob '*.md5' ) {
    next unless my ($prefix) = $file =~ / ^ ( [^_]+ ) /x;
    push @{ $files{$prefix} }, $file;
}


# Check that there are exactly two files with each prefix
#
{
    my $errors;

    while ( my ($prefix, $files) = each %files ) {

        my $n = @$files;

        if ( @$files != 2 ) {
            warn qq{$n files fouhd for prefix "${prefix}_"\n};
            ++$errors;
        }
    }

    die "Dying because errors found in source directory" if $errors;
}

# Display every pair of files by prefix
#
while ( my ($prefix, $files) = each %files ) {

    my ($file1, $file2) = sort @$files;

    print "Prefix: $prefix\n";

    for my $file ( sort @$files ) {
        open my $fh, '<', $file;
        my $md5 = <$fh>;
        $md5 =~ s/\s+\z//;
        print "    File: $file\n";
        print "        MD5: $md5\n";
    }
}

为什么我的文件处理程序是空的？ PERL

2 个答案: