Question

几乎准备好放弃这一个。 :(对任何新的想法或调整开放。

我有.txt文件列出.pdf文件。 无路径..只是文件名。对于每个.pdf，请查看源文件夹**和子目录中的比赛。如果匹配，则将.pdf复制到目标文件夹。 **源文件夹中的某些子目录在名称中有空格。

我的脚本：

for /f %%i in (File-List.txt) do echo F| xcopy "C:\Source_Folder\%%i"  "c:\Target\%%i"  /i /z /y

结果： 它正在查找.pdf文件，但只搜索源中的第一个目录..不是子目录？

Answer 1

@echo off
setlocal EnableDelayedExpansion

rem Create a list of subdirectories to search separated by semicolon (like PATH variable)
set "subdirs=C:\Source_Folder"
for /D /R "C:\Source_Folder" %%d in (*) do set "subdirs=!subdirs!;%%d"

rem For each .pdf in the text file
for /F "delims=" %%f in (File-List.txt) do (

   rem Look in the list of subdirectories for a match
   rem see HELP FOR for further details
   for %%p in ("%%f") do set "filePath=%%~$subdirs:p"

   rem If match found
   if defined filePath (
      rem Copy .pdf over to destination folder
      copy "!filePath!" "c:\Target"
   )

)

Answer 2

@ECHO OFF
SETLOCAL
SET "sourcedir=U:\sourcedir"
SET "targetdir=U:\destdir"

FOR /f %%a IN ("%sourcedir%") DO SET "drive=%%~da"

for /f "delims=" %%i in (q34868638.txt) do (
REM attrib /s "%sourcedir%\%%i"
 FOR /f "tokens=1*delims=:" %%a IN ('attrib /s "%sourcedir%\%%i"') DO (
  IF "%%a"=="File not found - %drive:~0,1%" (ECHO "%%i" NOT found) ELSE (
  ECHO copy /b "%drive%%%b"  "%targetdir%\"
  )
 )
)

GOTO :EOF

您需要更改sourcedir和targetdir的设置以适合您的具体情况。

我使用了一个名为q34868638.txt的文件，其中包含一些数据供我测试。您使用的文件名取决于您。

为了测试目的，所需的COPY命令仅为ECHO。 在您确认命令正确后，将ECHO(COPY更改为COPY以实际复制文件。附加>nul以取消报告消息（例如1 file copied）

批量使用.txt文件将文件从源复制到目标

2 个答案: