Question

起点是类似

的XML列表

<attributes>
        <para role="tocmain1"/>
        <para role="tocmain1"/>
        <other style="fix"/>
        <other style="fix"/>
        <para role="tocmain2"/>
        <para role="tocmain2"/>
        <para role="tocmain2"/>
        <para role="tocmain3"/>
        <para role="tocmain3"/>
        <para language="de"/>
        <para language="de"/>
        <para role="tocmain3"/>
</attributes>

我想将每个元素+属性+值实例的出现次数减少到一次。

像这样：

<attributes>
     <other style="fix"/>
     <para language="de"/>
     <para role="tocmain1"/>
     <para role="tocmain2"/>
     <para role="tocmain3"/>    
</attributes>`

到目前为止，我只是按字母顺序排序。到目前为止，我所有减少名单的努力都是徒劳无功。

这就是我现在所拥有的：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0">
<xsl:template match="/">
    <attributes>
        <xsl:for-each select="attributes/node()">               
            <xsl:sort select="name()" order="ascending"/>           
            <xsl:sort select="@*" order="ascending"/>                   
            <xsl:choose> 
                <xsl:when test="name() = name(preceding::*[1]) and self::node()/@* = preceding::*/@*"/> 
                <xsl:otherwise>
                    <xsl:copy-of select="."/>
                </xsl:otherwise>
            </xsl:choose>
        </xsl:for-each> 
    </attributes>
</xsl:template>
</xsl:stylesheet>

Answer 1

您还可以将xsl:for-each-group和xsl:apply-templates用于组中的第一个节点。这样可以轻松添加将来可能需要进行的任何其他转换。

XML输入（已修改以显示正确的排序）

<attributes>
    <para role="tocmain3"/>
    <para role="tocmain2"/>
    <para role="tocmain1"/>
    <para role="tocmain3"/>
    <para role="tocmain1"/>
    <para role="tocmain2"/>
    <para role="tocmain1"/>
    <para role="tocmain1"/>
    <para role="tocmain2"/>
    <para role="tocmain3"/>
    <para role="tocmain2"/>
    <para role="tocmain2"/>
    <para role="tocmain2"/>
    <para role="tocmain3"/>
    <para role="tocmain2"/>
    <para role="tocmain3"/>
    <para role="tocmain2"/>
    <para role="tocmain3"/>
    <para role="tocmain2"/>
    <para role="tocmain3"/>
</attributes>

XSLT 2.0

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output indent="yes"/>
  <xsl:strip-space elements="*"/>

  <xsl:template match="@*|node()">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="/*">
    <xsl:copy>
      <xsl:apply-templates select="@*"/>
      <xsl:for-each-group select="*" group-by="@role">
        <xsl:sort select="@role"/>
        <xsl:apply-templates select="current-group()[1]"/>
      </xsl:for-each-group>
    </xsl:copy>
  </xsl:template>

</xsl:stylesheet>

XML输出

<attributes>
   <para role="tocmain1"/>
   <para role="tocmain2"/>
   <para role="tocmain3"/>
</attributes>

Answer 2

您的XSLT会生成您所请求的XML模数格式问题，可以使用xsl:output和xsl:strip-space解决这些问题。此外，您可以利用distinct-values()来简化代码：

您的XML输入文档

<attributes>
  <para role="tocmain1"/>
  <para role="tocmain1"/>
  <para role="tocmain1"/>
  <para role="tocmain1"/>
  <para role="tocmain2"/>
  <para role="tocmain2"/>
  <para role="tocmain2"/>
  <para role="tocmain2"/>
  <para role="tocmain2"/>
  <para role="tocmain3"/>
  <para role="tocmain3"/>
  <para role="tocmain3"/>
</attributes>

给予这个简化的XSLT，

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                version="2.0">
  <xsl:output method="xml" indent="yes"/>
  <xsl:strip-space elements="*"/>

  <xsl:template match="/attributes">
    <attributes>
      <xsl:for-each select="distinct-values(para/@role)">
        <xsl:sort select="." order="ascending"/>
        <para role="{.}"/>
      </xsl:for-each> 
    </attributes>
  </xsl:template>
</xsl:stylesheet>

将生成此XML输出文档

<?xml version="1.0" encoding="UTF-8"?>
<attributes>
   <para role="tocmain1"/>
   <para role="tocmain2"/>
   <para role="tocmain3"/>
</attributes>

根据要求

。

Answer 3

好的，根据Daniel Haley的提议，我找到了一个适用于我的问题的答案。

我现在一个接一个地使用两个xsl：

XSL，它提供了一个没有重复的无序列表

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output indent="yes"/>
    <xsl:strip-space elements="*"/>       
    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
     </xsl:template>      
     <xsl:template match="/*">
         <xsl:copy>
            <xsl:apply-templates select="@*"/>
            <xsl:for-each-group select="*" group-by="@*">
                <xsl:sort select="@*"/>
                <xsl:apply-templates select="current-group()[1]"/>
            </xsl:for-each-group>
        </xsl:copy>
    </xsl:template>       
</xsl:stylesheet>

订购列表的XSL：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
version="2.0">
    <xsl:output indent="yes"/>
    <xsl:strip-space elements="*"/>
    <xsl:template match="/">
        <attributes>
            <xsl:for-each select="attributes/node()">                 
                <xsl:sort select="name()" order="ascending"/> 
                <xsl:sort select="name(@*)" order="ascending"/>                   
                <xsl:sort select="@*" order="ascending"/>                  
                <xsl:copy-of select="."/>                  
            </xsl:for-each>   
        </attributes>
    </xsl:template>           
</xsl:stylesheet>

按要求提供结果：

<attributes>
    <other style="fix"/>
    <para language="de"/>
    <para role="tocmain1"/>
    <para role="tocmain2"/>
    <para role="tocmain3"/>    
</attributes>

感谢您帮助我找到答案并抱歉误导了XML示例！如果有人知道如何将这两个步骤合并为一个脚本：欢迎您！

排序列表并消除XSLT中的重复项？

3 个答案: