Question

在使用MinGW，C ++ 11，Qt 5和qmake的Windows下我有以下项目结构：

/my-project
   my-project.pro
   /my-app
      my-app.pro
      main.cpp
   /module-a
      module-a.pro
      modulea.h
      modulea.cpp
   /module-b
      module-b.pro
      moduleb.h
      moduleb.cpp

模块之间的依赖关系应如下所示：

my-app ==> module-a ==> module-b

我想要实现的是my-app使用module-a，module-a使用module-b而my-app对module-b一无所知。模块-a仅通过其实现引用模块-b（模块-b的#include位于模块-a的.cpp中。

我尝试通过在qmake中将module-a和module-b配置为静态库来实现此目的。不幸的是，在编译时我收到链接器错误，说明了对ModuleB的未定义引用:: doSmthB（）＆＃39;

我理解这个链接问题的原因，我的问题是，是否有可能实现类似于提议的分层结构的东西？

来源：

my-project.pro：

TEMPLATE = subdirs
SUBDIRS += module-b
SUBDIRS += module-a
SUBDIRS += my-app
my-app.depends = module-a
module-a.depends = module-b

my-app.pro：

QT += widgets
TARGET = my-app
TEMPLATE = app
CONFIG += c++11
SOURCES += *.cpp
win32 {
    INCLUDEPATH += $$clean_path($$PWD/../module-a)
    DEPENDPATH += $$clean_path($$PWD/../module-a)
    LIBS += $$clean_path($$OUT_PWD/../module-a/debug/libmodule-a.a)
    PRE_TARGETDEPS += $$clean_path($$OUT_PWD/../module-a/debug/libmodule-a.a)
}

main.cpp中：

#include <QApplication>
#include <QGraphicsView>
#include <QGraphicsScene>

#include "modulea.h"

int main(int argc, char *args[])
{
    QApplication app(argc, args);
    QGraphicsView view;
    QGraphicsScene *scene = new QGraphicsScene(0, 0, 300, 300, &view);
    ModuleA moduleA;
    scene->addText(QString::number(moduleA.doSmthA())); // undefined reference to ModuleB::doSmthB()
    view.setScene(scene);
    view.show();
    return app.exec();
}

module-a.pro：

QT -= core gui
TARGET = module-a
TEMPLATE = lib
CONFIG += staticlib
CONFIG += c++11
HEADERS += *.h
SOURCES += *.cpp
win32 {
    INCLUDEPATH += $$clean_path($$PWD/../module-b)
    DEPENDPATH += $$clean_path($$PWD/../module-b)
    LIBS += $$clean_path($$OUT_PWD/../module-b/debug/libmodule-b.a)
    PRE_TARGETDEPS += $$clean_path($$OUT_PWD/../module-b/debug/libmodule-b.a)
}

modulea.h：

#ifndef MODULEA_H
#define MODULEA_H

struct ModuleA
{
    int doSmthA();
};

#endif // MODULEA_H

modulea.cpp：

#include "modulea.h"
#include "moduleb.h"

int ModuleA::doSmthA() {
    ModuleB other;
    return other.doSmthB();
}

module-b.pro：

QT -= core gui
TARGET = module-b
TEMPLATE = lib
CONFIG += staticlib
CONFIG += c++11
HEADERS += *.h
SOURCES += *.cpp

moduleb.h：

#ifndef MODULEB_H
#define MODULEB_H

struct ModuleB
{
    int doSmthB();
};

#endif // MODULEB_H

moduleb.cpp：

#include "moduleb.h"

int ModuleB::doSmthB() {
    return 12345;
}

Answer 1

要修改我的示例，需要进行以下更改：

1）将CONFIG += create_prl添加到所有应用程序直接依赖项的.pro文件中（在我的情况下为module-a）。修改这样的所有模块都不会受到伤害。

这里的解释： http://doc.qt.io/qt-5/qmake-advanced-usage.html#library-dependencies

2）在主.pro（在我的示例中为my-project.pro）app（SUBDIRS += my-app）的子目录声明必须放在app的直接依赖项之后（SUBDIRS += module-a之后））。

我在此处找到第二点的提示：https://stackoverflow.com/a/1417859/6223445

3）必须使用LIBS和-L选项（至少在Windows下）定义-l属性，例如而不是：

LIBS += $$clean_path($$OUT_PWD/../module-a/debug/libmodule-a.a)

使用以下内容：

LIBS += -L$$clean_path($$OUT_PWD/../module-a/debug/) -lmodule-a

固定解决方案如下所示（仅限修改过的文件）：

my-project.pro：

TEMPLATE = subdirs
SUBDIRS += module-b
SUBDIRS += module-a
SUBDIRS += my-app
my-app.depends = module-a
module-a.depends = module-b

my-app.pro：

QT += widgets
TARGET = my-app
TEMPLATE = app
CONFIG += c++11
SOURCES += *.cpp
win32 {
    INCLUDEPATH += $$clean_path($$PWD/../module-a)
    DEPENDPATH += $$clean_path($$PWD/../module-a)
    LIBS += -L$$clean_path($$OUT_PWD/../module-a/debug/) -lmodule-a
    PRE_TARGETDEPS += $$clean_path($$OUT_PWD/../module-a/debug/libmodule-a.a)
}

module-a.pro：

QT -= core gui
TARGET = module-a
TEMPLATE = lib
CONFIG += staticlib
CONFIG += c++11
CONFIG += create_prl
HEADERS += *.h
SOURCES += *.cpp
win32 {
    INCLUDEPATH += $$clean_path($$PWD/../module-b)
    DEPENDPATH += $$clean_path($$PWD/../module-b)
    LIBS += -L$$clean_path($$OUT_PWD/../module-b/debug/) -lmodule-b
    PRE_TARGETDEPS += $$clean_path($$OUT_PWD/../module-b/debug/libmodule-b.a)
}

如何使用qmake在c ++中创建分层项目结构

1 个答案: