Question

当我有

时

SET IrfanFile32=i_view32.exe    
FOR /F "tokens=*" %%a IN ('dir /b /s "%ProgramFiles%\%IrfanFile32%" 2^>NUL') DO SET IrfanPath=%%a

如果找到相应的文件，则会导致设置所需变量。但是当我将最后一行更改为

时

FOR /F "tokens=*" %%a IN ('dir /b /s "%PROGRAMFILES(X86)%\%IrfanFile32%"') DO SET IrfanPath=%%a

它说“\ IrfanView \ i_view32.exe”此时无法在语法上处理，这显然是指set命令。（echo用作给出正确的结果）。 SET似乎有一个括号问题，但当我认为我可以通过使用引号

来解决这个问题

FOR /F "tokens=*" %%a IN ('dir /b /s "%PROGRAMFILES(X86)%\%IrfanFile32%"') DO SET "IrfanPath=%%a"

我注意到它没有解决它。我错过了什么/我怎样才能做到这一点？（我读到了关于正常变量的delayedexpansion，但它是否适用于像%% a这样的循环变量？如果是这样的话：怎么样？）

以下是整个代码：

REM @echo off
SETLOCAL ENABLEDELAYEDEXPANSION
SET IrfanFile32=i_view32.exe
SET IrfanFile64=i_view64.exe
SET IrfanParams=""
SET SourcePath=%~1\nul
:Start
FOR /F "tokens=3,4,5,6,7,8,9" %%a IN ('REG QUERY HKCU\Environment /v IrfanPath ^|find "IrfanPath"') DO (
  REM echo %IrfanPath%
  SET IrfanPath=%%a %%b %%c %%d %%e %%f %%g
)
echo.
IF NOT DEFINED IrfanPath (GOTO Init) ELSE (GOTO Main)
:Init
  echo Dies scheint mein erster Start auf diesem System zu sein. 
  echo Ich benötige IrfanView (inkl. JPG_TRANSFORM Plugin) um zu funktionieren
  echo und suche nun im Ordner %ProgramFiles% und allen Unterverzeichnissen 
  echo nach IrfanViews Startdatei namens %IrfanFile32% bzw. %IrfanFile64%.
  echo.
  IF EXIST "%PROGRAMFILES(X86)%" echo 64bit Betriebssystem gefunden, suche zusätzlich in %PROGRAMFILES(X86)%.
  echo.
  FOR /F "tokens=*" %%a IN ('dir /b /s "%ProgramFiles%\%IrfanFile32%" 2^>NUL') DO SET IrfanPath=%%a
  FOR /F "tokens=*" %%a IN ('dir /b /s "%ProgramFiles%\%IrfanFile64%" 2^>NUL') DO SET IrfanPath=%%a
  FOR /F "tokens=*" %%a IN ('dir /b /s "%PROGRAMFILES(X86)%\%IrfanFile32%"') DO SET IrfanPath=%%a
  IF DEFINED IrfanPath (
    echo Ich habe IrfanView hier gefunden: %IrfanPath%
    :Entscheidung
    SET /P PathKorrekt=Ist das der gewünschte Pfad? [^(J^)a/^(N^)ein]
    if /i {!PathKorrekt!}=={j} (goto :yes)
    if /i {!PathKorrekt!}=={ja} (goto :yes)
    if /i {!PathKorrekt!}=={n} (goto :no)
    if /i {!PathKorrekt!}=={nein} (goto :no)
    echo Das war keine gültige Antwort. Benutze ja, nein, j oder n. 
    GOTO Entscheidung

    :yes
    REG ADD HKCU\Environment /v IrfanPath /d "%IrfanPath%" >nul
    GOTO Start
  )
  :no
  SET /P IrfanPath=Bitte gib den Pfad zur %IrfanFile32% bzw. %IrfanFile64% an: 
  IF NOT EXIST "%IrfanPath%\%IrfanFile32%" (
    IF NOT EXIST "%IrfanPath%\%IrfanFile64%" (
      echo Keine %IrfanFile32% oder %IrfanFile64% in diesem Ordner gefunden, nochmal bitte.
    GOTO no
    )
  ) ELSE (
    IF EXIST "%IrfanPath%\%IrfanFile32%" (
      REG ADD HKCU\Environment /v IrfanPath /d "%IrfanPath%\%IrfanFile32%"
    )
    IF EXIST "%IrfanPath%\%IrfanFile64%" (
      REG ADD HKCU\Environment /v IrfanPath /d "%IrfanPath%\%IrfanFile64%"
    )
    PAUSE > NUL
    GOTO Start
  )
) else GOTO Main

:Main
REM more code here

Answer 1

您的代码必须有更多未显示的代码，因为您发布的代码无法提供您所描述的错误，原因有很多：

SET命令不关心括号
像%%a这样的FOR变量的扩展可以防止像括号
在SET语句中添加引号可以防止出现毒性字符文字（无论如何你都不知道）

错误必须在您的代码中的其他位置。我的猜测是你有一个带括号的IF或FOR块，其中包含一个不带引号的%IrfanPath%，由于)中的Program Files (x86)，它会过早地关闭括号内的块。

如果在脚本中禁用ECHO OFF，则可能很快就会发现问题（保持ECHO ON）。

针对已修改的问题进行更新：

问题与我预测的完全一样 - 在代码后面的带括号的IF语句中：

  IF DEFINED IrfanPath (
    echo Ich habe IrfanView hier gefunden: %IrfanPath%
    ... additional code ...
  )

您的%IrfanPath%包含)，但未引用。因此，在扩展之后，它在逻辑上变为：

  IF DEFINED IrfanPath (
    echo Ich habe IrfanView hier gefunden: C:\Program Files (x86
  )
  \IrfanView\i_view32.exe
    ... additional code ...
  )

并且您有错误消息的来源。

最简单的解决方案是在扩展路径周围加上引号：

  IF DEFINED IrfanPath (
    echo Ich habe IrfanView hier gefunden: "%IrfanPath%"
    ... additional code ...
  )

我相信您的代码会正常运行。但是，您正在使用GOTO分支到带括号的IF块中的：标签，这是一个很大的禁忌，因为它会破坏IF块。你还有一个不平衡的关闭paren，它有效地作为一个评论：

) else GOTO Main

有关详细信息，请参阅(Windows batch) Goto within if block behaves very strangely。

我认为您的代码是一种特殊情况，它恰好可以正常工作。但更常见的是，如果你不了解这种机制，就不会导致难以调试的疯狂结果。

我会按如下方式重构您的代码：

REM @echo off
setlocal DisableDelayedExpansion
SET IrfanFile32=i_view32.exe
SET IrfanFile64=i_view64.exe
SET IrfanParams=""
SET "SourcePath=%~1\nul"
:Start
FOR /F "tokens=3,4,5,6,7,8,9" %%a IN ('REG QUERY HKCU\Environment /v IrfanPath ^|find "IrfanPath"') DO (
  REM echo %IrfanPath%
  SET IrfanPath=%%a %%b %%c %%d %%e %%f %%g
)
echo.
IF NOT DEFINED IrfanPath (GOTO Init) ELSE (GOTO Main)
:Init
  echo Dies scheint mein erster Start auf diesem System zu sein. 
  echo Ich benötige IrfanView (inkl. JPG_TRANSFORM Plugin) um zu funktionieren
  echo und suche nun im Ordner %ProgramFiles% und allen Unterverzeichnissen 
  echo nach IrfanViews Startdatei namens %IrfanFile32% bzw. %IrfanFile64%.
  echo.
  IF EXIST "%PROGRAMFILES(X86)%" echo 64bit Betriebssystem gefunden, suche zusätzlich in %PROGRAMFILES(X86)%.
  echo.
  FOR /F "tokens=*" %%a IN ('dir /b /s "%ProgramFiles%\%IrfanFile32%" 2^>NUL') DO SET IrfanPath=%%a
  FOR /F "tokens=*" %%a IN ('dir /b /s "%ProgramFiles%\%IrfanFile64%" 2^>NUL') DO SET IrfanPath=%%a
  FOR /F "tokens=*" %%a IN ('dir /b /s "%PROGRAMFILES(X86)%\%IrfanFile32%"') DO SET IrfanPath=%%a

  if not defined IrfanPath goto :no

  echo Ich habe IrfanView hier gefunden: %IrfanPath%
:Entscheidung
  SET /P PathKorrekt=Ist das der gewünschte Pfad? [^(J^)a/^(N^)ein]
  if /i "%PathKorrekt%"=="j" (goto :yes)
  if /i "%PathKorrekt%"=="ja" (goto :yes)
  if /i "%PathKorrekt%"=="n" (goto :no)
  if /i "%PathKorrekt%"=="nein" (goto :no)
  echo Das war keine gültige Antwort. Benutze ja, nein, j oder n.
  GOTO Entscheidung

:yes
  REG ADD HKCU\Environment /v IrfanPath /d "%IrfanPath%" >nul
  GOTO Start

:no
  SET /P IrfanPath=Bitte gib den Pfad zur %IrfanFile32% bzw. %IrfanFile64% an:
  IF NOT EXIST "%IrfanPath%\%IrfanFile32%" (
    IF NOT EXIST "%IrfanPath%\%IrfanFile64%" (
      echo Keine %IrfanFile32% oder %IrfanFile64% in diesem Ordner gefunden, nochmal bitte.
      GOTO no
    )
  ) ELSE (
    IF EXIST "%IrfanPath%\%IrfanFile32%" (
      REG ADD HKCU\Environment /v IrfanPath /d "%IrfanPath%\%IrfanFile32%"
    )
    IF EXIST "%IrfanPath%\%IrfanFile64%" (
      REG ADD HKCU\Environment /v IrfanPath /d "%IrfanPath%\%IrfanFile64%"
    )
    PAUSE > NUL
    GOTO Start
  )

:Main
REM more code here

请注意，此结构不再需要延迟扩展。

如何在set命令中用括号转义变量？

1 个答案: