地形图中的变量键

Question

在Terraform中，我正在尝试创建一个包含带有可变键的地图的模块。我不确定这是否可行，但我已经尝试了以下但没有成功。

resource "aws_instance" "web" {
    ami = "${var.base_ami}"
    availability_zone = "${var.region_a}"
    instance_type = "${var.ec2_instance_size}"
    security_groups = ["sec1"]
    count = "${var.ec2_instance_count}"
    tags {
        Name = "${var.role} ${var_env}"
        role = "${var.app_role}"
        ${var.app_role} = "${var_env}"
    }
}

和此：

tags {
   Name = "${var.role} ${var_env}"
}
tags."${var.role}" = "${var.env}"

有什么想法吗？目前Terraform无法实现这一目标吗？

Answer 1

我知道自从你发布以来已经有一段时间了，但我最近需要类似的东西，所以我在这里发布解决方案，万一其他人偶然发现它。

在terraform插值语法中支持（现在）lookup function，允许您在地图中查找动态键。

使用此功能，我现在可以执行以下操作：

output "image_bucket_name" {
  value = "${lookup(var.image_bucket_names, var.environment, "No way this should happen")}"
}

其中：

variable "image_bucket_names" {
  type = "map"

  default = {
    development = "bucket-dev"
    staging = "bucket-for-staging"
    preprod = "bucket-name-for-preprod"
    production = "bucket-for-production"
  }

}

和environment是一个简单的字符串变量。

Answer 2

以下内容适用于terraform版本0.11.7。此解决方案使用map function。

resource "aws_instance" "web" {
  ...
  tags = "${map(
    "Name", "${var.role} ${var_env}",
    "role", "${var.app_role}",
    "${var.app_role}", "${var_env}"
  )}"
}

Answer 3

我最近也需要动态设置标记密钥，并设法使用zipmap执行此操作：

locals {
  ec2_tag_keys = ["some/prefix/${var.some_var}", "another_tag"]
  ec2_tag_vals = ["some value", "another value"]
}

resource "aws_instance", "foo" {
  ...
  tags = "${zipmap(local.ec2_tag_keys, local.ec2_tag_vals)}"
}

它有点笨重，但它确实有效。

Answer 4

目前尚不支持此功能。

Answer 5

我不确定它何时被添加，但至少从版本0.11.7开始，Terraform支持使用变量作为地图键。以下是我当前如何使用它来选择AWS实例类型的示例：

在.tf文件中：

variable "environment" {}

...

variable "instance_types_webserver" {
  type = "map"

  default = {
    testing    = "t2.small"
    qa         = "t2.medium"
    staging    = "t2.xlarge"
    production = "t2.xlarge"
  }
}

...

resource "aws_opsworks_instance" "verification" {
  stack_id      = "${aws_opsworks_stack.verification.id}"
  layer_ids     = ["${aws_opsworks_custom_layer.verification.id}"]
  instance_type = "${var.instance_types_webserver["${var.environment}"]}"
  state         = "running"
  count         = 1
}

在.tfvars文件中：

...
environment = "testing"
...

Answer 6

更新

可接受的答案描述了如何在现有地图中进行动态查找。要使用动态键构造地图，在HCL2（0.12）中，可以在键中使用带引号的插值表达式：

resource "aws_instance" "web" {
  count = "${var.ec2_instance_count}"

  ami = "${var.base_ami}"
  availability_zone = "${var.region_a}"
  instance_type = "${var.ec2_instance_size}"
  security_groups = ["sec1"]

  tags = {
    Name              = "${var.role} ${var.env}"
    role              = "${var.app_role}"
    "${var.app_role}" = "${var.env}"               # <------ like this
  }
}

issue #21566固定后，您可以将"${var.app_role}"替换为documentation中描述的方法(var.app_role)。

（以下相同的警告也适用于此：如果var.app_role包含这些文字键之一作为其值，则它将替换它。）

旧答案

可接受的答案描述了如何在现有地图中进行动态查找。要使用动态键构造地图，在HCL2（0.12）中，您有两种方法：

For expressions + merge

您可以使用for expressions通过一个或多个键变量来动态构建地图，然后将其与merge function结合使用以构建静态和动态混合的新地图按键：

variable "app_role" {
  type = string
}

locals {
  tags = merge(
    {
      Name = "${var.role} ${var.env}"
      role = "${var.app_role}"
    },
    {
      for k in [var.app_role]: k => "${var.env}"
    }
  )
}

zipmap

或者，您可以使用zipmap一次构建它：

locals {
  tags = zipmap(
    [
       "Name",
       "role",
       var.app_role
    ],
    [
       "${var.role} ${var.env}",
       var.app_role,
       var.env
    ]
  )
}

然后您可以在资源中使用此地图：

resource "aws_instance" "web" {
  count = "${var.ec2_instance_count}"

  ami = "${var.base_ami}"
  availability_zone = "${var.region_a}"
  instance_type = "${var.ec2_instance_size}"
  security_groups = ["sec1"]

  tags = local.tags // or inline the above here
}

一个警告是，如果var.app_role等于"Name"或"role"，那么它将覆盖您的静态值。您可以通过交换merge中的参数或对zipmap中的列表重新排序来避免这种情况，尽管这种冲突很可能是配置错误，应在应用之前发现并解决。