Question

我正在尝试编写一个函数，该函数可以获取所有参数并将它们打印为完全符合输入的字符串。

例如使用以下功能：

test('arg1' => $arg1, 'arg2' => $arg2);

我想在函数格式完全中获取以下字符串，如下所示：

"'arg1' => $arg1, 'arg2' => $arg2"

我想这样做，所以我可以按照为调试/测试目的输入的方式打印所有参数。

Answer 1

Perl提供了特殊的debugging hooks，可以让您查看已编译源文件的原始行。您可以编写一个自定义调试器，每次调用子例程时都会打印原始行。

以下内容允许您指定一个或多个要匹配的子例程;每次调用匹配的子程序时，都会打印相应的行。

package Devel::ShowCalls;

our %targets;

sub import {
    my $self = shift;

    for (@_) {
        # Prepend 'main::' for names without a package specifier
        $_ = "main::$_" unless /::/;
        $targets{$_} = 1;        
    }
}

package DB;

sub DB {
    ($package, $file, $line) = caller;
}

sub sub {
    print ">> $file:$line: ",
          ${ $main::{"_<$file"} }[$line] if $Devel::ShowCalls::targets{$sub};
    &$sub;
}

1;

在以下程序中跟踪函数foo和Baz::qux的调用：

sub foo {}
sub bar {}
sub Baz::qux {}

foo(now => time);
bar rand;
Baz::qux( qw/unicorn pony waffles/ );

执行命令

$ perl -d:ShowCalls=foo,Baz::qux myscript.pl 
>> myscript.pl:5: foo(now => time);
>> myscript.pl:7: Baz::qux( qw/unicorn pony waffles/ );

请注意，这只会打印调用的第一行，因此对于

等调用不起作用

foo( bar,
     baz );

Answer 2

我知道这可能不是最好的解决方案，但它有效：

sub test {
    my (undef, $file_name, $line_number) = caller;
    open my $fh, '<', $file_name or die $!;
    my @lines = <$fh>;
    close $fh;

    my $line = $lines[$line_number - 1];
    trim($line);

    print $line."\n";
}

sub trim {
    return map { $_ =~ s/^\s+|\s+$//g } @_;
}

现在运行时：

test(time);

您将获得此输出：

试验（时间）;

将所有参数作为Perl中的字符串传递给子例程

2 个答案: