Question

我有这个批处理文件，我写的是打开putty，并希望将其作为其他人的通用脚本。该脚本如下

@echo off
::Written by Mark Gulick::
::Today's Date 20150316::

set /p U="Enter Username: "
set /p P="Enter Password: "
set /p DC="Enter DC Number: "
start /d "C:\Program Files (x86)\putty\" PUTTY.EXE %U%@b0%DC%db -pw %P%
pause

我想让密码不显示，并尝试了一些区域，但没有找到一个可行的密码。我也可能做错了。我的脚本有点生疏了。我错过了什么或者我应该使用set命令之外的其他东西吗？

Answer 1

在DOSTips上的

This post在这里引用了MC ND的帖子，但我找不到原文，所以这里又是。每当您想要获取密码并屏蔽输入时，只需call :getPassword target_variable input_prompt，其中target_variable是您存储密码的变量的名称，input_prompt是您向用户显示的任何内容，以提示他们输入密码。

@echo off
set /p "user_name=Enter username here:"
call :getPassword user_password "Enter password here: "
:: The user's password has been stored in the variable %user_password%

exit /b

::------------------------------------------------------------------------------
:: Masks user input and returns the input as a variable.
:: Password-masking code based on http://www.dostips.com/forum/viewtopic.php?p=33538#p33538
::
:: Arguments: %1 - the variable to store the password in
::            %2 - the prompt to display when receiving input
::------------------------------------------------------------------------------
:getPassword
set "_password="

:: We need a backspace to handle character removal
for /f %%a in ('"prompt;$H&for %%b in (0) do rem"') do set "BS=%%a"

:: Prompt the user 
set /p "=%~2" <nul 

:keyLoop
:: Retrieve a keypress
set "key="
for /f "delims=" %%a in ('xcopy /l /w "%~f0" "%~f0" 2^>nul') do if not defined key set "key=%%a"
set "key=%key:~-1%"

:: If No keypress (enter), then exit
:: If backspace, remove character from password and console
:: Otherwise, add a character to password and go ask for next one
if defined key (
    if "%key%"=="%BS%" (
        if defined _password (
            set "_password=%_password:~0,-1%"
            set /p "=!BS! !BS!"<nul
        )
    ) else (
        set "_password=%_password%%key%"
        set /p "="<nul
    )
    goto :keyLoop
)
echo/

:: Return password to caller
set "%~1=%_password%"
goto :eof

Answer 2

您可以这样做：

@echo off & setlocal DisableDelayedExpansion
Title %~n0
Mode 50,5 & Color 0E
set /p U="Enter Username : "
Call:InputPassword "Enter Password" P
set /p DC="Enter DC Number: "
setlocal EnableDelayedExpansion
start /d "C:\Program Files (x86)\putty\" PUTTY.EXE !U!@b0!DC!db -pw !P!
pause
::***********************************
:InputPassword
Cls
echo.
echo.
set "psCommand=powershell -Command "$pword = read-host '%1' -AsSecureString ; ^
    $BSTR=[System.Runtime.InteropServices.Marshal]::SecureStringToBSTR($pword); ^
      [System.Runtime.InteropServices.Marshal]::PtrToStringAuto($BSTR)""
        for /f "usebackq delims=" %%p in (`%psCommand%`) do set %2=%%p
)
goto :eof     
::***********************************

Answer 3

批处理文件不能单独执行此操作，但如果您正在运行批处理，这意味着您可能在Windows上，并自动安装VBScript。您可以使用它来获取屏蔽密码：

randomThing.bat

echo Blah blah blah...
:: Call a vbscript file with the outputs being set as a variable
for /f "usebackq tokens=*" %%r in (`wscript "password.vbs"`) do set retPass=%%r
:: Write back the input for example's sake.
echo What you typed in: %retPass%

password.vbs

'Call this script from a batch file to input a masked password
set objPassword = createObject("scriptPW.password") 
wScript.stdOut.write "Input Password:" 
strPassword = objPassword.getPassword() 
wScript.echo strPassword

注意我在移动设备上回答这个问题，因此无法测试此方法是否仍然有效。然而，它得到了主要的想法。

批处理文件命令隐藏密码

3 个答案:

randomThing.bat

password.vbs