Question

我试图找出如何从XML中的节点提取一些信息，其中信息在第2和第3之间＆＃34; |＆＃34;在答案中...... 因为所包含的单词的长度可以在长度上变化，所以唯一的常数是＆＃34; |＆＃34;

<root>
  <item>Apple|Pear|Orange|fig|Cherry|Banana</item>
</root>

我已经看过类似主题here的这个例子，但它并没有完全回答在两个已知字符之间找到第n个字符的情况。

所以我想找到＆＃34; Orange＆＃34;作为我的答案，无论你将其他名称更改为数组的其余部分。

Answer 1

对于 n 的较低值（例如示例中的3），您可以使用：

<xsl:value-of select="substring-before(substring-after(substring-after(item, '|'), '|'), '|')"/>

对于较高的 n 值或预先未知的值，您可以必须调用一个命名的递归模板：

<xsl:template name="get-Nth-value">
    <xsl:param name="list"/>
    <xsl:param name="N"/>
    <xsl:param name="delimiter" select="'|'"/>
    <xsl:choose>
        <xsl:when test="$N = 1">
            <xsl:value-of select="substring-before(concat($list, $delimiter), $delimiter)"/>
        </xsl:when>
        <xsl:when test="contains($list, $delimiter) and $N > 1">
            <!-- recursive call -->
            <xsl:call-template name="get-Nth-value">
                <xsl:with-param name="list" select="substring-after($list, $delimiter)"/>
                <xsl:with-param name="N" select="$N - 1"/>
                <xsl:with-param name="delimiter" select="$delimiter"/>
            </xsl:call-template>
        </xsl:when>
    </xsl:choose>
</xsl:template>

电话示例：

<xsl:template match="item">
    <xsl:copy>
        <xsl:call-template name="get-Nth-value">
            <xsl:with-param name="list" select="."/>
            <xsl:with-param name="N" select="3"/>
        </xsl:call-template>    
    </xsl:copy>
</xsl:template>

如果您的处理器支持，您可以使用EXSLT str:tokenize()扩展功能：
```
<xsl:value-of select="str:tokenize(item, '|')[3]" />
```

在第n个特殊字符出现之间提取文件

1 个答案: