Question

所以这是想法，我试图从Cmd中获取一个变量，例如IPv4，并能够在新窗口中ping它。

通过运行命令并获取该命令的特定部分并能够在新命令行中将其作为新的vairable输入以便它可以执行操作，逻辑是什么。

另一个例子：

查找计算机名称。
将命令运行到计算机名称末尾的数字。

我目前正在下载Visual Basics软件，因为它看起来可能是我可能需要的语言，但很困惑。

有没有人对我可以使用的内容有任何基本想法或有这方面的例子？

Answer 1

你可以尝试这样的事情：

@Echo off
Color 0A & Mode con cols=80 lines=15
Title How to grab IPv4
::**********************************
::Method1
::**********************************
echo( 
echo Method 1 with arp -a
echo( 
For /f "tokens=2 delims= " %%a in ('arp -a ^|findstr /i "Interface"') do (set IP=%%a)
Echo The Local IPv4 adress is : %IP%
pause
Cls
Call:PingHost %IP%
pause
::**********************************
::Method2
::**********************************
cls
echo( 
echo Method 2 with ipconfig
for /f "tokens=1-2 delims=:" %%a in ('ipconfig^|find "IPv4"') do (
  set ip=%%b
)
set ip=%ip:~1%
echo( 
echo The Local IPv4 adress is : %ip%
pause
Cls
Call:PingHost %IP%
pause
::**********************************
::Method3 by Stephan
::**********************************
cls
echo( 
echo Method 3 with %%computername%% = %computername%
for /f "tokens=2 delims=[]" %%i in ('ping -4 -n 1 %computername%') do set ip=%%i
echo( 
echo The Local IPv4 adress is : %ip%
pause
Cls
Call:PingHost %IP%
Pause
exit
::**********************************
:Pinghost
Start "%1" Ping %1
exit /b
::**********************************

如何在CMD中获取IPV4变量并在新的CMD窗口中获取Ping

1 个答案: