Question

我正在开发一个基于Java的xsl-transformation（XSLT 2.0，如果有一个免费的Java处理器，也可能是XSLT 3.0），它具有不同的输入xml文件。一个输入文件可能如下所示：

<?xml version="1.0" encoding="UTF-8"?>
<TEST>
    <MyElement>
        <CHILD>A</CHILD>
        <CHILDBEZ>ABEZ</CHILDBEZ>
        <NotInteresting></NotInteresting>
    </MyElement>
    <MyElement>
        <CHILD>B</CHILD>
        <CHILDBEZ>BBEZ</CHILDBEZ>
        <NotInteresting2></NotInteresting2>
    </MyElement>
</TEST>

我想复制除“NotInteresting”之外的所有元素，并根据我从映射文件中获取的两个参数重命名两个节点CHILD和CHILDBEZ：

xpath表达式告诉我感兴趣的文本放在哪里（在这种情况下：TEST / MyFirstElement / CHILD和TEST / MyFirstElement / CHILDBEZ）
以及它们在输出文件中应具有的元素名称（在本例中为：childName和childBez）

映射文件：

<?xml version="1.0" encoding="UTF-8"?>
<element root="TEST">
    <childName>TEST/MyElement/CHILD</childName>
    <childBez>TEST/MyElement/CHILDBEZ</childBez>
</element>

期望的输出：

<TEST>
    <MyElement>
        <childName>A</childName>
        <childBez>ABEZ</childBez>
    </MyElement>
    <MyElement>
        <childName>B</childName>
        <childBez>BBEZ</childBez>
    </MyElement>
</TEST>

到目前为止：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:transform version="2.0 "
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
    xmlns:xsd="http://www.w3.org/2001/XMLSchema" xmlns="http://www.apoverlag.at"
    xmlns:apo="http://www.apoverlag.at">

    <xsl:variable name="vars" select="document('mapping.xml')"/>
    <xsl:param name="src" />
     <xsl:variable name="path" xpath-default-namespace="" select="$src/path"/> <!-- = TEST/*-->

    <xsl:template match="/">
        <xsl:for-each select="$path">
            <xsl:call-template name="buildNode">
                <xsl:with-param name="currentNode" select="current()"></xsl:with-param>
            </xsl:call-template>
        </xsl:for-each>
    </xsl:template>


    <xsl:template name="buildNode">
        <xsl:param name="currentNode" />
        <xsl:element name="test">
            <xsl:for-each select="$vars/element/@root">
                <xsl:for-each select="$vars/element/*">
                    <xsl:element name="{name(.)}"> <xsl:value-of select="concat($currentNode,'/',current())" /> 
                        </xsl:element>
                </xsl:for-each>
            </xsl:for-each>
        </xsl:element>
    </xsl:template>
</xsl:transform>

我的问题是：

<xsl:value-of select="concat($currentNode,'/',current())" />

当我尝试硬编码时，

给了我“/ TEST / MyFirstElement / CHILD”：

<xsl:value-of select="$currentNode/CHILD" />

我收到了我想要的输出。谁能给我一个如何解决这个问题的提示？

Answer 1

我建议采用完全不同的方法。为简化起见，我使用了一个带有完整路径的映射文档（从/根节点开始）：

映射xml

<element root="TEST">
    <childName>/TEST/MyElement/CHILD</childName>
    <childBez>/TEST/MyElement/CHILDBEZ</childBez>
</element>

XSLT 2.0

<xsl:stylesheet version="2.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:param name="mapping" select="document('mapping.xml')"/>
<xsl:key name="map" match="*" use="." />

<xsl:template match="/">
    <xsl:variable name="first-pass">
        <xsl:apply-templates mode="first-pass"/>
    </xsl:variable>
    <xsl:apply-templates select="$first-pass/*"/>
</xsl:template>

<xsl:template match="*" mode="first-pass">
    <xsl:param name="parent-path"/>
    <xsl:variable name="path" select="concat($parent-path, '/', name())" />
    <xsl:variable name="replacement" select="key('map', $path, $mapping)" />
    <xsl:element name="{if ($replacement) then name($replacement) else name()}">
        <xsl:attribute name="original" select="not($replacement)"/>
        <xsl:apply-templates mode="first-pass">
            <xsl:with-param name="parent-path" select="$path"/>
        </xsl:apply-templates>
    </xsl:element>
</xsl:template>

<xsl:template match="*">
    <xsl:copy>
        <xsl:apply-templates/>
    </xsl:copy>
</xsl:template>

<xsl:template match="*[@original='true' and not(descendant::*/@original='false')]"/>

</xsl:stylesheet>

结果，当应用于提供的输入时：

<?xml version="1.0" encoding="UTF-8"?>
<TEST>
   <MyElement>
      <childName>A</childName>
      <childBez>ABEZ</childBez>
   </MyElement>
   <MyElement>
      <childName>B</childName>
      <childBez>BBEZ</childBez>
   </MyElement>
</TEST>

带有变量的XSLT 2.0 XPATH表达式

1 个答案: