Question

对于某种输出格式（不类似于HTML），我需要将HTML表转换为＆＃39; square＆＃39;表，其中每个colspan和rowspan不仅在父单元格中指示，而且还跟有正确数量的空单元格。

例如，简单的HTML表格

<table>
    <tr>
        <th>test</th>
        <th colspan="2">span 1/2</th>
        <th colspan="3">span 2/2</th>
    </tr>
    <tr>
        <td>col 1</td>
        <td>col 2</td>
        <td>col 3</td>
        <td>col 4</td>
        <td>col 5</td>
        <td>col 6</td>
    </tr>
</table>

应翻译为

<table>
    <tr>
        <th>test</th>
        <th colspan="2">span 1/2</th>
        <th />  <!-- < empty cell added -->
        <th colspan="3">span 2/2</th>
        <th />  <!-- < empty cell added -->
    </tr>
    ..

（注意：输出格式使用了非常不同的语法，这只是为了清晰起见！）

并且，类似地，rowpans应该传播到下一个<tr>行：

<table><tr><td rowspan="3" /><td rowspan="2" /><td /></tr>
    <tr><td>data</td></tr>
    <tr><td>data</td><td>data</td></tr>
</table>

应该是

<table>
    <tr><td /><td /><td /></tr>
    <tr><td /><td /><td>data</td></tr>  <!-- 2 empty cells added -->
    <tr><td /><td>data</td><td>data</td></tr>  <!-- 1 empty cell added -->
<table>

处理colspan非常简单：

<xsl:template name="add-empty">
    <xsl:param name="repeat" />

    <xsl:if test="$repeat &gt; 1">
        <td class="empty" />
        <xsl:call-template name="add-empty">
            <xsl:with-param name="repeat" select="$repeat - 1" />
        </xsl:call-template>
    </xsl:if>
</xsl:template>

<xsl:template match="th|td">
    <td>
        <xsl:apply-templates />
    </td>
    <xsl:if test="@colspan">
        <xsl:call-template name="add-empty">
            <xsl:with-param name="repeat" select="@colspan" />
        </xsl:call-template>
    </xsl:if>
</xsl:template>

这将添加单个th或td，检查每个colspan，并根据需要插入尽可能多的空单元格，并对模板进行递归调用{{1 }}。类属性add-empty仅用于调试。

问题在于empty。为了使其正常工作，它需要扫描每个之前的rowspan，并计算哪些列需要为空。那次迭代就像是

tr

- 不需要在第一行调用它，因为只有<xsl:if test="position() > 1"> <xsl:variable name="currentRow" select="position()" /> <xsl:for-each select="../tr[position() < $currentRow]"> <xsl:message>testing <xsl:value-of select="." /></xsl:message> </xsl:for-each> </xsl:if>需要添加。那么，问题有两个：如何构建单元格列表以添加到当前行的正确集合？有了这样的列表，我如何迭代这个列表（这与表中的列总数一样长）和每行colspan个元素？

后者是一个问题，因为我可以使用像

这样的东西迭代单元格集

th|td

（如果<xsl:for-each select="1 to string-length(cell-set)"> <xsl:if test="substring($cell-set, ., 1) = 'E'> .. empty .. ... </xsl:for-each>是字符串），或通过＆＃39;当前＆＃39; cell-set内容使用

tr

在这种情况下，与<xsl:for-each select="th|td"> ..的内容没有直接关系。第一个，我不知道要插入cell-set的哪个索引，第二个我不知道何时插入空白。

Answer 1

基于我在链接中提到的http://andrewjwelch.com/code/xslt/table/table-normalization.html，您可以使用：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xs="http://www.w3.org/2001/XMLSchema" version="2.0" exclude-result-prefixes="xs">

    <xsl:output indent="yes" omit-xml-declaration="yes" />

    <xsl:variable name="table_with_no_colspans">
        <xsl:apply-templates mode="colspan" />
    </xsl:variable>

    <xsl:variable name="table_with_no_rowspans">
        <xsl:for-each select="$table_with_no_colspans">
            <xsl:apply-templates mode="rowspan" />
        </xsl:for-each>
    </xsl:variable>

    <xsl:template match="/">
        <xsl:apply-templates select="$table_with_no_rowspans" mode="final" />
    </xsl:template>

    <xsl:template match="@*|*" mode="#all">
        <xsl:copy>
            <xsl:apply-templates select="@*|*" mode="#current" />
        </xsl:copy>
    </xsl:template>

    <xsl:template match="td | th" mode="colspan">
        <xsl:choose>
            <xsl:when test="@colspan">
                <xsl:copy>
                    <xsl:copy-of select="@* except @colspan"/>
                    <xsl:apply-templates/>
                </xsl:copy>
                <xsl:for-each select="2 to @colspan">
                    <td/>
                </xsl:for-each>
            </xsl:when>
            <xsl:otherwise>
                <xsl:copy-of select="." />
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>

    <!-- make sure it works for both table/tr and table/tbody/tr -->
    <xsl:template match="tbody|table[not(tbody)]" mode="rowspan">
        <xsl:copy>
            <xsl:copy-of select="tr[1]" />
            <xsl:apply-templates select="tr[2]" mode="rowspan">
                <xsl:with-param name="previousRow" select="tr[1]" />
            </xsl:apply-templates>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="tr" mode="rowspan">
        <xsl:param name="previousRow" as="element()" />

        <xsl:variable name="currentRow" select="." />

        <xsl:variable name="normalizedTDs">
            <xsl:for-each select="$previousRow/*">
                <xsl:choose>
                    <xsl:when test="@rowspan &gt; 1">
                        <xsl:copy>
                            <xsl:attribute name="rowspan">
                                <xsl:value-of select="@rowspan - 1" />
                            </xsl:attribute><!--
                            <xsl:copy-of select="@*[not(name() = 'rowspan')]" />
                            <xsl:copy-of select="node()" />
                        --></xsl:copy>
                    </xsl:when>
                    <xsl:otherwise>
                        <xsl:copy-of select="$currentRow/*[1 + count(current()/preceding-sibling::*[not(@rowspan) or (@rowspan = 1)])]" />
                    </xsl:otherwise>
                </xsl:choose>
            </xsl:for-each>
        </xsl:variable>

        <xsl:variable name="newRow" as="element(tr)">
            <xsl:copy>
                <xsl:copy-of select="$currentRow/@*" />
                <xsl:copy-of select="$normalizedTDs" />
            </xsl:copy>
        </xsl:variable>

        <xsl:copy-of select="$newRow" />

        <xsl:apply-templates select="following-sibling::tr[1]" mode="rowspan">
            <xsl:with-param name="previousRow" select="$newRow" />
        </xsl:apply-templates>
    </xsl:template>

    <xsl:template match="td | th" mode="final">
        <xsl:choose>
            <xsl:when test="@rowspan">
                <xsl:copy>
                    <xsl:copy-of select="@* except @rowspan" />
                    <xsl:copy-of select="node()" />
                </xsl:copy>
            </xsl:when>
            <xsl:otherwise>
                <xsl:copy-of select="." />
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>

</xsl:stylesheet>

将HTML colspan和rowspan转换为＆＃34; empty＆＃34;细胞

1 个答案: