Question

我正在尝试使用FParsec解析文件，其中包含float或int值。我面临两个问题，我找不到一个好的解决方案。

1

pint32和pfloat都会成功解析相同的字符串，但会给出不同的答案，例如pint32在解析字符串3时会返回"3.0"并且解析相同的字符串时，pfloat将返回3.0。是否可以尝试使用pint32解析浮点值，如果字符串为"3.0"则会失败？

换句话说，有没有办法使下面的代码工作：

let parseFloatOrInt lines =
    let rec loop intvalues floatvalues lines =
        match lines with
        | [] -> floatvalues, intvalues
        | line::rest ->
            match run floatWs line with
            | Success (r, _, _) -> loop intvalues (r::floatvalues) rest
            | Failure _ -> 
                match run intWs line with
                | Success (r, _, _) -> loop (r::intvalues) floatvalues rest
                | Failure _ -> loop intvalues floatvalues rest

    loop [] [] lines

这段代码会正确地将所有浮点值放在floatvalues列表中，但因为pfloat在解析字符串"3.0"时返回"3"，所有整数值都将也可以放在floatvalues列表中。

2

上面的代码示例对我来说似乎有点笨拙，所以我猜测必须有更好的方法来做到这一点。我考虑过使用choice组合它们，但是两个解析器必须返回相同的类型才能工作。我想我可以使用一个float选项和一个int选项进行区分联合，并使用pint32运算符转换pfloat和|>>的输出。但是，我想知道是否有更好的解决方案？

Answer 1

您正在考虑定义域数据并将解析器的定义与源数据上的用法分开。这似乎是一种很好的方法，因为随着您的真实项目的进一步发展，您可能需要更多的数据类型。

以下是我的写作方式：

/// The resulting type, or DSL
type MyData =
    | IntValue of int
    | FloatValue of float
    | Error  // special case for all parse failures

// Then, let's define individual parsers:
let pMyInt =
    pint32
    |>> IntValue

// this is an alternative version of float parser.
// it ensures that the value has non-zero fractional part.
// caveat: the naive approach would treat values like 42.0 as integer
let pMyFloat =
    pfloat
    >>= (fun x -> if x % 1 = 0 then fail "Not a float" else preturn (FloatValue x))
let pError =
    // this parser must consume some input,
    // otherwise combined with `many` it would hang in a dead loop
    skipAnyChar
    >>. preturn Error

 // Now, the combined parser:
let pCombined =
    [ pMyFloat; pMyInt; pError ]    // note, future parsers will be added here;
                                    // mind the order as float supersedes the int,
                                    // and Error must be the last
    |> List.map (fun p -> p .>> ws) // I'm too lazy to add whitespase skipping
                                    // into each individual parser
    |> List.map attempt             // each parser is optional
    |> choice                       // on each iteration, one of the parsers must succeed
    |> many                         // a loop

注意，上面的代码能够处理任何来源：字符串，流或其他任何来源。您的真实应用可能需要使用文件，但只需使用string list即可简化单元测试。

// Now, applying the parser somewhere in the code:
let maybeParseResult =
    match run pCombined myStringData with
    | Success(result, _, _) -> Some result
    | Failure(_, _, _)      -> None // or anything that indicates general parse failure

UPD。我根据评论编辑了代码。 pMyFloat已更新，以确保解析后的值具有非零小数部分。

使用FParsec

1 个答案: