Question

与Select[Tuples[Range[0, n], d], Total[#] == n &]相似，但更快？

更新

以下是3个解决方案及其时间图，IntegerPartitions后跟Permutations似乎最快。分别为递归，FrobeniusSolve和IntegerPartition解决方案的时间分别为1,7和0.03

partition[n_, 1] := {{n}};
partition[n_, d_] := 
  Flatten[Table[
    Map[Join[{k}, #] &, partition[n - k, d - 1]], {k, 0, n}], 1];
f[n_, d_, 1] := partition[n, d];
f[n_, d_, 2] := FrobeniusSolve[Array[1 &, d], n];
f[n_, d_, 3] := 
  Flatten[Permutations /@ IntegerPartitions[n, {d}, Range[0, n]], 1];
times = Table[First[Log[Timing[f[n, 8, i]]]], {i, 1, 3}, {n, 3, 8}];
Needs["PlotLegends`"];
ListLinePlot[times, PlotRange -> All, 
 PlotLegend -> {"Recursive", "Frobenius", "IntegerPartitions"}]
Exp /@ times[[All, 6]]

Answer 1

你的职能：

In[21]:= g[n_, d_] := Select[Tuples[Range[0, n], d], Total[#] == n &]

In[22]:= Timing[g[15, 4];]

Out[22]= {0.219, Null}

尝试FrobeniusSolve：

In[23]:= f[n_, d_] := FrobeniusSolve[ConstantArray[1, d], n]

In[24]:= Timing[f[15, 4];]

Out[24]= {0.031, Null}

结果是一样的：

In[25]:= f[15, 4] == g[15, 4]

Out[25]= True

您可以使用IntegerPartitions加快速度，但不会得到相同顺序的结果：

In[43]:= h[n_, d_] := 
 Flatten[Permutations /@ IntegerPartitions[n, {d}, Range[0, n]], 1]

排序结果相同：

In[46]:= Sort[h[15, 4]] == Sort[f[15, 4]]

Out[46]= True

速度更快：

In[59]:= {Timing[h[15, 4];], Timing[h[23, 5];]}

Out[59]= {{0., Null}, {0., Null}}

感谢phadej的快速回答让我再次看。

请注意，如果您确实需要所有不同排序的排列，则只需要拨打Permutations（和Flatten），即使您想要

In[60]:= h[3, 2]

Out[60]= {{3, 0}, {0, 3}, {2, 1}, {1, 2}}

而不是

In[60]:= etc[3, 2]

Out[60]= {{3, 0}, {2, 1}}

Answer 2

partition[n_, 1] := {{n}}
partition[n_, d_] := Flatten[ Table[ Map[Join[{k}, #] &, partition[n - k, d - 1]], {k, 0, n}], 1]

这比FrobeniusSolve更快：）

编辑：如果用Haskell编写，它可能更清楚发生了什么 - 功能性：

partition n 1 = [[n]]
partition n d = concat $ map outer [0..n]
  where outer k = map (k:) $ partition (n-k) (d-1)

枚举Mathematica中的所有分区

2 个答案: