Question

假设我有ListView个可点击的委托组件（或GridView或Repeater）。这些委托组件需要在触发时发出信号以及自定义数据，这些信息可以由ListView的父级接收。如何实现这种信号绑定？

e.g。以下代码是我的尝试，但我不知道如何将委托组件的trigger信号绑定到componentTriggered项中的root信号？

Item {
    id: root
    anchors.fill: parent

    signal componentTriggered(string name)

    onComponentTriggered: {
        console.log(name + ' component was triggered')
    }

    ListModel {
        id: myModel

        ListElement { name: "alpha" }
        ListElement { name: "beta" }
        ListElement { name: "gamma" }
        ListElement { name: "delta" }
    }

    ListView {
        id: myListView
        width: 100
        height: 600

        model: myModel
        delegate: TheDelegate { name: model.name }
    }
}

访问TheDelegate.qml

import QtQuick 2.0

Rectangle {
    id: root
    width: 100
    height: 50
    color: "steelblue"
    border.color: "white"
    border.width: 2

    property string name

    signal trigger(string name)

    Text {
        anchors.centerIn: parent
        text: model.name
    }

    MouseArea {
        anchors.fill: parent
        onClicked: {
            console.log(root.name + ' clicked')
            root.trigger(root.name)
        }
    }
}

Answer 1

您可以在Component.onCompleted处理程序中连接两个信号。

使用你的代码就是这样的：

ListView {
        id: myListView
        width: 100
        height: 600

        model: myModel
        delegate: TheDelegate {
            name: model.name
            Component.onCompleted: {
                trigger.connect(root.componentTriggered)
            }
        }
    }

您可以实现一个函数，而不是调用信号componentTriggered，但这取决于您的要求。无论如何，信号都没问题。

如何在QML中绑定到ListView中的委托组件的信号

1 个答案: