Question

如果计算时间过长，我想中断通话，比如

try
   do_something ()
with Too_long -> something_else ()

是否有可能在OCaml中做类似的事情？可能不会修改函数do_something。

Answer 1

一般来说，中断函数的唯一方法是使用信号，正如Basile建议的那样。不幸的是，控制流将被转移到信号处理程序，因此您将无法返回您喜欢的值。要获得更精细的控件，可以在单独的线程中运行do_something。第一个近似值是以下函数：

exception Timeout

let with_timeout timeout f =
  let result = ref None in
  let finished = Condition.create () in
  let guard = Mutex.create () in
  let set x =
    Mutex.lock guard;
    result := Some x;
    Mutex.unlock guard in
  Mutex.lock guard;
  let work () =
    let x = f () in
    set x;
    Condition.signal finished in
  let delay () =
    Thread.delay timeout;
    Condition.signal finished in
  let task = Thread.create work () in
  let wait = Thread.create delay () in
  Condition.wait finished guard;
  match !result with
  | None ->
    Thread.kill task;
    raise Timeout
  | Some x ->
    Thread.kill wait;
    x

具有线程和信号功能的解决方案有一些缺点。例如，线程在OCaml中在特定的中断点中切换，通常这是任何分配。因此，如果您的代码没有执行任何分配或外部调用，那么它可能永远不会屈服于其他线程并将永远运行。这种功能的一个很好的例子是let rec f () = f ()。在这种情况下，你应该在另一个进程而不是线程中运行你的函数。在OCaml中有许多用于多处理的库，仅举几例：

Answer 2

没有内置工具在标准库中执行此精确操作，但实现起来相当简单。使用Thread模块，运行一个线程来执行主程序和一个监视线程，如果它持续太长时间将终止程序。这是一个开始实现：

type 'a state =
    | Running
    | Finished of 'a
    | Failed of exn
    | Cancelled of 'a

let bounded_run d f g x =
    let state = ref Running in
    let p = ref None in
    let m = ref None in
    let cancel t' = match !t' with
      | Some(t) -> Thread.kill t
      | None -> ()
    in
    let program () =
      (try state := Finished(f x)
       with exn -> state := Failed (exn));
      cancel m;
    in
    let monitor () =
      Thread.delay d;
      match !state with
        | Running -> cancel p; state := Cancelled(g x)
        | _ -> ()
    in
    p := Some(Thread.create program ());
    m := Some(Thread.create monitor p);
    (match !m with
      | None -> ()
      | Some(t) -> Thread.join t);
    !state

调用bounded_run d f g x最多f x秒运行d，如果计算在给定时间内运行，则返回Finished(f x)。如果计算抛出异常，它可能会返回Failed(exn)。当计算持续时间过长时，返回的值为Cancelled(g x)。

此实现有许多默认值，例如，状态和返回值应该具有不同的类型（返回类型中不应该值Running），它不使用互斥锁来防止并发访问p和m变量保存对我们使用的线程的引用。虽然边缘粗糙，但这应该可以帮助您入门，但是为了更高级的使用，您还应该学习事件或第三方库，例如Lwt或Async - 前者需要您更改功能。

Answer 3

^{（我猜你在Linux上）}

详细了解signal(7) - s。您可以将Ocaml的Sys.signal用于Sys.sigalarm和Unix模块（尤其是Unix.setitimer）

中断OCaml中的呼叫

3 个答案: