如何使用Delphi读取文本文件中的最后一行

Question

我需要读取一些非常大的文本文件中的最后一行（从数据中获取时间戳）。 TStringlist是一个简单的方法，但它返回一个内存不足的错误。我试图使用seek和blockread，但缓冲区中的字符都是无意义的。这与unicode有关吗？

$(document).ready(function () {
    $('.service-info').hide();
    $('.read-more').click(function () {
        $(this).siblings('.service-info').slideDown('slow');
        $(this).hide();
        $(this).parent().find('.read-less').show();
    })
    $('.read-less').click(function () {
        $(this).siblings('.service-info').slideUp('slow');
        $(this).hide();
        $(this).parent().find('.read-more').show();
    })
});

基于www.delphipages.com/forum/showthread.php?t=102965

testfile是我在excel中创建的简单CSV（这不是我最终需要阅读的100MB）。

    Function TForm1.ReadLastLine2(FileName: String): String;
    var
      FileHandle: File;
      s,line: string;
      ok: 0..1;
      Buf: array[1..8] of Char;
      k: longword;
      i,ReadCount: integer;
    begin
      AssignFile (FileHandle,FileName);
      Reset (FileHandle);           // or for binary files: Reset (FileHandle,1);
      ok := 0;
      k := FileSize (FileHandle);
      Seek (FileHandle, k-1);
      s := '';
      while ok<>1 do begin
        BlockRead (FileHandle, buf, SizeOf(Buf)-1, ReadCount);  //BlockRead ( var FileHandle : File; var Buffer; RecordCount : Integer {; var RecordsRead : Integer} ) ;
        if ord (buf[1]) <>13 then         //Arg to integer
          s := s + buf[1]
        else
          ok := ok + 1;
        k := k-1;
        seek (FileHandle,k);
      end;
      CloseFile (FileHandle);

      // Reverse the order in the line read
      setlength (line,length(s));
      for i:=1 to length(s) do
        line[length(s) - i+1 ] := s[i];
      Result := Line;
    end;

Answer 1

你真的必须从LARGE块中读取文件从尾部到头部。 因为它太大而不适合内存 - 然后从头到尾逐行读取它会非常慢。使用ReadLn - 两次缓慢。

您还必须准备好最后一行可能以EOL结束，或者可能不结束。

我个人也会考虑三种可能的EOL序列：

• CR / LF又名＃13＃10 = ^ M ^ J - DOS / Windows风格
• 没有LF的CR - 只是＃13 = ^ M - 经典MacOS文件
• 没有CR的LF - 只是＃10 = ^ J - UNIX风格，包括MacOS版本10

如果您确定您的CSV文件只能由本机Windows程序生成，则可以安全地假设使用完整的CR / LF。但如果可以有其他Java程序，非Windows平台，移动程序 - 我会不太确定。当然，没有LF的纯CR将是最不可能的情况。

uses System.IOUtils, System.Math, System.Classes;

type FileChar = AnsiChar; FileString = AnsiString; // for non-Unicode files
// type FileChar = WideChar; FileString = UnicodeString;// for UTF16 and UCS-2 files
const FileCharSize = SizeOf(FileChar);
// somewhere later in the code add: Assert(FileCharSize = SizeOf(FileString[1]);

function ReadLastLine(const FileName: String): FileString; overload; forward;

const PageSize = 4*1024; 
// the minimal read atom of most modern HDD and the memory allocation atom of Win32
// since the chances your file would have lines longer than 4Kb are very small - I would not increase it to several atoms.

function ReadLastLine(const Lines: TStringDynArray): FileString; overload;
var i: integer;
begin
  Result := '';
  i := High(Lines);
  if i < Low(Lines) then exit; // empty array - empty file

  Result := Lines[i];
  if Result > '' then exit; // we got the line

  Dec(i); // skip the empty ghost line, in case last line was CRLF-terminated
  if i < Low(Lines) then exit; // that ghost was the only line in the empty file
  Result := Lines[i];
end;

// scan for EOLs in not-yet-scanned part
function FindLastLine(buffer: TArray<FileChar>; const OldRead : Integer; 
     const LastChunk: Boolean; out Line: FileString): boolean;
var i, tailCRLF: integer; c: FileChar;
begin
  Result := False;
  if Length(Buffer) = 0 then exit;

  i := High(Buffer);    
  tailCRLF := 0; // test for trailing CR/LF
  if Buffer[i] = ^J then begin // LF - single, or after CR
     Dec(i);
     Inc(tailCRLF);
  end;
  if (i >= Low(Buffer)) and (Buffer[i] = ^M) then begin // CR, alone or before LF
     Inc(tailCRLF);
  end;

  i := High(Buffer) - Max(OldRead, tailCRLF);
  if i - Low(Buffer) < 0 then exit; // no new data to read - results would be like before

  if OldRead > 0 then Inc(i); // the CR/LF pair could be sliced between new and previous buffer - so need to start a bit earlier

  for i := i downto Low(Buffer) do begin
      c := Buffer[i];
      if (c=^J) or (c=^M) then begin // found EOL
         SetString( Line, @Buffer[i+1], High(Buffer) - tailCRLF - i);
         exit(True); 
      end;
  end;  

  // we did not find non-terminating EOL in the buffer (except maybe trailing),
  // now we should ask for more file content, if there is still left any
  // or take the entire file (without trailing EOL if any)

  if LastChunk then begin
     SetString( Line, @Buffer[ Low(Buffer) ], Length(Buffer) - tailCRLF);
     Result := true;
  end;
end;


function ReadLastLine(const FileName: String): FileString; overload;
var Buffer, tmp: TArray<FileChar>; 
    // dynamic arrays - eases memory management and protect from stack corruption
    FS: TFileStream; FSize, NewPos: Int64; 
    OldRead, NewLen : Integer; EndOfFile: boolean;
begin
  Result := '';
  FS := TFile.OpenRead(FileName);
  try
    FSize := FS.Size;
    if FSize <= PageSize then begin // small file, we can be lazy!
       FreeAndNil(FS);  // free the handle and avoid double-free in finally
       Result := ReadLastLine( TFile.ReadAllLines( FileName, TEncoding.ANSI )); 
          // or TEncoding.UTF16
          // warning - TFIle is not share-aware, if the file is being written to by another app
       exit;
    end;

    SetLength( Buffer, PageSize div FileCharSize);
    OldRead := 0;
    repeat
      NewPos := FSize - Length(Buffer)*FileCharSize;
      EndOfFile := NewPos <= 0;
      if NewPos < 0 then NewPos := 0; 
      FS.Position := NewPos;

      FS.ReadBuffer( Buffer[Low(Buffer)], (Length(Buffer) - OldRead)*FileCharSize);

      if FindLastLine(Buffer, OldRead, EndOfFile, Result) then 
         exit; // done !

      tmp := Buffer; Buffer := nil; // flip-flop: preparing to broaden our mouth

      OldRead := Length(tmp); // need not to re-scan the tail again and again when expanding our scanning range
      NewLen := Min( 2*Length(tmp), FSize div FileCharSize );

      SetLength(Buffer, NewLen); // this may trigger EOutOfMemory...
      Move( tmp[Low(tmp)], Buffer[High(Buffer)-OldRead+1], OldRead*FileCharSize);
      tmp := nil; // free old buffer
    until EndOfFile;
  finally
    FS.Free;
  end;
end;

PS。注意一个额外的特殊情况 - 如果你使用Unicode字符（两个字节的）并且会给出奇数长度的文件（3个字节，5个字节等） - 你将永远无法扫描起始的单个字节（半宽字节） ）。也许你应该在那里添加额外的警卫，比如Assert( 0 = FS.Size mod FileCharSize)

PPS。根据经验，你最好将这些功能保留在表单类之外，因为为什么混合使用它们？通常，您应该将问题分成小块。读取文件与用户交互没有任何关系 - 因此最好将其卸载到额外的UNIT中。然后，您可以在主线程或多线程应用程序中以一种形式或10种形式使用该单元中的函数。像乐高零件一样 - 它们通过小而独立的方式为您提供灵活性。

PPPS。这里的另一种方法是使用内存映射文件。谷歌为Delphi的MMF实施和关于MMF方法的好处和问题的文章。就个人而言，我认为重写上面的代码来使用MMF会大大简化它，删除几个＆＃34;特殊情况＆＃34;以及麻烦和记忆复制的触发器。 OTOH它会要求你对指针算术非常严格。

• https://en.wikipedia.org/wiki/Memory-mapped_file
• https://msdn.microsoft.com/en-us/library/ms810613.aspx
• http://torry.net/quicksearchd.php?String=memory+map&Title=No

Answer 2

您的char类型是两个字节，因此缓冲区是16字节。然后使用blockread将sizeof（缓冲区）-1字节读入其中，如果它等于＃13，则检查前2个字节的字符。

sizeof（缓冲区）-1是狡猾的（-1来自哪里？），其余的是有效的，但前提是你的输入文件是utf16。

您每次只读取8个（或16个）字符，但只比较一个，然后再次搜索。这也不是很合乎逻辑。

如果您的编码不是utf16，我建议您将缓冲区元素的类型更改为 ansichar 并删除-1

Answer 3

想到了一个新的解决方案。

同样，可能会有更好的，但这个是我想到的最好的。

function GetLastLine(textFilePath: string): string;
var
  list: tstringlist;
begin
  list := tstringlist.Create;
  try
    list.LoadFromFile(textFilePath);
    result := list[list.Count-1];
  finally
     list.free;
  end;
end;

Answer 4

为了回应kopiks的建议，我想出了如何使用TFilestream，它可以使用简单的测试文件，但是当我在各种csv文件上使用它时可能会有一些进一步的调整。此外，我并未声称这是最有效的方法。

    procedure TForm1.Button6Click(Sender: TObject);
    Var
      StreamSize, ApproxNumRows : Integer;
      TempStr : String;
    begin
      if OpenDialog1.Execute then begin
        TempStr := ReadLastLineOfTextFile(OpenDialog1.FileName,StreamSize, ApproxNumRows);
    //    TempStr := ReadFileStream('c:\temp\CSVTestFile.csv');
        ShowMessage ('approximately '+ IntToStr(ApproxNumRows)+' Rows');
        ListBox1.Items.Add(TempStr);
      end;
    end;

      Function TForm1.ReadLastLineOfTextFile(const FileName: String; var StreamSize, ApproxNumRows : Integer): String;
        const
          MAXLINELENGTH = 256;
        var
          Stream: TFileStream;
          BlockSize,CharCount : integer;
          Hash13Found : Boolean;
          Buffer : array [0..MAXLINELENGTH] of AnsiChar;
        begin
          Hash13Found := False;
          Result :='';
          Stream      := TFileStream.Create(FileName, fmOpenRead or fmShareDenyWrite);
          StreamSize := Stream.size;

          if StreamSize < MAXLINELENGTH then
            BlockSize := StreamSize
          Else
            BlockSize := MAXLINELENGTH;

        //  for CharCount := 0 to Length(Buffer)-1 do begin
        //    Buffer[CharCount] := #0;                         // zeroing the buffer can aid diagnostics
        //  end;

          CharCount := 0;
          Repeat
            Stream.Seek(-(CharCount+3), 2);         //+3 misses out the #0,#10,#13 at the end of the file
            Stream.Read( Buffer[CharCount], 1);
            Result := String(Buffer[CharCount]) + result;
            if Buffer[CharCount] =#13 then
              Hash13Found := True;
            Inc(CharCount);
          Until Hash13Found OR (CharCount = BlockSize);

          ShowMessage(Result);
          ApproxNumRows := Round(StreamSize / CharCount);
        end;