Question

我试图使用1到12个线程绘制某些数据集1,2和3的执行时间。基于其他合作者的提示，我已经设法绘制了一些内容，但仍然是原始的，需要进行一些修改。

test.dat文件如下所示：

以这种方式组织：前10行是数据集1和1线程的执行时间;接下来的10个是数据集2和1个线程的时间; 10个下一个数据集3,1个线程，依此类推，最多可包含12个线程。

gnuplot脚本如下所示：

set boxwidth 0.7 relative
set style fill solid 1.0 noborder
set xtics ("1" 15, "2" 75, "3" 135, "4" 195, "5" 255, "6" 315, "7" 375, "8" 435, "9" 495, "10" 555, "11" 615, "12" 675)
unset key
set terminal png size 800,600 enhanced font "Helvetica,10"
set output 'output.png'
set xlabel "Number of threads"
set ylabel "Execution time"
plot for [i=1:12] 'test.dat' using ($0+(i-1)*60):1 every ::((i-1)*30)::(i*30-1) with boxes lt i

这个情节存在一些问题：

数据集：我们可以看到每个数据集有10个执行，每个线程数。数据集1是最低值，ds 2是中值，ds 3是最高值。对于每个线程数而不是一种颜色，应该只有3种颜色，例如数据集1为红色，数据集2为绿色，数据集3为蓝色，这些应通过右上角的设置键通知。
间距：绘图开始粘在左y轴上。在第一个直方图和左侧y轴之间应该有15个单位的间距，在数据集之间应该有几个单位，在线程数之间还有15个单位，在最后一个直方图和右边y轴之间有15个单位。 / LI>
xtics：xtics应考虑前面提到的间距。是否可以循环这些xtics的设置？

提前致谢。

更新

Matthew，基于您对第1点的断言，这里是按数据集排序的执行时间（数据集1：第1 - 120行;数据集2：行121 - 240;数据集3：行241 - 360）;给定ds的前10行代表1个线程的执行时间，10个下一个代表2个线程，依此类推。

我也会发布之前的情节，以便衡量你在改善方面的帮助：

Answer 1

我相信这会实现你想要的目标：

set xlabel "Number of threads"
set ylabel "Execution time"

set style fill solid 1.0 noborder

set boxwidth 0.7

set xtics ("1" 19.5)
set for[i=2:12] xtics add (sprintf("%d",i) (i-1)*55+19.5) 

set key top right

set xrange[-15:660]

plot for [i=0:2] for [j=0:9] 'test.dat' using ($0*55+j+i*15):1 every 30::(i*10+j) with boxes lt (i+1) t (j==0)?sprintf("Data Set %d",i+1):""

这里我们在两个边缘，线程之间插入15个单位，在数据集之间插入5个单位。我还将盒宽设置为绝对值而不是相对值。

结果如下：

解决你的观点：

第3点

是的，可以使用set for语法查看x-tics的设置。在这里，我明确指定第一个xtic。这具有关闭所有抽搐但是我指定的抽搐的效果，然后我使用set xtics add命令添加额外的xtics。如果我没有明确设置第一个，我会得到自动生成的抽动除了我的。

或者，我们可以在字符串中构建命令，然后使用

执行它

tcommand = "("
do for[i=1:12] {tcommand = sprintf("%s \"%d\" %f,",tcommand,i,(i-1)*55+19.5)}
tcommand = tcommand[1:strlen(tcommand)-1].")"
set xtics @tcommand

这里tcommand的内容将是

( "1" 19.500000, "2" 74.500000, "3" 129.500000, "4" 184.500000, "5" 239.500000, "6" 294.500000, "7" 349.500000, "8" 404.500000, "9" 459.500000, "10" 514.500000, "11" 569.500000, "12" 624.500000)

但是，这只适用于支持字符串宏的情况。

注意螺纹部分的宽度是3 * 10 + 2 * 5 + 15 = 55，因为有三个数据集占用10个空间，它们之间有5个空格的2个空格，以及15个空格的一个间隙。 19.5将tic标记直接放在中心数据集的中心。

第2点

这可以通过调整xrange轻松处理。如果我们将第一个框置于0，我们可以在-15处开始xrange以留下左边的间隙。由于有12个线程单元每个使用55个空格（包括间隙），我们可以将xrange的末尾放在660.

第1点

这是比较棘手的部分，我怀疑可能有更好的方法。特别是，数据结构使这更加困难。如果列出了数据集1的所有值，接着是集合2的所有值，依此类推，则会更容易。它们混合在一起的事实使它变得更难。

此处各种线程数和数据点的行号如下所示：

               Data set 1
     1 thread   2 threads   3 threads ...
1st  0          30          60
2nd  1          31          61
...

               Data set 2
     1 thread   2 threads   3 threads ...
1st  10         40          70
2nd  11         41          71
...

每个命令都不支持类似＆＃34;每30个点开始连续10行＆＃34;，所以我们需要做两个循环。第一个循环（i）将在数据集上。第二个（j）将位于数据集中的第一行（第一行，第二行等）。

因此我们可以从（i * 10 + j）开始读取每30行。例如，当i和j都为0时，我们将读取第0行，第30行，第60行等，即数据集1的每个线程集中的第一行。因此，我们可以将这些值放在$ 0 * 55 + j + i * 15其中$ 0的范围是0到11，因此可以用来选择线程组。

因为这意味着我们每个数据集将有10条曲线，我们只在第一条曲线上设置标题（将其设置为空将其抑制）。

在这里，我使用了默认的线型。要为每个集合设置特定颜色，可以修改plot命令，或者可以重新定义线型。

编辑：

对于OP提供的排序数据集，plot命令（其余命令保持不变）可以简化为

plot for [i=0:2] 'test.dat' u (i*15 + floor($0/10)*55 + int($0)%10):1 every ::(i*120)::((i+1)*120-1) w boxes t sprintf("Data set %d",i+1)

这里我们只需循环遍历数据集。没有必要循环遍历线，因为我们可以读取连续行的一个块中的每个数据集。对于每个数据集，每个符号选择与其对应的120（行0 - 119,120 - 239,240 - 359）。

为了计算x坐标，我们计算数据集的偏移量（第一个为0，第二个为15，第三个为30），对应于前一个集合使用的10个单位块的数量加上间距为5个单位。为此我们添加了线程块的偏移量。为此，我们将行号（0索引）除以10（每个线程的测量次数）并将结果置于平局。因此前十行给出0，接下来的10行给我们1，依此类推。这告诉我们要跳过多少个线程块，然后将它乘以线程块的大小（55）。最后，我们在测量集中添加线的值。我们使用模运算来获得相对于线程块而不是数据集的实际行号（0,1,2,3,4,5,6,7,8,9,0,1,2 ...... ）。因此i*15 + floor($0/10)*55 + int($0)%10为我们提供了测量的x坐标。尽管$ 0只有整数值，但它被视为浮点数，所以我们转换为int以获取模数。

添加标签要简单得多，因为我们只需要遍历每个数据集一次而不是10次，所以我们不必担心会跳过后来的循环。

抛光gnuplot直方图

1 个答案:

第3点

第2点

第1点