Question

我有以下用户定义的功能：

create function [dbo].[FullNameLastFirst]
(
    @IsPerson bit,
    @LastName nvarchar(100),
    @FirstName nvarchar(100)
)
returns nvarchar(201)
as
begin
    declare @Result nvarchar(201)
    set @Result = (case when @IsPerson = 0 then @LastName else case when @FirstName = '' then @LastName else (@LastName + ' ' + @FirstName) end end)
    return @Result
end

我无法使用此函数在计算列上创建索引，因为它不是确定性的。有人可以解释为什么它不是确定性的，最终如何修改以使其具有确定性？感谢

Answer 1

您只需创建with schemabinding即可。

然后，SQL Server将验证它是否符合要被视为确定性的标准（因为它不访问任何外部表或使用非确定性函数，如getdate()）。

您可以验证它是否适用于

SELECT OBJECTPROPERTY(OBJECT_ID('[dbo].[FullNameLastFirst]'), 'IsDeterministic')

将原型代码中的schemabinding选项添加正常，但版本稍微简单一些。

CREATE FUNCTION [dbo].[FullNameLastFirst] (@IsPerson  BIT,
                                           @LastName  NVARCHAR(100),
                                           @FirstName NVARCHAR(100))
RETURNS NVARCHAR(201)
WITH SCHEMABINDING
AS
  BEGIN
      RETURN CASE
               WHEN @IsPerson = 0
                     OR @FirstName = '' THEN @LastName
               ELSE @LastName + ' ' + @FirstName
             END
  END

Answer 2

您需要声明用户定义函数WITH SCHEMABINDING以安抚计算列上索引的'确定性'要求。

声明为WITH SCHEMABINDING的函数将保留有关函数中使用的对象依赖项的额外知识（例如表中的列），并且将阻止对这些列的任何更改，除非事先删除函数本身。

确定性函数还可以帮助Sql Server优化其执行计划，最明显的是Halloween Protection问题。

以下是使用模式绑定函数在计算列上创建索引的示例：

create function [dbo].[FullNameLastFirst] 
( 
    @IsPerson bit, 
    @LastName nvarchar(100), 
    @FirstName nvarchar(100) 
) 
returns nvarchar(201) 
with schemabinding
as 
begin 
    declare @Result nvarchar(201) 
    set @Result = (case when @IsPerson = 0 then @LastName 
                        else case when @FirstName = '' then @LastName 
                                  else (@LastName + ' ' + @FirstName) end end) 
    return @Result 
end 


create table Person
(
  isperson bit,
  lastname nvarchar(100),
  firstname nvarchar(100),
  fullname as [dbo].[FullNameLastFirst] (isperson, lastname, firstname)
)
go
insert into person(isperson, lastname, firstname) values (1,'Firstname', 'Surname')
go

create index ix1_person on person(fullname)
go

select fullname from Person with (index=ix1_person) where fullname = 'Firstname Surname'
go

Sql Server确定性用户定义函数

2 个答案: