Question

我想在Pharo中实现一个小班，所以我已经这样做了：

Object subclass: #Person
    instanceVariableNames: 'name age'
    classVariableNames: ''
    category: 'Test'

我想模拟一个构造函数，所以我创建了一个类似如下的方法：

newName:aName newAge:aAge
    "comment stating purpose of message"

    name:=aName.
    age:=aAge.
    ^self.

但是当我想在Pharo的操场上打电话时，就像这样：

objPerson:=Person newName:'Carl' newAge: 10.

Pharo不承认它，我做错了什么？

Answer 1

表达式Person newName: 'Carl' newAge: 10是类对象Person的消息。因此，您必须在Person的类侧实现它。

您的代码需要像这样调整

Person class >> newName: aName newAge: anAge
  | person |
  person := self new.
  person name: aName.
  person age: anAge.
  ^person

请注意，在上面的代码中self引用了类，因为该方法位于类的一侧。但由于person是Person的实例，因此必须在实例端定义消息name: aName和age: anAge。

因此，在实例端，您需要添加两个setter：

Person >> name: aString
  name := aString

Person >> age: anInteger
  age := anInteger

使用这三种方法，您应该可以运行您的示例。

关于编码风格的一些补充意见：

首先，我会为“构造函数”方法选择一个不同的选择器（在Smalltalk中我们称之为“实例创建”方法）。例如，

Person class >> named: aString age: anInteger
  ^self new name: aString; age: anInteger

其次，没有必要对新创建的实例使用临时person，因为表达式self new已经引用了这样的实例。

最后，请注意

中使用级联语法

^self new name: aString; age: anInteger

这意味着消息age: anInteger将被发送到name: aString的同一接收者，在这种情况下恰好是self new返回的新实例。

Answer 2

虽然总的来说我同意Leandro的回答，但会暴露私有财产的访问者。

Kent Beck在他的 Smalltalk最佳实践模式（我强烈推荐）中，建议使用set作为实例端构造函数的前缀，例如：

"add to class side to 'instance creation' protocol"
Person>>class name: aName age: anAge
    ^ self new
        setName: aName age: anAge;
        yourself

"add to instance side to 'initialization' protocol"
Person>>setName: aName age: anAge
    name := aName.
    age := anAge.

通过这种方式，您可以控制是否要公开属性。

或者您可以坚持使用原始命名，只需添加new即可。

objPerson := Person new newName:'Carl' newAge: 10.

在Pharo或Smalltalk中制作构造函数

2 个答案: