Question

所以我正在尝试重新实现reduce方法，因此它可以添加一些通常可以使用reduce完成的数字，例如：

(reduce + [1 2 3]) ;; 6
(newRd + [1 2 3])  ;; 6

所以我想也许可以使用递归函数来完成，每次调用时都会添加向量的第一个元素，并为向量的其余部分再次执行。像这样：

(defn newRd [list]
  (let [sum 0]
    (if (not= 0 (count list))
      (+ sum (first list))
      (newRd (rest list))
      )
    )
  )

我认为我没有正确地进行本地存储。任何建议或更好的方法？

Answer 1

您的代码中存在两个错误：

1）您不能将当前金额添加到递归调用结果

2）当列表为空时你应该返回零

更正的变体：

(defn newRd [list]
  (let [sum 0]
    (if (not= 0 (count list))
      (+ sum (first list)
         (newRd (rest list)))
      sum)))

在repl中：

user> (newRd [1 2 3 4])
10

接下来，您可以稍微更新一下：

首先，您并不需要let语句中的总和，因为sum总是= 0

第二，有一个lib函数empty?来检查列表是否为空。

(defn newRd [list]
  (if-not (empty? list)
    (+ (first list)
       (newRd (rest list)))
    0))

但请记住：clojure不会进行尾部调用优化，因此很容易导致堆栈功能流有很长的列表：

user> (newRd (repeat 1000000 1))
StackOverflowError   user/newRd (form-init289434844644272272.clj:73)

所以最好使用loop / recur

(defn sum-list [list]
  (loop [list list sum 0]
    (if (empty? list)
      sum
      (recur (rest list) (+ sum (first list))))))

在repl中：

user> (sum-list (repeat 1000000 1))
1000000

另一个选择是使函数本身尾递归：

(defn newRd [list sum]
  (if-not (empty? list)
    (recur (rest list) (+ sum (first list)))
    sum))

user> (newRd (repeat 1000000 1) 0)
1000000

然后你可以添加additoinal arity，以便不在每次调用中传递第二个参数：

(defn newRd
  ([list] (newRd list 0))
  ([list sum]
   (if-not (empty? list)
     (recur (rest list) (+ sum (first list)))
     sum)))

Answer 2

继leetwinksi's answer ...

之后

一般来说，您也可以实施new-reduce（驼峰案例不是惯用语）：

(defn new-reduce
  ([f init coll]
   (if (seq coll)
     (recur f (f init (f init (first coll))) (rest coll))
     init))
  ([f coll]
   (if (seq coll)
     (reduce f (first coll) (rest coll))
     (f))))

然后

(new-reduce + [1 2 3]) ;; 6

这或多或少是reduce的源代码，直到最近，如果你剥离了分块。

您使用的双参数版本倾向于三参数版本，您可以recur直接使用该版本，而不使用明确的loop。这需要每次都传递f，但这是过去的事情。据推测，携带额外参数比在本地范围内工作更快。

添加Vector的元素而不使用`reduce`或`apply`

2 个答案: