Question

我想将时间戳从localtime转换为GMT。我有遗留代码，可以使用Time::Local::timelocal()和gmtime“手动”执行此操作。它有效，但我不喜欢它，并希望使用Time::Piece代替。我使用this answer来执行此操作（尽管他们正在进行相反的转换，但我能够将+替换为-： - ））。

这是我的代码：

#!/usr/bin/env perl

use strict;
use warnings;
use Time::Local;
use Time::Piece;
use POSIX qw(strftime);

sub local_to_utc_timelocal
{
    my $local_ts = shift;
    my ( $year, $mon, $mday, $hour, $min, $sec ) 
        = ( $local_ts =~ /(\d\d)-(\d\d)-(\d\d) (\d\d):(\d\d):(\d\d)/ );
    my $local_secs = Time::Local::timelocal( $sec, $min, $hour, $mday, $mon - 1, $year );
    return POSIX::strftime( '%y-%m-%d %H:%M:%S', gmtime($local_secs) );
}

sub local_to_utc_timepiece
{
    my $local_ts = shift;
    my $local_tp = Time::Piece->strptime( $local_ts, '%y-%m-%d %H:%M:%S' );
    my $utc_tp   = $local_tp - localtime->tzoffset(); # ***
    return $utc_tp->strftime('%y-%m-%d %H:%M:%S');
}

my $local;

# DST in effect (April 19 2016):
$local = '16-04-19 14:30:00';
print "DST in effect:\n";
printf("utc(%s) = %s (using timelocal)\n", $local, local_to_utc_timelocal($local));
printf("utc(%s) = %s (using timepiece)\n\n", $local, local_to_utc_timepiece($local));

# DST NOT in effect (Feb 19 2016):
$local = '16-02-19 14:30:00';
print "DST NOT in effect:\n";
printf("utc(%s) = %s (using timelocal)\n", $local, local_to_utc_timelocal($local));
printf("utc(%s) = %s (using timepiece)\n", $local, local_to_utc_timepiece($local));

不幸的是，Time :: Piece代码似乎无法正常使用DST。我住在德国，所以目前（春/夏，DST有效）我们是UTC + 2。对于“2016年4月19日”，上述代码给出：

DST in effect:
utc(16-04-19 14:30:00) = 16-04-19 12:30:00 (using timelocal)
utc(16-04-19 14:30:00) = 16-04-19 12:30:00 (using timepiece)

这是正确的。但对于“2016年2月19日”（当我们是UTC + 1时），相同的代码给出了：

DST NOT in effect:
utc(16-02-19 14:30:00) = 16-02-19 13:30:00 (using timelocal)
utc(16-02-19 14:30:00) = 16-02-19 12:30:00 (using timepiece)

即：gmtime(Time::Local::timelocal($timestamp))提供正确的1小时偏移，而Time::Piece仍提供2小时偏移。

这是Time::Piece中的错误还是错误使用？

我知道有很多方法可以将localtime转换为UTC，但由于其简单性，我想使用Time::Piece。另外，我不能使用DateTime，因为这将涉及在十几台生产机器上部署它。

Answer 1

问题1

localtime现在返回，因此localtime->tzoffset()现在返回偏移量。变化

my $utc_tp = $local_tp - localtime->tzoffset();

到

my $utc_tp = $local_tp - $local_tp->tzoffset();

但是，这会将$utc_tp标记为本地时间，因此您真的需要：

my $utc_tp = gmtime( $local_tp->epoch );

问题2

尽管名称$local_tp不是本地时间，但$local_tp->tzoffset()为零。变化

Time::Piece->strptime( $local_ts, '%y-%m-%d %H:%M:%S' )

到

localtime->strptime( $local_ts, '%y-%m-%d %H:%M:%S' );

如何在将本地时间转换为UTC时使Time :: Piece尊重DST？

1 个答案:

问题1

问题2