Question

以下是我编写的批处理脚本

@echo off
setlocal enabledelayedexpansion
set finalcontent=
For /F "tokens=1-2* delims=  " %%I in (abc.txt) do (
IF %%J EQU MAJORVER (
set currentline=%%I %%J %1
set finalcontent=!finalcontent!!currentline!
) ELSE IF %%J EQU MINORVER (
set currentline=%%I %%J %2
set finalcontent=!finalcontent!!currentline!
) ELSE IF %%J EQU BUILDNUM (
set currentline=%%I %%J %3
set finalcontent=!finalcontent!!currentline!
) ELSE (
set currentline=%%I %%J %%K%NL%
set finalcontent=!finalcontent!!currentline!
)
)
echo %finalcontent%>>xyz.txt

我想在变量当前行的每个出现的末尾追加一个换行符。任何人都可以指导我吗？

Answer 1

您可以创建一个真实的换行符并将其分配给变量。

setlocal EnableDelayedExpansion
set LF=^


rem TWO empty lines are required
echo This text!LF!uses two lines

换行符最适用于延迟扩展，您也可以将其与扩展百分比一起使用，但随后它会更复杂一些。

set LF=^


rem TWO empty lines are required
echo This text^%LF%%LF%uses two lines
echo This also^

uses two lines

它是如何工作的？
插入符是一个转义字符，它逃脱了下一个字符并且本身被删除但是如果下一个字符是换行符，则换行也会被删除，只有下一个字符被有效地转义（即使这也是一个换行符）。

因此，需要两个空行，LF1被忽略LF2被转义，LF3需要完成“行”。

set myLinefeed=^<LF1>
<LF2>
<LF3>

<强>提示：
使用完全不同格式的换行变量定义通常会更好，避免无意中删除所需的空行。

(SET LF=^
%=this line is empty=%
)

我经常删除其中一条空行，然后我永远搜索为什么我的程序不再有效。

并且偏执版本还会检查新行变量的空格或其他垃圾。

if "!LF!" NEQ "!LF:~0,1!" echo Error "Linefeed definition is defect, probably multiple invisble whitespaces at the line end in the definition of LF"

FOR /F "delims=" %%n in ("!LF!") do (
  echo Error "Linefeed definition is defect, probably invisble whitespaces at the line end in the definition of LF"
)

Answer 2

您可以按如下方式定义换行符：

set newline=^& echo.

然后，您可以在echo语句中使用换行符，如下所示:(但不适用于概述的情况）

echo %finalcontent%%newline%

或者你可以在每个set语句中使用换行符，如下所示:(注意额外的插入符号）

set finalcontent=!finalcontent!!currentline!^!newline!

或类似地：

set currentline=%%I %%J %1^%newline%

将换行符分配给批处理脚本中的变量

2 个答案: