Question

我需要仅使用xslt 1.0来压缩XML文档中的缺失数据，对其进行重新排序，使得项目的索引比索引丢失之后的任何索引大1。（很难用连贯的语言解释，我承认）。

我已经尝试过某些算法，但是当然没有一个算法可以根据输出的变化进行预测，并且不会反复运行脚本，直到输出不再变化为止。一个简单的例子：

输入：

<Set Id="gump">
    <!--    Missing 2,3, must renumber 4->2 and 5->3    -->
    <parameter fieldId="primary.1.label" value="Was 1"/>
    <parameter fieldId="primary.4.label" value="Was 4"/>
    <parameter fieldId="primary.4.tag" value="Was 4"/>
    <parameter fieldId="primary.5.label" value="Was 5"/>
    <parameter fieldId="primary.5.somefld" value="Was 5"/>
</Set>

fieldId属性中嵌入的索引必须按顺序输出，1,2,3;不是1,4,5，例如 - “primary.4.label”必须是输出中的“primary.2.label”等。

在输入样本中，没有索引为2或3的项目。这是必须由索引大于缺失索引的后续项目填充的差距。所以所有指数4都成为指数2，所有指数5都成为指数3。

子索引（“label”，“tag”，“somefld”）在索引集之间可能不同。有些可能存在于一组中而在另一组中不存在。

输出：

<Set Id="gump">
    <!--    Desired output    -->
    <parameter fieldId="primary.1.label" value="Was 1"/>
    <parameter fieldId="primary.2.label" value="Was 4"/>
    <parameter fieldId="primary.2.tag" value="Was 4"/>
    <parameter fieldId="primary.3.label" value="Was 5"/>
    <parameter fieldId="primary.3.somefld" value="Was 5"/>
</Set>

我是xslt的新手，所以我一直在努力使用键等。

Answer 1

---编辑---

显然，这是一个分组问题 - 在XSLT 1.0中最好使用Muenchian方法解决。

假设要替换的数字始终在给定字符串的第一个和第二个句点之间，您可以应用以下样式表：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:key name="param-by-id" match="parameter" use="substring-before(substring-after(@fieldId, '.'), '.')" />

<xsl:template match="Set">
    <xsl:copy>
        <xsl:copy-of select="@*"/>
        <xsl:for-each select="parameter[count(. | key('param-by-id', substring-before(substring-after(@fieldId, '.'), '.'))[1]) = 1]">
            <xsl:variable name="i" select="position()" />
            <xsl:for-each select="key('param-by-id', substring-before(substring-after(@fieldId, '.'), '.'))">
                <parameter>
                    <xsl:copy-of select="@*"/>
                    <xsl:attribute name="fieldId">
                        <xsl:value-of select="substring-before(@fieldId, '.')"/>
                        <xsl:text>.</xsl:text>
                        <xsl:value-of select="$i"/>
                        <xsl:text>.</xsl:text>
                        <xsl:value-of select="substring-after(substring-after(@fieldId, '.'), '.')"/>
                    </xsl:attribute>
                </parameter>
            </xsl:for-each>
        </xsl:for-each>
    </xsl:copy>
</xsl:template>

</xsl:stylesheet>

输入并接收：

<?xml version="1.0" encoding="UTF-8"?>
<Set Id="gump">
   <parameter fieldId="primary.1.label" value="Was 1"/>
   <parameter fieldId="primary.2.label" value="Was 4"/>
   <parameter fieldId="primary.2.tag" value="Was 4"/>
   <parameter fieldId="primary.3.label" value="Was 5"/>
   <parameter fieldId="primary.3.somefld" value="Was 5"/>
</Set>

使用xslt 1.0重新编号，重新排序XML数据

1 个答案: