Question

我有一个perl脚本，它只保留命名集的最后一组记录，并且我有多组记录。所以它过度写入哈希中的数据并保持最后一组。我需要帮助打印出所有记录。谢谢！

这是我的脚本的副本：

#!/usr/local/bin/perl 

use strict;
use warnings;
use Data::Dumper;

my ($ServerName)=@ARGV;
my %MyItems;
foreach my $ServerName(@ARGV){
   while (my $line = <>){
     chomp $line;
              if ($line =~ m/.* \w+ \d{2} (\d{2}:\d{2}:\d{2}) \d{4}: ([^:]+):backup:/){
                  my $ServerName = basename $ARGV, '.mydomain.com.backup-software.log'; #$ARGV is reading input from command line
                  my $BckupSet =$2;
                  my $BckupVal=$1;
                  $MyItems{$ServerName}{$BckupSet}->{'1-Server'}    = $ServerName;
                  $MyItems{$ServerName}{$BckupSet}->{'2-BackupSet'} = $BckupSet;
                  $MyItems{$ServerName}{$BckupSet}->{'3-StartTime'} = $BckupVal;

                  if ($line =~ m/(backup-date)[:=](.+)/){
                      my $BckupKey="4-DateStamp";
                      my $BckupVal=$2;
                      $MyItems{$ServerName}{$BckupSet}->{$BckupKey} = $BckupVal;
                  }

                  if ($line =~ m/(backup-time)[:=](.+)/){
                      my $BckupKey="5-Duration";
                      my $BckupVal=$2;
                      $MyItems{$ServerName}{$BckupSet}->{$BckupKey} = $BckupVal;
                  }
                  if ($line =~ m/(backup-size)[:=](.+)/){
                      my $BckupKey="6-Size";
                      my $BckupVal=$2;
                      $MyItems{$ServerName}{$BckupSet}->{$BckupKey} = $BckupVal;
                  }
                  if ($line =~ m/(Backup succeeded)/){
                      my $BckupKey="7-Status";
                      my $BckupVal="Succeeded";
                      $MyItems{$ServerName}{$BckupSet}->{$BckupKey} = $BckupVal;
                  }
                  if ($line =~ m/(ERROR)[:=](.+)/){
                      my $BckupKey="8-Status";
                      my $BckupVal="Unsuccessful";
                      $MyItems{$ServerName}{$BckupSet}->{$BckupKey} = $BckupVal;
                      print "$BckupKey=$BckupVal\n" if debug;
                  }
              }
   } #endwhile
   print Dumper(\%MyItems);
   for my $ServerName(keys%MyItems){
     for my $BckupSet(keys%{$MyItems{$ServerName}}){
       for(sort keys%{$MyItems{$ServerName}{$BckupSet}}){
         #print$_,'=>',$MyItems{$ServerName}{$BckupSet}{$_},';';
         print$_,'=',$MyItems{$ServerName}{$BckupSet}{$_},';';
       }
       print"\n";
     }
   }
} #END foreach

以下是转储时的样子：

$VAR1 = {
          'server1.name.colo' => { 
                                        'set1' => {
                                                               '3-StartTime' => '07:08:15',
                                                               '1-Server' => 'server1.name.colo',
                                                               '6-Size' => '72.04 GB',
                                                               '7-Status' => 'Succeeded',
                                                               '4-DateStamp' => '20100820060002',
                                                               '5-Duration' => '01:08:13',
                                                               '2-BackupSet' => 'set1',
                                                               '8-Status' => 'Unsuccessful'
                                                             },
                                        'set2' => {
                                                                '7-Status' => 'Succeeded',
                                                                '6-Size' => '187.24 GB',
                                                                '3-StartTime' => '01:51:25',
                                                                '4-DateStamp' => '20100820000003',
                                                                '1-Server' => 'server1.name.colo',
                                                                '5-Duration' => '01:51:21',
                                                                '2-BackupSet' => 'set2'
                                                              },
                                        'set3' => {
                                                              '3-StartTime' => '23:00:05',
                                                              '4-DateStamp' => '20100814230003',
                                                              '1-Server' => 'server1.name.colo',
                                                              '8-Status' => 'Unsuccessful',
                                                              '2-BackupSet' => 'set3'
                                                            },
                                        'set4' => {
                                                              '7-Status' => 'Succeeded',
                                                              '6-Size' => '427.75 GB',
                                                              '3-StartTime' => '00:43:20',
                                                              '4-DateStamp' => '20100819200004',
                                                              '1-Server' => 'server1.name.colo',
                                                              '5-Duration' => '04:43:14',
                                                              '2-BackupSet' => 'set4'
                                                            },
                                        'set3' => {
                                                              '7-Status' => 'Succeeded',
                                                              '6-Size' => '46.42 GB',
                                                              '3-StartTime' => '04:42:59',
                                                              '4-DateStamp' => '20100820040002',
                                                              '1-Server' => 'server1.name.colo',
                                                              '5-Duration' => '00:42:56',
                                                              '2-BackupSet' => 'set3'
                                                            }
                                      }
        };

Answer 1

根据调试输出，看起来你的问题就在这里：

if ($line =~ m/(ERROR)[:=](.+)/){
    my $BckupKey="8-Status";
    my $BckupVal="Unsuccessful";
    $MyItems{$ServerName}{$BckupSet}->{$BckupKey} = $BckupVal;
    print "$BckupKey=$BckupVal\n" if debug;
}

要保存所有错误，您需要将该哈希槽视为对数组的引用：

if ($line =~ m/(ERROR)[:=](.+)/){
    my $BckupKey="8-Status";
    my $BckupVal="Unsuccessful";
    push @{ $MyItems{$ServerName}{$BckupSet}{$BckupKey} } => $BckupVal;
    print "$BckupKey=$BckupVal\n" if debug;
}

在您的转储中，8-Status值将类似于

'8-Status' => [ 'Unsuccessful', 'Other error', 'Et cetera' ],

如果你想稍后循环播放它们，你会做类似

的事情

foreach my $err (@{ $MyItems{$ServerName}{$BckupSet}{$BckupKey} }) {
    print "got $err\n";
}

要获得第一个，你要写

print $MyItems{$ServerName}{$BckupSet}{$BckupKey}[0], "\n";

另一个问题是

foreach my $ServerName(@ARGV){
   while (my $line = <>){

意识到while (<>) { ... }隐式循环遍历@ARGV中命名的所有文件，因此将其嵌套在@ARGV上的循环中并不是很有意义。如果您的命令行的格式为

$ readlogs server1 server2 server3 log1 log2

然后您要先使用shift从@ARGV服务器中删除服务器。区分用户打算作为服务器主机名的参数可能很棘手。一种惯例是使用--来表示选项处理的结束，因此您可能

my @servers;
while (@ARGV) {
  my $server = shift;
  last if $server eq "--"
  push @servers => $server;
}

die "Usage: $0 server .. -- log ..\n" unless @ARGV;

while (<>) {
  # ...
}

Answer 2

这是偏离主题的，但是只要您需要深层嵌套的数据结构，您的代码就会面临变得臃肿和难以阅读的风险。简单的便利变量在简化事物和减轻代码的读者（你，3个月后）必须执行许多精神差异方面有很长的路要走：

# A convenience var.
my $bs = $MyItems{$ServerName}{$BckupSet};

# The rest of your code can use the var.
$bs->{'1-Server'} = $ServerName;

另外，你有几个基本相同的if块。似乎可以采用某种调度表策略：

my @dispatch_table = (
    {
        regex => qr/(backup-date)[:=](.+)/,
        key   => '4-DateStamp',
        val   => sub { $2 },
    },
    {
        # etc.
    },
);

然后你的if块会归结为类似的东西：

for my $dt (@dispatch_table){
    next unless $line =~ $dt->{regex};
    $bs->{ $dt->{key} } = $dt->{val}->();
}

perl - 帮助哈希和转储记录

2 个答案: