当列中的值更改时，删除关联的单元格

Question

我有一个excel表，有三列：员工编号
员工姓名
可用性
我想要做的是当可用性值从员工编号和员工的数字变为零时与该行关联的名称获得删除线。
当添加可用性编号时，删除线也会消失。我在下面写了一些代码，但我不知道我是否朝着正确的方向前进。

Sub change(ByVal Target As Range)
Dim ws As Worksheet
Dim watchrange As Range
dim intersectrange as range

Set ws = Worksheets("Workbench Report")

endrow = ws.Cells(ws.Rows.count, "E").End(xlUp).Row

Set watchrange = Range("E2:E" & endrow)
Set intersectrange = Intersect(Target, watchrange)
If intersectrange = "" Then
ws.Range("B" & rng.Row).Resize(1, 2).Font.Strikethrough = True
Else
'do nothing
End If

End Sub

有人可以帮助我吗？

提前谢谢

Answer 1

使用以下数据：

此工作表事件宏：

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim watchrange As Range, r As Range, rw As Long
    Dim intersectrange As Range, endrow As Long

    endrow = Cells(Rows.Count, "A").End(xlUp).Row
    Set watchrange = Range("C2:C" & endrow)
    Set intersectrange = Intersect(Target, watchrange)
    If intersectrange Is Nothing Then Exit Sub

    For Each r In intersectrange
        rw = r.Row
        If r.Value = "" Then
            Range("A" & rw & ":B" & rw).Font.Strikethrough = True
        Else
            Range("A" & rw & ":B" & rw).Font.Strikethrough = False
        End If
    Next r
End Sub

将满足您的需求。您需要调整列以匹配您的数据模式。

因为它是工作表代码，所以很容易安装和自动使用：

1. 右键单击Excel窗口底部附近的选项卡名称
2. 选择查看代码 - 这会打开一个VBE窗口
3. 粘贴内容并关闭VBE窗口

如果您有任何疑虑，请先在试用工作表上试用。

如果保存工作簿，宏将随之保存。 如果您在2003年之后使用的是Excel版本，则必须保存 该文件为.xlsm而不是.xlsx

删除宏：

1. 按上述方式调出VBE窗口
2. 清除代码
3. 关闭VBE窗口

要了解有关事件宏（工作表代码）的更多信息，请参阅：

http://www.mvps.org/dmcritchie/excel/event.htm

修改＃1：

此代码由列 C 的更改触发，并驻留在该工作表的代码区域中。

如果您的按钮代码更改了 C 列，则此事件代码可以使用它。