Question

我必须在xslt 1.0中将此GMT格式转换为EST。

  <Date>Mon, 11 Aug 2009 13:15:10 GMT</Date>

有没有这样做？

Answer 1

这是一个纯XSLT解决方案：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:my="my:my" >
 <xsl:import href=
  "C:\Program Files\Marrowsoft\Xselerator25\Samples\Libraries\datetime_lib.xsl"/>
 <xsl:output method="text"/>

 <xsl:param name="pnewZone" select="'EST'"/>

 <my:zones>
   <zone name="GMT" offset="+00:00"/>
   <zone name="EST" offset="-05:00"/>
 </my:zones>

 <xsl:template match="/">
   <xsl:variable name="vDay" select=
   "substring-before(substring-after(., ' '), ' ')
   "/>

   <xsl:variable name="vMonthName" select=
   "substring-before(substring-after(., concat($vDay, ' ')), ' ')
   "/>

   <xsl:variable name="vYear" select=
   "substring-before(substring-after(., concat($vMonthName, ' ')), ' ')
   "/>

   <xsl:variable name="vTime" select=
   "substring-before(substring-after(., concat($vYear, ' ')), ' ')
   "/>

   <xsl:variable name="vMonth" select=
   "substring-before(
       substring($default-month-names,
                 string-length(substring-before($default-month-names,
                                                $vMonthName)
                               )-2),
       ']'
                    )
    "/>


  <xsl:variable name="vZone"
   select="substring-after(., concat($vTime, ' '))"/>

  <xsl:variable name="vzoneOffset" select=
   "document('')/*/my:zones/*[@name=$vZone]/@offset"/>

  <xsl:variable name="vnewzoneOffset" select=
   "document('')/*/my:zones/*[@name=$pnewZone]/@offset"/>

  <xsl:variable name="vDateTimeUTC" select=
   "concat($vYear, '-', $vMonth, '-', $vDay, 'T', $vTime, 'Z', $vzoneOffset)"/>

  <xsl:call-template name="local-to-local">
    <xsl:with-param name="datetime" select="$vDateTimeUTC"/>
    <xsl:with-param name="local-offset" select="$vnewzoneOffset"/>
  </xsl:call-template>

 </xsl:template>
</xsl:stylesheet>

将此转换应用于提供的XML文档：

<Date>Mon, 11 Aug 2009 13:15:10 GMT</Date>

产生了所需的正确结果：

2009-08-11T08:15:10Z-05:00

请注意：

我正在使用Martin Rowlinson的datetime_lib.xsl模板库。此库是 XSelerator 的一部分，目前该库是免费产品，可以在SourceForge下载。
上述代码中的所有处理都是从导入的库中为local-to-local模板准备参数。
我在local-to-local中发现了一个错误并更正了。在第1143行替换以下内容：
```
<xsl:when test="($offset != 0) and ($new-offset != 0)">
```

与

    <xsl:when test="($offset != 0) or ($new-offset != 0)">

将结果转换为初始dateTime格式作为练习留给读者：）

xslt中的时区转换

1 个答案: