Question

我为系统创建OTP令牌的方案。所以我试图通过以下方式使用种子随机函数。

Public Shared Function generateOTP(seed As Integer) As Integer
    Dim rand As Random
    rand = New Random(seed)
    Return rand.Next(100000, 999999)
End Function

按照我的预期，它的工作正常。当我传递一个值为10时，它总是返回相同的6位数字。

但我的问题是，是否有可能为不同的数字生成相同的随机数？另一个问题是，在运行应用程序的所有计算机中，随机数对于相同的数字是否相同。我的意思是随机函数与种子有任何处理器依赖或时间依赖性？

Answer 1

I've a scenario to create OTP token for a system

如果是这种情况，我不明白你为什么要使用同一套random。也许它适用于双方系统，因此您需要服务器和客户端使用相同的值？如果是这样，请继续阅读。

已经存在一次性密码算法（RFC4226）。这里的所有帖子都是C＃和/或粗略（ ...已经创建了foo和bar，对于第4步执行此操作:(某些代码））。我找不到一个以与RFC要求相同的方式对令牌/值进行编码的方法。

对下面列出的参考文献提供一些提示，帮助和更改，主要基于RFC附录C，这是一个VB版本。

请注意，RFC描述了一个双方系统。客户端从共享密钥生成OTP（忽略矛盾）和移动值＆＃34;或价值序列。然后，服务器可以使用密钥和下一个值进行验证。如果它有效，则它将计数器移动到系列中的下一个。显然，这些OTP会立即被使用，否则服务器无法验证客户B，直到客户A被兑换成＃34;

似乎没有人对这部分感兴趣，只是关于用6位数表示散列并且复制机率很低的部分。 RFC也有一个支票数字的规定，似乎没有人感兴趣。

这个主要还是对6位哈希的核心动作感兴趣，因此不符合RFC4226标准。可以添加从一系列值中获取值的方面。

Partial Public Class CryptoTools
    Private Const TicksPerSec = 10000000
    Private Const TicksPerMilli = 10000

    ' generate your own key
    Private Shared SecretKey As String = "PoNodJHz4jjVG6...UuiIvmA=="

秘密密钥将在后面描述。（这个评论真的是为了减少缩进。）

Public Shared Function GetOneTimePass(somevalue As UInt64,
                                     Optional size As Int32 = 6) As String
    ' undo how the key was made
    Dim Key() As Byte = Convert.FromBase64String(SecretKey)
    Dim hashData As Byte()

    ' encode the value to Data...called text[] in RFC
    ' this part seems missing in most SO answers
    Dim Data(7) As Byte
    For n As Int32 = Data.Length - 1 To 0 Step -1
        Data(n) = CByte(CLng(somevalue) And &HFF)
        somevalue = somevalue >> 8
    Next

    ' create hasher with our key; hash
    Using hasher As New HMACSHA1(Key)
        hashData = hasher.ComputeHash(Data)
    End Using

    ' THIS is the part everyone likes
    ' see links and http://tools.ietf.org/html/rfc4226#section-5.4
    Dim offset = hashData(hashData.Length - 1) And &HF
    Dim binCode = (hashData(offset) And &H7F) << 24 Or
                (hashData(offset + 1) And &HFF) << 16 Or
               (hashData(offset + 2) And &HFF) << 8 Or
               (hashData(offset + 3) And &HFF)

    Dim otp As UInt64
    ' RFC: 6 is minimim size, 10 is my max
    Dim sz = If(size < 6, 6,
               If(size > 10, 10, size))

    otp = Convert.ToUInt64(binCode Mod Math.Pow(10, sz))

    ' optional check digit
    ' no one seems to implement; not included
    Dim check = CalculateCheckSum(otp, size)
    'Return otp.ToString().PadLeft(sz, "0"c) & String.Format("-{0}", check.ToString)
    ' pad to minimum length

    ' work in progress: only works out to 7 chars
    'Console.WriteLine(ConvertToBase26(otp))

    Return otp.ToString().PadLeft(sz, "0"c)
End Function

Public Shared Function GetTimeToken() As UInt64
    Dim t As UInt64 = Convert.ToUInt64(DateTime.Now.Ticks / TicksPerMilli)
    Return t
End Function

Public Shared Function GetRandomUInt64() As UInt64
    Dim rBytes(7) As Byte
    Using crng As New RNGCryptoServiceProvider()
        crng.GetBytes(rBytes)
        Return BitConverter.ToUInt64(rBytes, 0)
    End Using
End Function

用法：

Dim token As UInt64 = CryptoTools.GetTimeToken()
Dim otp As String = CryptoTools.GetOneTimePass(token)

Dim rToken As UInt64 = CryptoTools.GetRandomUInt64()
Dim otp As String = CryptoTools.GetOneTimePass(rToken)

备注

HMACSHA1 hasher的密钥的建议大小为64字节。要创建密钥，请使用RNGCryptoServiceProvider创建一个包含64个随机字节的数组，然后Convert.ToBase64String()。
这需要UInt64。对于一个真实的＆＃34; 2方4226版本，该值应该是值序列中的下一个。否则...
价值可以来自任何地方：它可以是时间或随机数。 GetTimeToken()是一个实用函数，可以将时间作为UInt64。 GetRandomUInt64()会返回加密随机UInt64以用作起始值。
上面的大多数SO链接似乎都不像RFC所要求的那样编码值/时间/数据，如果有的话。一篇文章提到添加盐。但是根据RFC 4226附录C对传递的值进行编码似乎对结果至关重要（这可能解释了盐）。
我只运行了2000多次迭代，但是没有看到过任何欺骗行为（即使价值仅相差一毫秒）。
RFC规定了最低6位数，这可以实现，但可以更长。这允许6-10位数，但超过6位很难读，考虑插入8或更多的分隔符。

RFC指出，HOTP值仅为数字（第4节）是理想的。不是不能是字母数字。就个人而言，似乎如果结果以WYQ77-8WYB9的形式编码，那将更容易（除了可能在手机上）。我无法将结果转换为超过7个字符。

如前所述，这不符合RFC4226，就像它一样。测试它死了。它看起来是正确的，似乎是正确的，它与其他版本和/或RFC相匹配，但是按原样显示。

添加了GetRandomUInt64()和GetTimeToken()方法。

参考文献：

RFC 4226特别参见第4,5节和附录C
A java variant
SO: How can you generate OTP ... that can be authenticated on client答案类型从中间开始
SO: How do I generate One time passwords (OTP / HOTP)?
MSDN: HMACSHA1 Class
MSDN: RNGCryptoServiceProvider Class

Answer 2

是否有可能为不同的数字生成相同的随机数？

是的，底层算法可以在较新的.NET版本中更改，因此在更新后将生成另一个序列

所有计算机中相同数字的随机数是否相同？

如果所有计算机都使用相同的库版本 - 是的。

有一点需要注意：标准随机没有额外的“熵线程”。一些库将启动额外的线程，这将重新播种随机状态，并且这个状态被混合到种子值中（因此，即使对于相同的种子，也会有不同的序列）

使用Random作为一次性密码令牌的基础

2 个答案:

用法：

备注