在c中使用GNU automake中的解析器

时间：2016-04-15 05:53:37

标签： c yacc lex autotools automake

我是GNU autotools的新手，在我的项目中使用lex和yacc解析器。将它们作为makefile.am中的源生成以下错误：

configure.in： 

...
AC_CHECK_PROGS(YACC,bison yacc,none)
if test "x$YACC" = "xbison"; then
    YACC="$YACC -y"
fi

AC_CHECK_PROGS(LEX,flex,none)
...

makefile.am： 

## $Id
AUTOMAKE_OPTIONS=foreign no-dependencies
include $(srcdir)/Makefile_defs

dynamicpreprocessordir = ${libdir}/snort_dynamicpreprocessor

dynamicpreprocessor_LTLIBRARIES = libsf_appid_preproc.la


libsf_appid_preproc_la_LDFLAGS = -export-dynamic -module @XCCFLAGS@
if SO_WITH_STATIC_LIB
libsf_appid_preproc_la_LIBADD = ../libsf_dynamic_preproc.la 


../libsf_dynamic_utils.la $(LUA_LIBS)
else
nodist_libsf_appid_preproc_la_SOURCES = \
../include/sf_dynamic_preproc_lib.c \
../include/sf_ip.c \
../include/sfPolicyUserData.c \
../include/sfxhash.c \
../include/sfghash.c \
../include/sflsq.c \
../include/sfhashfcn.c \
../include/sfmemcap.c \
../include/sfprimetable.c

libsf_appid_preproc_la_LIBADD = $(LUA_LIBS)
endif

libsf_appid_preproc_la_CFLAGS = -DDYNAMIC_PREPROC_CONTEXT -DSTATIC=static $(LUA_CFLAGS)

libsf_appid_preproc_la_SOURCES = $(APPID_SOURCES)

all-local: $(LTLIBRARIES)
    $(MAKE) DESTDIR=`pwd`/../build install-dynamicpreprocessorLTLIBRARIES

在Makefile_defs中：

APPID_SRC_DIR = ${top_srcdir}/src/dynamic-preprocessors/appid
...
APPID_SOURCES =  \
$(APPID_SRC_DIR)/vfml/fc45.lex  \
$(APPID_SRC_DIR)/vfml/fc45.y \
...

当我运行程序时，我收到以下错误：

libsf_appid_preproc.so: undefined symbol: FC45SetFile

FC45SetFile（）已在fc45.lex文件中定义。

fc45.lex： 

%{
#include "fc45.tab.h"
//#include "vfml.h"
#include <string.h>
#include <stdlib.h>

  /* HERE  doesn't match strings starting with numbers other than 0 right */

char string_buf[4000]; /* BUG - maybe check for strings that are too long? */
char *string_buf_ptr;

void FC45FinishString(void);

extern int gLineNumber;
%}

%x str_rule

%%
<str_rule,INITIAL>\|[^\n]* ;

[\ \t\r]+ ;
\n      gLineNumber++;

\. { return '.';}
, { return ',';}
: { return ':';}

ignore { return tIgnore; }
continuous { return tContinuous; }
discrete { return tDiscrete; }


[^:?,\t\n\r\|\.\\\ ] string_buf_ptr = string_buf; unput(yytext[0]); BEGIN(str_rule);

<str_rule>[:,?]             FC45FinishString(); unput(yytext[0]); return tString;
<str_rule>\.[\t\r\ ]    FC45FinishString(); unput(yytext[1]); unput(yytext[0]); return tString;
<str_rule>\.\n    FC45FinishString(); unput(yytext[1]); unput(yytext[0]); return tString; gLineNumber++;

<str_rule><<EOF>> {
   int len = strlen(string_buf);
   //   printf("eof rule.\n");
   if(len == 1 && string_buf[0] == '.') {
     //printf("   period at end of file\n");
      return '.';
   } else if(string_buf[len - 1] == '.') {
     // printf("   period: %s - unput .\n", string_buf);

      FC45FinishString(); unput('.'); return tString;
   } else {
     // printf("   no-period: %s\n", string_buf);
      FC45FinishString(); return tString;
   }
}

<str_rule>\\:   *string_buf_ptr++ = ':';
<str_rule>\\\?  *string_buf_ptr++ = '?';
<str_rule>\\,   *string_buf_ptr++ = ',';
<str_rule>\\.    *string_buf_ptr++ = '.';

<str_rule>\n  *string_buf_ptr++ = ' '; gLineNumber++;
<str_rule>[ \t\r]+  *string_buf_ptr++ = ' ';

<str_rule>[^:?,\t\n\r\|\.\\\ ]+        {
   char *yptr = yytext;

   while(*yptr) {
      *string_buf_ptr++ = *yptr++;
   }
}


%%
int fc45wrap(void) {
    return 1;
}

void FC45SetFile(FILE *file) {
    fc45in = file;
    yyrestart(fc45in);
}

void FC45FinishString(void) {
   int len;
   char *tmpStr;

   BEGIN(INITIAL);
   *string_buf_ptr = '\0';

   len = strlen(string_buf);

   /* remove any ending spaces */
   while(string_buf[len - 1] == ' ') {
     string_buf[len - 1] = '\0';
     len--;
   }

   tmpStr = MNewPtr(len + 1);
   strncpy(tmpStr, string_buf, len + 1);
   fc45lval.string = tmpStr;
   string_buf[0] = '\0';
}

fc45.y： 

%{
#include <stdio.h>
#include <stdlib.h>
#include <malloc.h>
#include "ExampleSpec1.h"
//#include "AttributeTracker.c"
//#include "vfml.h"
%}

%{
int fc45lex(void);
int fc45error(const char *);

/* HERE figure out how to give better error messages */
/* BUG needs a \n at the end of the names file */

/* These tmps are allocated at the begining of parsing and then
    used during parsing.  For example, so that we can simply
    add terrains to an area while parsing.  After parsing a
    statement, the associated tmp is added to the appropriate
    global list, and a new tmp is allocated.  Finally, at the
    end of parsing, all the tmps are freed
*/

ExampleSpecPtr        exampleSpec;
AttributeSpecPtr      attributeSpec;
int gLineNumber;

%}

%union {
   int integer;
   float f;
   char *string;
}

%token <integer> tInteger
%token <string>  tString

%token tIgnore tContinuous tDiscrete tEOF

%%

ExampleSpec: ClassList '.' AttributeList;

ClassList: ClassList ',' ClassSpec | ClassSpec /* ending */;

ClassSpec: tString { ExampleSpecAddClass(exampleSpec, $1); };

AttributeList: AttributeList AttributeSpec | /* ending */;

AttributeSpec: tString ':' AttributeInfo '.' { 
   AttributeSpecSetName(attributeSpec, $1);
   ExampleSpecAddAttributeSpec(exampleSpec, attributeSpec);
   attributeSpec = AttributeSpecNew();
};

AttributeInfo: tIgnore {
                   AttributeSpecSetType(attributeSpec, asIgnore);} |
               tContinuous {
                   AttributeSpecSetType(attributeSpec, asContinuous);} |
               tDiscrete tString {
                   AttributeSpecSetType(attributeSpec, asDiscreteNoName);
                   AttributeSpecSetNumValues(attributeSpec, atoi($2)); } |
               AttributeValueNameList { 
         AttributeSpecSetType(attributeSpec, asDiscreteNamed); };

AttributeValueNameList: AttributeValueNameList ',' tString {
   AttributeSpecSetNumValues(attributeSpec,
                     AttributeSpecGetNumValues(attributeSpec) + 1);
   AttributeSpecAddValue(attributeSpec, $3); } |
tString {
   AttributeSpecSetNumValues(attributeSpec,
                     AttributeSpecGetNumValues(attributeSpec) + 1);
   AttributeSpecAddValue(attributeSpec, $1); };

%%

void FC45SetFile(FILE *file);

int fc45error(const char *msg) {
   fprintf(stderr, "%s line %d\n", msg, gLineNumber);
   return 0;
}

ExampleSpecPtr ParseFC45(const char *file) {
   FILE *input;

   input = fopen(file, "r");
   if(input == 0) {
      return 0;
   }

   FC45SetFile(input);

   exampleSpec = ExampleSpecNew();
   attributeSpec = AttributeSpecNew();

   gLineNumber = 0;

   if(fc45parse()) {
      /* parse failed! */
      fprintf(stderr, "Error in parsing: %s\n", file);
   }

   fclose(input);

   /* free the left over attribute spec */
   AttributeSpecFree(attributeSpec);

   return exampleSpec;
}

我已经在互联网上寻找解决方案而无法想出任何解决方案。 希望有人认识到这个问题并快速解决问题。任何帮助将不胜感激。

2 个答案:

答案 0 :(得分：2)

问题是make和automake都不知道有关非标准.lex文件扩展名的任何内容，所以当你有一个以.lex结尾的源文件时，他们不知道该怎么做用它。您可以创建处理.lex的规则，但是使用.l文件扩展名重命名文件可能要容易得多，他们知道如何处理。

答案 1 :(得分：1)

我刚刚浏览了a simple example，添加了以下Autotools文件：

<强> configure.ac ：

AC_PREREQ([2.69])
AC_INIT([example], [0.1a], [example@example.com])
AC_CONFIG_SRCDIR([ex1.l])

# Used only to shorten the otherwise lengthy compilation line in the output below.
AC_CONFIG_HEADERS([config.h])

AM_INIT_AUTOMAKE([foreign])

# I used C instead of C++.
AC_PROG_CC
AM_PROG_LEX
AC_PROG_YACC

AC_CONFIG_FILES([Makefile])
AC_OUTPUT

Makefile.am （几乎直接来自the Automake manual）：

BUILT_SOURCES = ex1.h
AM_YFLAGS = -d
bin_PROGRAMS = ex1
ex1_SOURCES = ex1.l ex1.y

事实证明，您无法使用相同的基本文件名命名文件。就我而言，我有 ex1.l 和 ex1.y 。当我调用ex1_SOURCES = ex1.l ex1.y时，使用make会产生以下输出：

make[1]: Entering directory '/home/kit/ex1'
/bin/bash ./ylwrap ex1.l lex.yy.c ex1.c -- flex  
make[1]: Leaving directory '/home/kit/ex1'
make  all-am
make[1]: Entering directory '/home/kit/ex1'
gcc -DHAVE_CONFIG_H=1 -I. -g -O2 -MT ex1.o -MD -MP -MF .deps/ex1.Tpo -c -o ex1.o ex1.c
ex1.l:5:17: fatal error: ex1.h: No such file or directory
 #include "ex1.h"
                 ^
compilation terminated.
Makefile:378: recipe for target 'ex1.o' failed
make[1]: *** [ex1.o] Error 1
make[1]: Leaving directory '/home/kit/ex1'
Makefile:281: recipe for target 'all' failed
make: *** [all] Error 2

请注意，在第二行调用了flex，但bison / yacc没有调用。原因是什么？好吧，ylwrap脚本是原因：

ex1.c: ex1.l
ex1.c: ex1.y

因为脚本重命名ex1.l的输出来自＆＃34; lex.yy.c＆＃34;对于＆＃34; ex1.c＆＃34;，makefile认为ex1.c已经构建好了，所以它不会对bison / yacc文件做任何事情，这意味着ex1.h isn＆t; t建造了。

您无法禁用ylwrap脚本，但您可以解决此问题：只需重命名您的Flex源文件，并将Makefile.in和configure.ac文件中对文件名的引用更改为必要。您不应该重命名您的bison / yacc源文件，因为这意味着每个C文件中的每个#include "fc45.h"都会更改为#include "fc45_g.h"（或者您重命名为文件的任何内容）以及您的flex源文件。

相关问题
最新问题