Question

我想控制插槽中保存值的方式以及读取插槽时返回的内容。这是我的班级定义：

(defclass object ()
  ((name :accessor name-access
         :initform 'noname
         :initarg :name)
   (value :accessor value-access
      :initform 10
      :initarg :value)))

我以这种方式创建对象：

(setf obj1 (make-instance 'object))

这就是我获取广告位name的价值的方式：

(name-access obj1)

我如何设置新值：

(setf (name-access obj1) 'realname)

为了能够对对象（写入时）进行一些更改并控制返回的值，有什么方法可以覆盖此访问器函数（或方法）？

谢谢。

Answer 1

您可以手动定义获取和设置插槽的方法：

(defclass foo ()
  ((name :initform 'noname
         :initarg :name)))

(defgeneric name-access (foo)
  (:method ((foo foo))
    (format t "~&Getting name.~%")
    (slot-value foo 'name)))

(defgeneric (setf name-access) (name foo)
  (:method (name (foo foo))
    (format t "~&Setting a new name.~%")
    (setf (slot-value foo 'name) name)))

(defparameter *foo* (make-instance 'foo))
(name-access *foo*)
; Getting name.
;=> NONAME

(setf (name-access *foo*) 'some-name)
; Setting a new name.
;=> SOME-NAME

(name-access *foo*)
; Getting name.
;=> SOME-NAME

本书Practical Common Lisp在chapter 17中介绍了这些内容。你应该读一下。

Answer 2

您可以扩展DEFCLASS：

定义的访问者方法

CL-USER 66 > (defclass object ()
               ((name :accessor name-access
                      :initform 'noname
                      :initarg :name)
                (value :accessor value-access
                       :initform 10
                       :initarg :value)))
#<STANDARD-CLASS OBJECT 4220014953>

使用:before方法写作：

CL-USER 67 > (defmethod (setf name-access) :before (new-value (o1 object))
               (print "hi"))
#<STANDARD-METHOD (SETF NAME-ACCESS) (:BEFORE) (T OBJECT) 40202283BB>

使用:around方法阅读：

CL-USER 68 > (defmethod name-access :around ((o1 object))
               (let ((name (call-next-method)))
                 (values name (length (symbol-name name)))))
#<STANDARD-METHOD NAME-ACCESS (:AROUND) (OBJECT) 4020061213>

示例：

CL-USER 69 > (let ((o1 (make-instance 'object)))
               (setf (name-access o1) 'foobar)
               (name-access o1))

"hi"     ; side effect
FOOBAR   ; return value 1
6        ; return value 2

Common Lisp：如何覆盖插槽访问器？

2 个答案: