Question

所以我有一个问题。我有一个ASP.NET Webforms应用程序。我使用SMO进行一些简单的复制到另一个数据库。整个例程通过我的本地IIS完美运行。我在整个声明中都有一个Try Catch。它返回错误：目录＆＃39; LocalApplicationData＆＃39;不存在。

任何人都可以帮我吗？我已遍历谷歌但无法找到任何内容（我读https://social.technet.microsoft.com/Forums/systemcenter/en-US/34fd1bce-e9a3-40bc-8d18-f80fe4ec7aaf/localapplicationdata-does-not-exist?forum=sqlsmoanddmo但需要更好的解释）。

我的代码：

Imports System.Data.SqlClient
Imports System.Runtime.InteropServices
Imports System.Security.Principal
Imports Microsoft.SqlServer.Management.Smo
Public Class betatolive

Inherits System.Web.UI.Page

Public Shadows User As clsUser = New clsUser(Me.Page)

Private Sub betatolive_Load(sender As Object, e As System.EventArgs) Handles Me.Load
    If User.Data.fUserLevel < 98 Then Response.Redirect("~/Admin/")
End Sub

Private Sub lnkTransferData_Click(ByVal sender As Object, ByVal e As System.EventArgs)
    Dim feedback As String = "Transfer successful."

    Try

        Dim dbSrcServer = New Server("123.192.4.567,1337")
        With dbSrcServer.ConnectionContext
            .LoginSecure = False
            .Login = "username"
            .Password = "password"
            .Connect()
        End With

        Dim dbSource As Database = dbSrcServer.Databases("dTransferSource")
        Dim dbDest As Database = dbSrcServer.Databases("dTransferDest")

        Dim dbTransfer As New Transfer(dbSource)

        For Each t As Table In dbSource.Tables
            If Not t.Name.Contains("OBSOLETE") And Not t.Name = "name" Then
                dbTransfer.ObjectList.Add(t)
            End If
        Next

        Dim dropDestTables As New List(Of Table)

        For Each t As Table In dbDest.Tables
            If Not t.Name = "name1" And Not t.Name = "name2" And Not t.Name = "name3" Then
                dropDestTables.Add(t)
            End If
        Next

        For Each t As Table In dropDestTables
            dbDest.Tables(t.Name).Drop()
        Next

        Dim transferOpts As New ScriptingOption
        With transferOpts
            .ClusteredIndexes = True
            .Default = True
            .FullTextIndexes = True
            .Indexes = True
            .NonClusteredIndexes = True
        End With

        With dbTransfer
            .CopySchema = True
            .CopyData = True
            .CopyAllObjects = False
            .CopyAllTables = False
            .Options = transferOpts
            .DestinationServer = dbSrcServer.Name
            .DestinationDatabase = dbVaDest.Name
            .DestinationLoginSecure = False
            .DestinationLogin = "username"
            .DestinationPassword = "password"
        End With

        dbTransfer.TransferData()

    Catch ex As Exception
        feedback = String.Format("Please do not attempt the transfer again until further notice. <br /> Transfer Error: " & ex.InnerException.Message())
    End Try

    lnkTransferData.Text = feedback
    lnkTransferData.Enabled = False
End Sub

End Class

Answer 1

固定。

With dbTransfer
    .CopySchema = True
    .CopyData = True
    .CopyAllObjects = False
    .CopyAllTables = False
    .Options = transferOpts
    .TemporaryPackageDirectory = Server.MapPath("~/dbtemp")   ' This is the fix, had to create a temp folder and set that property to the path
    .DestinationServer = dbSrcServer.Name
    .DestinationDatabase = dbVaDest.Name
    .DestinationLoginSecure = False
    .DestinationLogin = "username"
    .DestinationPassword = "password"
End With

@jmcilhinney - 仅供参考，我做了你所说的，它返回一个空白字符串，这使我想到可能需要设置它，所以我检查了引用并发现了上面的财产。

感谢您的意见，我没有想到按照您的建议行事，这导致我解决了这个问题。

目录＆＃39; LocalApplicationData＆＃39;不存在。 - SQL SMO ASP.NET复制数据库

1 个答案: