Question

我正在尝试创建一个控件，它在设计时和运行时创建3个标准TPanel。一切都很好：控制创造了完美的面板。但我遇到了一个问题：在设计时，我希望能够选择一个面板我希望重现TPageControl的标准行为：当用户点击屏幕上的TabSheet时，TabSheet可通过对象检查器进行编辑。

下面附上我的控制代码：

unit MyContainer;

interface

uses
  Windows,
  Messages,
  SysUtils,
  Classes,
  Graphics,
  Controls,
  Forms,
  StdCtrls,
  ExtCtrls,
  StrUtils,
  Dialogs;

type
  TMyContainer = class(TCustomControl)
  private
    FPanelA: TPanel;
    FPanelB: TPanel;
    FPanelC: TPanel;

  protected
    procedure Paint; override;

  public
    constructor Create(AOwner: TComponent); override;
    destructor Destroy; override;
  end;

  procedure register;

implementation

{ TMyContainer }

procedure Register;
begin
  RegisterComponents('MyComps', [TMyContainer]);
end;

constructor TMyContainer.Create(AOwner: TComponent);
begin
  Inherited Create(AOwner);

  Width := 200;
  Height := 200;
  ControlStyle := ControlStyle + [csAcceptsControls];

  FPanelA := TPanel.Create(Self);
  FPanelA.Parent := Self;
  FPanelA.Width := 100;
  FPanelA.Height := 60;
  FPanelA.Left := 10;
  FPanelA.Top := 10;

  FPanelB := TPanel.Create(Self);
  FPanelB.Parent := Self;
  FPanelB.Width := 100;
  FPanelB.Height := 60;
  FPanelB.Left := 10;
  FPanelB.Top := 80;

  FPanelC := TPanel.Create(Self);
  FPanelC.Parent := Self;
  FPanelC.Width := 100;
  FPanelC.Height := 60;
  FPanelC.Left := 10;
  FPanelC.Top := 160;
end;

destructor TMyContainer.Destroy;
begin
  FreeAndNil(FPanelA);
  FreeAndNil(FPanelB);
  FreeAndNil(FPanelC);

  Inherited Destroy;
end;

procedure TMyContainer.Paint;
begin
  Canvas.Brush.Color := clBlue;
  Canvas.FillRect(Canvas.ClipRect);
end;


end.

是否有人可以告诉我如何为我的任务找到解决方案？提前谢谢。

Answer 1

这可以通过多种方式实施，具体取决于您的具体愿望。因为你的代码确实只显示了面板的创建，所以我认为你需要的是基础知识，然后你才能真正意识到你的愿望，但是对于新手组件构建者来说，基础知识可能有点困难。

首先：对于在对象检查器中可编辑的内容，它必须是组件或组件的已发布属性（的一部分）。现在你的面板只是私人领域。因此，您可以尝试在属性中发布面板。或者，您可以为所有面板添加一个属性，该属性将通过选定的索引属性进行区分。

您还可以通过将面板添加为单独的组件来模仿页面控件组件。在这种情况下，您可能需要在其上下文菜单中为“新页面”命令添加component editor。

一些注意事项：不需要该控件样式设置，除非该组件通过设计器成为其他控件的父级。此外，你的析构函数是多余的。

然后尝试询问一个非常具体的组件写作问题。

Answer 2

如果您希望允许用户在设计时（或任何其他子控件）实际单击其中一个面板，则主要组件需要处理CM_DESIGNHITTEST消息并返回对于属于所需子控件的任何鼠标坐标的非零值。该邮件在其lParam字段中包含鼠标坐标（您可以将该邮件作为TWMMouse记录接收，该记录包含Pos字段，您可以将其转换为TPoint字段SmallPointToPoint()函数。）

Answer 3

我的问题有一个解决方案我们需要使用TComponentEditor来获得在设计时创建面板的能力，类似于TPageControl。感谢用户NGLN提供了有用的link。

下面的代码为我的组件注册了TComponentEditor（已经讨论过了）。

unit MyEditor;

interface

uses
  Classes,
  SysUtils,
  TypInfo,
  StdCtrls,
  ComCtrls,
  ExtCtrls,
  Dialogs,

  ToolsAPI,
  DesignIntf,
  DesignEditors,
  VCLEditors,

  MyContainer; // our control

type
  {>>>>>>>>>>>>>>>>>>>>>>>>>}
  TMyContainerEditor = class(TComponentEditor)
  private
    procedure ExecuteVerb(Index: Integer); override;
    function GetVerbCount: Integer; override;
    function GetVerb(Index: Integer): string; override;
    procedure Edit; override;
  end;
  {<<<<<<<<<<<<<<<<<<<<<<<<<}

procedure Register;

implementation


{ TMyContainerEditor}

procedure Register;
begin
  RegisterComponentEditor(TMyContainer, TMyContainerEditor )
end;

procedure TMyContainerEditor.Edit;
begin
  ShowMessage('TMyContainerEditor editor');
end;

procedure TMyContainerEditor.ExecuteVerb(Index: Integer);
var
  Panel: TPanel;
begin
  Inherited ExecuteVerb(Index);
  case Index of
    0:  
      ShowMessage('Design editor');  
    1:                                    
    begin
      Panel:= TPanel.Create(Designer.Root);
      Panel.Parent := Designer.Root;
      Panel.Name := Designer.UniqueName('Panel');
      Designer.SelectComponent(Panel);
      Designer.Modified;
    end;
  end;
end;

function TMyContainerEditor.GetVerb(Index: Integer): string;
begin
  case Index of
    0: Result := 'Show info...';
    1: Result := 'Add page';
  end;
end;

function TMyContainerEditor.GetVerbCount: Integer;
begin
  Result := 2;
end;

end.

如何在delphi中的设计时选择我的自定义控件中的子控件

3 个答案: