Question

在prolog中是否有办法缩短以下时间：

rule(prop, [1/2,2/2]).
rule(prop, [1/3,2/3,3/3]).
rule(prop, [1/4,2/4,3/4,4/4]).
rule(prop, [1/5,2/5,3/5,4/5,5/5]).
rule(prop, [1/6,2/6,3/6,4/6,5/6,6/6]).
rule(prop, [1/7,2/7,3/7,4/7,5/7,6/7,7/7]).

Answer 1

TL; DR：为什么不委托处理递归的责任并正确处理？

@lurker在this previous answer跟进此答案。我们没有涵盖整个问题，而是专注于展示如何定义类似list_props/3的谓词，以便将所有递归委托给经过验证的真实Prolog谓词 length/2，numlist/2和maplist/3：

:- use_module(library(between), [numlist/2]).
:- use_module(library(lists),   [maplist/3]).

要自定义多功能meta-predicate maplist/3我们定义：

denom_num_expr(B, A, A/B).

使用sicstus-prolog进行示例查询4.3.2：

| ?- length(_Ds, N), numlist(N, _Ds), maplist(denom_num_expr(N), _Ds, Qs).
N = 1, Qs = [1/1] ? ;
N = 2, Qs = [1/2,2/2] ? ;
N = 3, Qs = [1/3,2/3,3/3] ? ;
N = 4, Qs = [1/4,2/4,3/4,4/4] ? ;
N = 5, Qs = [1/5,2/5,3/5,4/5,5/5] ? ;
N = 6, Qs = [1/6,2/6,3/6,4/6,5/6,6/6] ? ;
N = 7, Qs = [1/7,2/7,3/7,4/7,5/7,6/7,7/7] ? ;
N = 8, Qs = [1/8,2/8,3/8,4/8,5/8,6/8,7/8,8/8] ? ;
N = 9, Qs = [1/9,2/9,3/9,4/9,5/9,6/9,7/9,8/9,9/9] ? ...

Answer 2

以下代码不一定是＆＃34;更短＆＃34;对于6种不同规则的情况，但它更具可扩展性，这可能就是你的真正含义。

你可以按照以下方式解决这个问题。首先，生成一个列表的规则：

list_props(N, N, [N/N]).
list_props(X, N, [X/N|T]) :-
    X >= 1,
    X < N,
    X1 is X + 1,
    list_props(X1, N, T).

当你调用它时，它会生成一个从第一个参数到最后一个参数的比例列表，最后一个参数是分母。例如：

| ?- list_props(1, 4, L).

L = [1/4,2/4,3/4,4/4] ? a

| ?-

请注意，您可以使用N和条件强制integer(N)为整数＆gt; = 1，但我很简短，并且上面没有这样做。

您可以在顶级谓词中使用它：

rule(prop, L) :-
    between(2, 7, X),
    list_props(1, X, L).

哪个收益率：

| ?- rule(prop, L).

L = [1/2,2/2] ? ;

L = [1/3,2/3,3/3] ? ;

L = [1/4,2/4,3/4,4/4] ? ;

L = [1/5,2/5,3/5,4/5,5/5] ? ;

L = [1/6,2/6,3/6,4/6,5/6,6/6] ? ;

L = [1/7,2/7,3/7,4/7,5/7,6/7,7/7] ? ;

(2 ms) no
| ?-

Prolog：效率

2 个答案: