Question

正在尝试随机化一堆按钮坐标并使用此代码成功管理...

var coordinates:Vector.<Point> = new <Point>[
new Point(44, 420),
new Point(270, 420),
new Point(44, 550),
new Point(270, 550)
];


function positionAtRandomCoordinate(object:DisplayObject):void {
var index:int = Math.random() * coordinates.length;
var coordinate:Point = coordinates.splice(index, 1)[0];
object.x = coordinate.x;
object.y = coordinate.y;
}

positionAtRandomCoordinate(answerButtons);
positionAtRandomCoordinate(answerButtons_2);
positionAtRandomCoordinate(answerButtons_3);
positionAtRandomCoordinate(answerButtons_4);

此代码有效，当我开始游戏时，按钮的坐标随机化。

我遇到的问题是我希望每次有正确答案时这些坐标都是随机的。

我的代码是......

function checkAnswers() {
if (questionColour == answerColour){
    textLabeller(textBox);
    colourLabeller(textBox);
    updateScore();
positionAtRandomCoordinate(answerButtons);
positionAtRandomCoordinate(answerButtons_2);
positionAtRandomCoordinate(answerButtons_3);
positionAtRandomCoordinate(answerButtons_4);


    if (score > sharedData.data.highScore){
        sharedData.data.highScore = score;
        sharedData.flush();
        updateHiScore();


    }
    SecondsToCountDown = 6;

    }else {
    trace ("colours do not match");
    CountDownTimer.stop();
     gotoAndStop(3);
}

}

大多数checkAnswers函数与我认为的问题无关，它只是通过检查两个事物是否匹配来显示函数是如何工作的，需要发生一些事情。

当我运行此按钮时，按钮随机正常...但是当我得到正确的答案时，我的输出上出现此错误

RangeError：错误＃1125：索引0超出范围0。

......他们不再随意了。

任何想法都可以吗？非常感谢。

修改

Per Aarons的建议，我修改后的代码是......

function createCoordinatePositions():Vector.<Point> {
return new <Point>[
    new Point(44, 420),
    new Point(270, 420),
    new Point(44, 550),
    new Point(270, 550)
];
}

function positionAtRandomCoordinate(object:DisplayObject, coordinates:Vector.<Point>):void {
var index:int = Math.random() * coordinates.length;
var coordinate:Point = coordinates.splice(index, 1)[0];
object.x = coordinate.x;
object.y = coordinate.y;
}

function positionButtonsRandomly():void {
var coordinates:Vector.<Point> = createCoordinatePositions();
positionAtRandomCoordinate(answerButtons, coordinates);
positionAtRandomCoordinate(answerButtons_2, coordinates);
positionAtRandomCoordinate(answerButtons_3, coordinates);
positionAtRandomCoordinate(answerButtons_4, coordinates);
}

然后我添加到checkAnswers（）函数...

positionButtonsRandomly();

它现在无缝地工作，没有范围错误。

谢谢！所有人都欢呼亚伦。

Answer 1

您需要每次重新创建坐标，因为当您选择随机位置时使用splice()删除所有点。

例如，您可以创建一个函数来创建可能的坐标，而不是使用顶级coordinates var：

function createCoordinatePositions():Vector.<Point> {
    return new <Point>[
        new Point(44, 420),
        new Point(270, 420),
        new Point(44, 550),
        new Point(270, 550)
    ];
}

然后修改随机位置函数以获取可能坐标的参数：

function positionAtRandomCoordinate(object:DisplayObject, coordinates:Vector.<Pont>):void {
    // Same as before
}

现在，要随机定位所有按钮，首先要创建一个新的可能坐标列表，并将其传递给每个随机定位的调用：

function positionButtonsRandomly():void {
    var coordinates:Vector.<Point> = createCoordinatePositions();
    positionAtRandomCoordinate(answerButtons, coordinates);
    positionAtRandomCoordinate(answerButtons_2, coordinates);
    positionAtRandomCoordinate(answerButtons_3, coordinates);
    positionAtRandomCoordinate(answerButtons_4, coordinates);
    // By here the coordinates.length = 0
}

RangeError：错误＃1125：索引0超出范围0

1 个答案: