Question

我需要编写一个宏子代码，以防止在Excel中的M列中输入重复项。

例如：

我在单元格M5中输入“A - 100” 如果我在单元格M7中输入“A - 100”，我想向我显示一条重复的错误消息。

我尝试了数据验证，但公式不起作用，所以我想使用宏。

Answer 1

在工作表代码区域中输入以下事件宏：

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim Intr As Range, M As Range, r As Range
    Dim wf As WorksheetFunction, t As String

    Set wf = Application.WorksheetFunction
    Set M = Range("M:M")
    Set Intr = Intersect(M, Target)
    If Intr Is Nothing Then Exit Sub
    For Each r In Intr
        t = r.Text
        If t <> "" Then
            If wf.CountIf(M, t) <> 1 Then
                Application.EnableEvents = False
                    r.Select
                    r.ClearContents
                    MsgBox t & " has already been entered."
                Application.EnableEvents = True
                Exit Sub
            End If
        End If
    Next r
End Sub

因为它是工作表代码，所以很容易安装和自动使用：

右键单击Excel窗口底部附近的选项卡名称
选择查看代码 - 这会打开一个VBE窗口
粘贴内容并关闭VBE窗口

如果您有任何疑虑，请先在试用工作表上试用。

如果保存工作簿，宏将随之保存。如果您在2003年之后使用的是Excel版本，则必须保存该文件为 .xlsm ，而不是 .xlsx

删除宏：

按上述方式调出VBE窗口
清除代码
关闭VBE窗口

要了解有关宏的更多信息，请参阅：

http://www.mvps.org/dmcritchie/excel/getstarted.htm

和

http://msdn.microsoft.com/en-us/library/ee814735(v=office.14).aspx

要了解有关事件宏（工作表代码）的更多信息，请参阅：

http://www.mvps.org/dmcritchie/excel/event.htm

必须启用宏才能使其生效！

用于防止在Excel中的M列中输入重复项的宏

1 个答案: