Question

如何在Prolog中模拟此代码？

// L = an existing list ; 
// function foo(var X, var Y)
result = new List();
for(int i=0;i<L.length;i++)
    for(int j=0;j<L.length;j++){
        result.add(foo(L.get(i), L.get(j));
    }

Answer 1

嵌套循环基本上是序列之间的连接，并且Prolog中的大多数列表处理最好在没有索引的情况下表达：

?- L=[a,b,c], findall(foo(X,Y), (member(X,L),member(Y,L)), R).
L = [a, b, c],
R = [foo(a, a), foo(a, b), foo(a, c), foo(b, a), foo(b, b), foo(b, c), foo(c, a), foo(c, b), foo(..., ...)].

修改的

有时整数允许以简单的方式捕获含义。作为一个例子，我的解决方案是一个更简单的Prolog上下文测验。

icecream(N) :-
    loop(N, top(N)),
    left, loop(N+1, center), nl,
    loop(N+1, bottom(N)).

:- meta_predicate loop(+, 1).

loop(XH, PR) :-
    H is XH,
    forall(between(1, H, I), call(PR, I)).

top(N, I) :-
    left, spc(N-I+1), pop,
    (   I > 1
    ->  pop,
        spc(2*(I-2)),
        pcl
    ;   true
    ),
    pcl, nl.

bottom(N, I) :-
    left, spc(I-1), put(\), spc(2*(N-I+1)), put(/), nl.

center(_) :- put(/), put(\).

left :- spc(4).
pop :- put(0'().
pcl :- put(0')).
spc(Ex) :- V is Ex, forall(between(1, V, _), put(0' )).

在SWI-Prolog中运行：

?- icecream(3).
       ()
      (())
     ((  ))
    /\/\/\/\
    \      /
     \    /
      \  /
       \/
true.


?- forall(loop(3,[X]>>loop(2,{X}/[Y]>>writeln(X-Y))),true).
1-1
1-2
2-1
2-2
3-1
3-2
true.

Answer 2

您可以轻松定义forto/4元谓词。一个示例，取自Logtalk库loop对象：

:- meta_predicate(forto(*, *, *, 0)).
forto(Count, FirstExp, LastExp, Goal) :-
    First is FirstExp,
    Last is LastExp,
    forto_aux(Count, First, Last, 1, Goal).

:- meta_predicate(forto_aux(*, *, *, *, 0)).
forto_aux(Count, First, Last, Increment, Goal) :-
    (   First =< Last ->
        \+ \+ (Count = First, call(Goal)),
        Next is First + Increment,
        forto_aux(Count, Next, Last, Increment, Goal)
    ;   true
    ).

示例目标：

?- loop::forto(I, 1, 2, loop::forto(J, 1, 3, (write(I-J), nl))).
1-1
1-2
1-3
2-1
2-2
2-3
true.

一些Prolog编译器还为具有良好表现力的“逻辑循环”提供内置或库支持。例子是（按字母顺序）B-Prolog，ECLiPSe和SICStus Prolog。有关详细信息，请查看这些系统的文档。如果您需要跨大多数Prolog系统的便携式解决方案，请查看Logtalk的库文档。或者简单地采用上面的例子并定义你自己的循环元谓词。

Answer 3

你可以使用 SICStus-prolog 来使用这个谓词来循环变量I,J直到N并将所有这些变量连续到下面提到的事实foo/2中; < / p>

<强>代码

loop(N) :- for(I,0,N),param(N) do
               for(J,0,N),param(I) do 
                      write(foo(I,J)),nl.

<强>结果

| ?- loop(2).
foo(0,0)
foo(0,1)
foo(0,2)
foo(1,0)
foo(1,1)
foo(1,2)
foo(2,0)
foo(2,1)
foo(2,2)
yes

如何在prolog中模拟嵌套循环？

3 个答案: