Question

在XML文档中，我想找到光标所在的节点。

我不认为Ace Editor可以做到这一点。但我想也许它可以通过使用索引系统来跟踪。

我的意思是什么？嗯，在XML中有叶子和分支或祖先和后代的层次结构。如果要跟踪节点和位置的数量，可以创建系统以再次查找它。

例如，请使用以下代码：

根节点将是项[0]。第一个后代是[0][0]。第二个后代将是[0][1]。如果第二个后代有三个后代，那么他们的位置将是[0][1][0]，[0][1][1]，[0][1][2]。

有没有办法在Ace Editor中获得该职位？原因是我的应用程序中有一个XML对象。但Ace Editor是JavaScript版，它不支持XML或E4X。我只能从中获取字符串值以传回我的应用程序。

所以我首先必须得到游标在JavaScript中的节点，然后我必须找到如何将它映射回我的应用程序中的XML对象。

现在我已经走到了这一步：

var xml:XML = new XML(ace.text);
var token:Object = ace.getTokenAt(ace.row, ace.column);
var type:String = token ? token.type : "";
var tagName:String;
var index:int = token ? token.index : -1; // index = 2
var start:int = token ? token.start : -1; // start = 5

if (type=="meta.tag.tag-name.xml") {
    tagName = token.value; // head
}

var matchingTagsList:XMLList = xml.descendants(tagName);

if (matchingTagsList.length()==1) {
     var match:XML = matchingTagsList[0];
}
else {
     // numerous matches. how to find one from the other?
}

BTW Ace Editor返回索引和起始值。我可以用它来尝试找到匹配的标签。

我也可以将所有XML匹配转换为字符串，然后如果我可以从Ace的范围从开始标记到结束标记，我可以比较每个。但这确实很糟糕，因为有很多失败点。如果存在名称空间，则字符串不匹配，如果存在空格字符，则字符串不匹配，或编码实体等。

Answer 1

抱歉这已经晚了几个月，但我遇到了同样的问题并找到了自己的解决方案。我已经成功地使用递归函数将光标行与xml节点相关联，以使我的函数的行计数器与光标行匹配。此函数通过子节点，直到行计数器等于光标行。我只是在寻找一个元素节点。如果你的xml有评论行，你也必须计算它们。我假设xml每行有一个节点。否则，您还必须使用cursor.column和更多逻辑。代码有点粗糙。您可能需要清理它。

var cursor = ace.selection.getCursor();
var line = 0;

var insertXmlAtChildNode = function(parent, xmlToInsert) {
  var foundit = false;
  if (parent.nodeType === 1) {
    //element node
    if (cursor.row == line) {
      // found the xml node that matches the cursor row.
      // add your code here to use that node.
      console.log("found the node that matches cursor row " + cursor.row);
      parent.appendChild(xmlToInsert);
      foundit = true;
    }
    if (!foundit && parent && parent.childNodes && parent.childNodes.length > 0) {
      var i;
      for (i = 0; i < parent.childNodes.length; i++) {
        if (parent.childNodes[i].nodeType === 1) {
          // found a child element node
          line++;
        }
        foundit = insertXmlAtChildNode(parent.childNodes[i], xmlToInsert);
        if (foundit) {
          break;
        }
      }
    }
  }
  if (parent.nodeType === 2) {
    //attribute node
  }
  if (parent.nodeType === 3) {
    //text node
  }
  if (parent.nodeType === 8) {
    //comment node
  }
  if (!foundit && parent && parent.childNodes && parent.childNodes.length > 0) {
    // inc line before exiting recursion. this accounts for line number of the closing tag on multi-line element.
    line++;
  }
  return foundit;
};

这开始搜索。

var xml = new XML();

console.log("start looking");
if (xml && xml.childNodes && xml.childNodes.length > 0) {
  var i;
  var foundit = false;
  for (i = 0; i < xml.childNodes.length; i++) {
    foundit = insertXmlAtChildNode(xml.childNodes[i], xmlToInsert);
    if (foundit) {
      break;
    }
  }
}
console.log("end");

Answer 2

我在其中一个Apache FlexJS示例的解决方案中找到了部分答案，用于构建一个人们最终可以通过将其与ace编辑器位置相关联来使用的树结构。

当文本/ XML发生变化时，我们会对其进行解析并将其与之前的值进行比较。我们通过为每个节点提供一个id来创建节点映射。

它没有回答整个问题，但我想展示到目前为止我所拥有的。将此与其他答案相结合可以提供完整的解决方案（仍然通过它）。

每当XML文件或XML文本值发生更改时，您都会调用checkForDifferences，例如，当用户保存.xml文件或用户在编辑器中输入新文本时。这会创建一个对象和标签树。然后在Ace编辑器中，如果有一个树，你将爬回树，以获得父节点中的节点索引，然后获得父深度。使用该信息，您应该能够在树对象中找到节点，然后，如果要保留对树对象中节点的引用，则可以获取光标所在的当前XML节点。

<fx:Script>
    <![CDATA[           
        private function checkForDifferences(filePath:String = null):void {
            var mxmlFile:File;

            if (filePath!=null && filePath!="") {
                try {
                    mxmlFile = new File(filePath);

                    if (mxmlFile.exists && mxmlFile.modificationDate.time == lastModifiedTime) {
                        return;
                    }
                } catch (e:Error) {
                    // might check while file is open to be written so just ignore
                    // and check on the next interval;
                    return;
                }
            }

            parseFile();
            computeChanges();
            applyChanges();
        }

        private function parseFile():void {
            var xml:XML = new XML(aceEditor.text);
            newDB = {};
            generatedIDCounter = 0;
            parseChildren(newDB, xml);
        }

        private function parseChildren(newDB:Object, parent:XML):void {
            var effectiveID:String;
            var elementAttributes:XMLList;
            var numberOfAttributes:int;
            var attributeMap:Object;
            var attributeName:String;
            var children:XMLList;
            var childNode:XML;
            var childNodeName:String;
            var numberOfChildren:int;
            var memberName:String;
            var isStateSpecific:Boolean;
            var metaData:MetaData;

            children = parent.children();
            numberOfChildren = children.length();

            for (var i:int = 0; i < numberOfChildren; i++){
                childNode = children[i];
                childNodeName = childNode.name();

                if (childNodeName == null) {
                    continue; // saw this for CDATA children
                }

                // items to ignore
                if (filteredMXMLNodes[childNodeName]) {
                    continue;
                }

                // we go deep first because that's how the Falcon compiler
                // generates IDs for tags that don't have id attributes set.
                parseChildren(newDB, childNode);

                // check if a class rather than property, style or event
                if (isInstance(childNodeName)) {
                    if (childNode.@id.length() == 0) {
                        effectiveID = "#" + generatedIDCounter++;
                    }
                    else {
                        effectiveID = childNode.@id;
                    }

                    elementAttributes = childNode.attributes();
                    numberOfAttributes = elementAttributes.length();

                    attributeMap = {};
                    newDB[effectiveID] = attributeMap;

                    for (var j:int = 0; j < numberOfAttributes; j++) {
                        attributeName = elementAttributes[j].name();
                        isStateSpecific = attributeName.indexOf(".")!=-1;
                        memberName = getAttributeName(attributeName);
                        //metaData = ClassUtils.getMetaDataOfMember(childNodeName, memberName);

                        //if (supportedAttributes.hasOwnProperty()) {
                        //if (supportedAttributes.hasOwnProperty(getAttributeName(attributeName))) {
                            attributeMap[attributeName] = childNode["@" + attributeName].toString();
                        //}
                    }
                }
            }
        }

        // assume it is an instance if the tag name starts with a capital letter
        private function isInstance(tagName:String):Boolean {
            var hasNamespace:int = tagName.indexOf("::");
            var firstCharacter:String;
            var isCapitalLetter:Boolean;

            if (hasNamespace > -1) {
                tagName = tagName.substring(hasNamespace + 2);
            }

            firstCharacter = tagName.charAt(0);
            isCapitalLetter = firstCharacter >= "A" && firstCharacter <= "Z";

            return isCapitalLetter;
        }

        /**
         * If it contains a period we need to set the attribute in that state if the state exists
         * */
        private function getAttributeName(attributeName:String):String {
            var containsPeriod:int = attributeName.indexOf(".");

            if (containsPeriod > -1) {
                attributeName = attributeName.substring(0, containsPeriod);
            }

            return attributeName;
        }


        private var lastModifiedTime:Number = 0;
        private var generatedIDCounter:int = 0;
        private var newDB:Object;
        private var oldDB:Object;
        private var changes:Object;
        private var removals:Object;

        private var filteredMXMLNodes:Object = {
            "http://ns.adobe.com/mxml/2009::Script": 1,
            "http://ns.adobe.com/mxml/2009::Declarations": 1,
            "http://ns.adobe.com/mxml/2009::Style": 1
        }


        private function applyChanges():void {
            var changedValues:Object;
            var removedValues:Object;
            var attributeName:String;
            var nodeID:String;

            for (nodeID in changes) {
                changedValues = changes[nodeID];
                trace("Node ID:" + nodeID);

                for (attributeName in changedValues) {
                    trace(" - Attribute to change: " + attributeName);
                    trace(" - New value: " + changedValues[attributeName]);
                    //commandconnection.send("_MXMLLiveEditPluginCommands", "setValue", nodeID, attributeName, changedValues[attributeName]);
                }
            }

            for (nodeID in removals) {
                removedValues = removals[nodeID];
                trace(nodeID);

                for (attributeName in removedValues)
                {
                    trace(" - Attribute removed: " + attributeName);
                    //commandconnection.send("_MXMLLiveEditPluginCommands", "setValue", p, q, removedValues[q]);
                }
            }
        }
    ]]>
</fx:Script>

注意：可能有一个函数或变量丢失，因为我从一个更复杂的例子中复制了它。

注意：Ace编辑器正在查找匹配节点，如图所示，方法是在节点周围创建一个轮廓（见图片）。

有没有办法获得光标所在节点的分层索引？

2 个答案: