Question

我有一个XML，类似这样：

<?xml version="1.0" encoding="UTF-8"?>
       <earth>
     <computer>
             <parts>;;remove;;This should stay;;remove too;;This stay;;yeah also remove;;this stay </parts>

       </computer>
    </earth>

我想创建一个XSLT 2.0转换来删除以;;开头和结尾的所有文本

<?xml version="1.0" encoding="utf-8"?>
<earth>
     <computer>
            <parts>This should stay This stay this stay </parts>
      </computer>

    </earth>

尝试做这样的事情，但没有运气：

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="2.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:fn="http://www.w3.org/2005/xpath-functions"
    exclude-result-prefixes="fn">
    <xsl:output encoding="utf-8" method="xml" indent="yes" />
    <xsl:template match="@* | node()">
        <xsl:copy>
            <xsl:apply-templates select="@* | node()" />
        </xsl:copy>
    </xsl:template>

    <xsl:template match="parts">
  <xsl:element name="parts" >
                <xsl:value-of  select="replace(., ';;.*;;','')" />
            </xsl:element>
    </xsl:template>
</xsl:stylesheet>

Answer 1

哇，这是一种愚蠢的标记文字方式。您可以使用XML，为什么不使用它？即使以这种方式标记，为什么不使用不同的符号来打开和关闭标记的部分？

无论如何，我相信这会返回预期的结果：

XSLT 2.0

<xsl:stylesheet version="2.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="parts">
    <xsl:copy>
        <xsl:value-of select="replace(., ';;.+?;;', '')" />
    </xsl:copy>
</xsl:template>

</xsl:stylesheet>

Answer 2

XSLT 1.0

对于这种事我会使用递归。只需使用字符串替换，您就可以获得某个字符（或一组字符）之前和之后的内容。您需要做的就是不断循环遍历字符串，直到不再出现替换字符，如下所示：

<xsl:template name="string-remove-between">
    <xsl:param name="text" />
    <xsl:param name="remove" />

    <xsl:choose>
        <xsl:when test="contains($text, $remove)">
            <xsl:value-of select="substring-before($text,$remove)" />
            <xsl:call-template name="string-remove-between">
                <xsl:with-param name="text" select="substring-after(substring-after($text,$remove), $remove)" />
                <xsl:with-param name="remove" select="$remove" />
            </xsl:call-template>
        </xsl:when>
        <xsl:otherwise>
            <xsl:value-of select="$text"/>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

然后，您只需使用您的文字和要删除的部分调用模板：

<xsl:call-template name="string-remove-between">
    <xsl:with-param name="text" select="parts"/>
    <xsl:with-param name="remove">;;</xsl:with-param>
</xsl:call-template>

请注意，有两个子串后调用，这可以确保我们获得替换字符的第二个实例';;'所以我们不介意之间的文字。

Answer 3

另一种方法是对＃34 ;;;＆＃34;进行标记化。作为分隔符，然后删除所有偶数编号的标记：

<xsl:template match="parts">
  <parts>
   <xsl:value-of select="tokenize(.,';;')[position() mod 2 = 1]"
     separator=""/>
  </parts>
</xsl:template>

XSLT正则表达式删除序列文本

3 个答案: