Question

我有一个XSLT 1.0 *样式表，它进行一些预处理并创建一个结果片段，其中包含一个元素列表<x>，每个元素都有两个子节点 - 然后调用<a>和<b>。

因此生成的列表如下所示：

<x><a>A-content</a><b>B-content</b></x>
<x><a>A-content</a><b>B-content</b></x>
...
<x><a>A-content</a><b>B-content</b></x>

然后我使用node-set（）将其转换为节点集，并使用apply-templates将所有<x>元素转换为输出表示。

到目前为止，非常好。

但我必须在输出模板上使用match="*"规则，虽然我可以使用"*[1]"和"*[2]"获取子元素，但我无法使用{{1}找到它们和"a" - 我得到一个空的结果。

位置语法作为一种解决方法，但它相当脆弱，我想将其更改为处理元素名称。此外，它不是非常易读。

我确实怀疑它可能是名称空间问题（"b"，<x>和<a>未在输入或输出文档的原始架构中定义），但至于当使用“*”选择元素时，我可以看到没有命名空间的装饰。

以防万一重要，我在cygwin下使用xsltproc（libxml 20902，libxslt 10128和libexslt 817）。

关于我可能做错了什么的想法，或者有关调试的提示？

（* - 我必须使用XSLT 1.0，因为它设计为在网络浏览器中运行。）

编辑：根据要求添加了示例

输入test.xml：

<b>

转换test.xslt：

<?xml version="1.0" encoding="utf-8"?>
<?xml-stylesheet href="test.xsl" type="text/xsl" ?>

<books>
    <book>
        <title>Diaspora</title>
        <author>Greg Egan</author>
    </book>

    <book>
        <title>2001</title>
        <author>Arthur C Clarke</author>
    </book>

    <book>
        <title>Eon</title>
        <author>Greg Bear</author>
    </book>
</books>

输出（来自msxslt和xsltproc的相同输出）：

<?xml version="1.0" encoding="utf-8"?>

<xsl:stylesheet version="1.0"
                xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                xmlns="http://www.w3.org/1999/xhtml"
                                xmlns:exslt="http://exslt.org/common"
                                xmlns:xalan="http://xml.apache.org/xalan"
                                xmlns:msxslt="urn:schemas-microsoft-com:xslt"
                                exclude-result-prefixes="xsl msxslt exslt xalan">
<!--    extension-element-prefixes="exslt"> -->

    <xsl:template match="books">
        <!-- Generate list -->
        <xsl:variable name="list">
            <xsl:apply-templates select="book" mode="phase1"/>
        </xsl:variable>

        <html>
            <head>
                <title>Books</title>
            </head>
            <body>
                <xsl:choose>
                    <xsl:when test="function-available('msxslt:node-set')">
                        <xsl:apply-templates select="msxslt:node-set($list)" mode="process-list"/>
                    </xsl:when>
                    <xsl:when test="function-available('exslt:node-set')">
                        <xsl:apply-templates select="exslt:node-set($list)" mode="process-list"/>
                    </xsl:when>
                    <xsl:when test="function-available('xalan:nodeset')">
                        <xsl:apply-templates select="xalan:nodeset($list)"  mode="process-list"/>
                    </xsl:when>
                    <xsl:otherwise>
                        <xsl:apply-templates select="$list" mode="process-list"/>
                    </xsl:otherwise>
                </xsl:choose>
            </body>
        </html>
    </xsl:template>

    <xsl:template match="book" mode="phase1">
        <!-- Actual transformation is more involved -->
        <xsl:element name="x">
            <xsl:element name="a">
                <b>
                    <xsl:value-of select="author/text()"/>
                </b>
            </xsl:element>
            <xsl:element name="b">
                <i>
                    <xsl:value-of select="title/text()"/>
                </i>
            </xsl:element>
        </xsl:element>
    </xsl:template>

    <xsl:template match="*" mode="process-list">
        <p>
            [<xsl:value-of select="*[1]"/>]
            [<xsl:value-of select="*[2]"/>]
            [<xsl:value-of select="a"/>]
            [<xsl:value-of select="b"/>]
        </p>
    </xsl:template>

</xsl:stylesheet>

Answer 1

我继续搜索并找到了解决方案。正如我们所怀疑的，这是一个名称空间问题 - 这里是描述它的previous post。

尽管我试图将新元素放在新的命名空间中，但它们仍然进入默认命名空间，我声明为：

xmlns="http://www.w3.org/1999/xhtml"

但是，这不是XPATH表达式中的默认值，因此未找到它。（次要问题 - 为什么不呢？）

解决方案是使用名称空间前缀重复声明默认名称空间：

xmlns:xhtml="http://www.w3.org/1999/xhtml"

并在xpath中明确使用该前缀：

[<xsl:copy-of select="xhtml:a"/>]
[<xsl:copy-of select="xhtml:b"/>]

然后一切都匹配，我从命名和基于位置的XPATH表达式获得相同的输出。

感谢大家充当声音板 - 我希望以后可以帮助别人。

Answer 2

我只能假设，您正在使用exslt扩展来创建节点集，我想您正在尝试设置多次传递转换：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:exsl="http://exslt.org/common"
                extension-element-prefixes="exsl">

<xsl:template match="/">
  <!-- create your first pass here -->
  <xsl:variable name="first-pass">
      <xsl:apply-templates mode="first-pass"/>
  </xsl:variable>
  <xsl:apply-templates select="exsl:node-set($first-pass)" mode="second-pass"/>
</xsl:template>

<!-- implementation of first-pass
    ....
 -->

<!-- second-pass: find a and b elements in x -->
<xsl:template match="x/a" mode="second-pass">
    <!-- your turn -->
</xsl:template>

<xsl:template match="x/b" mode="second-pass">
    <!-- your turn -->
</xsl:template>

<xsl:template match="@*|node()" mode="second-pass">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()" mode="second-pass"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="@*|node()" mode="first-pass">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()" mode="first-pass"/>
    </xsl:copy>
</xsl:template>

</xsl:stylesheet>

无法使用name在node-set（）结果中选择元素，但*找到它

2 个答案: