Question

我希望这是一个简单的，虽然它似乎经常不是......

我正在使用 XLST 1.0 ，我有一个字符串，我需要translate。该字符串是用户输入的文本字段。它包含由分隔符分隔的几个较小的字符串。（在这种情况下，它＆＃34; |＆＃34;。）此字符串的长度和特殊字符的数量差异很大。

（此字段类似于CSV列表，但是，而不是使用逗号作为分隔符，＆＃34; |＆＃34;是分隔符。）

我需要了解如何将此分隔符更改为<br>。

我已尝试使用以下XSL来实现此目的：

<xsl:variable name="stringtotrans">
    <xsl:text>String1|String2|String3</xsl:text>
</xsl:vairable>
    <!-- In the actual XML document, this variable grabs the value of an attribute. -->
    <!-- For this example, it's being entered manually. -->
    <!-- The number and length of the individual strings varies widely. -->

<xsl:value-of select="translate($stringtotrans, '|', '&#xA;&#xD;')"/>

运行此代码时，输出为：

String1String2String3

预期/期望的输出是：

String1
String2
String3

非常感谢任何和所有这方面的帮助！

Answer 1

translate()函数从字符映射到字符。在您的情况下，您将|替换为
（第一个字符），即换行符（LF）。这可能适用于Unix系统，其中LF通常标记行尾，但它不能在Windows上工作，例如，行结束标记为CR + LF（
）。

有关XML中EOL的更多详细信息，请参阅How to add a newline (line break) in XML file?

要在XSLT 1.0中用字符串替换字符，请参阅Michael's recursive template for replace。

Answer 2

我需要了解如何将此分隔符更改为<br>。

以下样式表：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="html" encoding="UTF-8" />

<xsl:template match="/">

    <xsl:variable name="stringtotrans">
        <xsl:text>String1|String2|String3</xsl:text>
    </xsl:variable>

    <p>
        <xsl:call-template name="tokenize">
            <xsl:with-param name="text" select="$stringtotrans"/>
        </xsl:call-template>
    </p>
</xsl:template>

<xsl:template name="tokenize">
    <xsl:param name="text"/>
    <xsl:param name="delimiter" select="'|'"/>
    <xsl:choose>
        <xsl:when test="contains($text, $delimiter)">
            <xsl:value-of select="substring-before($text, $delimiter)"/>
            <br/>
            <!-- recursive call -->
            <xsl:call-template name="tokenize">
                <xsl:with-param name="text" select="substring-after($text, $delimiter)"/>
            </xsl:call-template>
        </xsl:when>
        <xsl:otherwise>
            <xsl:value-of select="$text"/>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

</xsl:stylesheet>

应用于任何XML输入，将返回：

<p>String1<br>String2<br>String3</p>

XSLT 1.0翻译字符串 - 将字符更改为新行

2 个答案: