Question

对于DigitalMicrograph中的字符串变量，我们可以使用＆＃34; find＆＃34;找到特定模式的位置。功能：

Number find( String str, String sub_str )

我想用图像数据做同样的事情。例如，我可以使用

创建图像

image img := exprsize(1024, icol);

我希望找到的模式是

image pattern := exprsize( 15, icol+64 );

在上面的例子中，我们知道了w.r.t模式的偏移量。数据在第64列。一个真实的案例我们不会有这样一个简单的模式（即一条直线）。一个残酷的力量方法与'＃34;为＆＃34;循环肯定会工作，但当数据量越来越大时，它会变得非常缓慢。任何人都有更好/更优雅的建议？ 1D图像可能更容易，2D图像怎么样？

非常感谢！

Answer 1

鉴于您正在有效地寻找与数字数据的精确匹配，那么明智地使用图像表达式可能是解决方案的最有效途径。大致按照您的示例，我们首先设置源数据和目标模式：

Image sourceData := RealImage("Source data", 4, 4096);
sourceData = Random();

Image targetPattern := RealImage("Target pattern", 4, 15);
targetPattern = sourceData.Index(icol + 1733, 0);

然后我们准备一个精心安排的搜索缓冲区，其中包含一个图像表达式：

Number targetSize = targetPattern.ImageGetDimensionSize(0);
Number searchBufferW = sourceData.ImageGetDimensionSize(0) - targetSize;
Image searchBuffer := RealImage("Search buffer", 4, searchBufferW, targetSize);
searchBuffer = sourceData.Index(icol + irow, 0);

这将源数据的所有潜在匹配子集排列在2D图像的垂直列中。最后，我们进行一些小图像数学运算，找到与目标模式的匹配（如果存在）：

searchBuffer = Abs(searchBuffer - targetPattern.Index(irow, 0));
Image projectionVector := targetPattern.ImageClone();
projectionVector = 1.0;
Image searchResult := projectionVector.MatrixMultiply(searchBuffer);

Number posX, posY;
Number wasFound = (searchResult.Min(posX, posY) == 0);
String resultMsg = (wasFound) ? "Pattern found at " + posX : "Pattern not found";
OKDialog(resultMsg);

第一行将在与目标模式匹配的搜索缓冲区列的每个像素中产生精确的零。垂直求和搜索缓冲区并使用Min（）函数找到零可以加速搜索匹配。

注意使用MatrixMultiply（）进行快速垂直和投影。这仅适用于Real（4字节浮点）类型的源数据。但是，快速数据投影的方法稍微复杂一些，这也会为任何数字数据类型提供相当快速的结果。

虽然在1D数据集中对1D模式进行了说明，但是通过使用多维搜索缓冲区和使用ImageDataSlice对象的更高级索引，这种方法可以扩展到2D和3D数据集中的1D和2D模式，但是将是另一个问题的主题。

Answer 2

正如迈克指出的那样，互相关是在存在噪声的情况下搜索模式的好方法。但是，在没有噪音的情况下进行搜索甚至更好（如果不是完美的方法）！这将在1D和2D中用于脚本编写。见下文

number sx = 1024
number sy = 1024
number pw = 32
number ph = 32
number px = 100 // trunc( random()*(sx-pw) )
number py = 200 // trunc( random()*(sy-ph) )

image test := RealImage("Data",4,sx,sy)
test = random()
image pattern := test[py,px,py+ph,px+pw].ImageClone()
//test.showimage()
//pattern.showimage()
image patternSearch = test*0
patternSearch[0,0,ph,pw] = pattern
//patternSearch.ShowImage()

image corr := CrossCorrelate(test,patternSearch)
corr.ShowImage()
number mx,my,mv
mv = max(corr,mx,my)
mx -= trunc(sx/2)       // because we've placed the pattern in the 
my -= trunc(sy/2)       // top/left of the search-mask
Result("\n Pattern = " + px + " / " + py )
Result("\n max = " + mv + " at " + mx + "/" + my )

image found = test*0
found[my,mx,my+ph,mx+pw]=pattern
rgbImage overlay = RGB((test-found)*256,found*256,0)
overlay.ShowImage()

如果您的问题只有1D并且您拥有非常大的数据，那么另一种方法可能会为您提供更快速的解决方案。然后，我建议尝试使用RAW数据流（通过TagGroup Streaming命令）并使用您拥有的任何其他信息来调整搜索，即仅搜索流中模式的开头，然后仅验证＆＃ 34;打＆＃34;等

此处添加的注释用于解决有关一维图像中搜索模式的问题。如果我们运行以下脚本几次，那么我们就会发现它在大约50％的时间内无法正确找到模式。

number sx = 1024
number sy = 0
number pw = 16
number ph = 0
number px = trunc( random()*(sx-pw) )
number py = 0 // trunc( random()*(sy-ph) )

image test := RealImage("Data",4,sx );
test = random();
image patternSearch := exprsize( sx, icol<pw? test[icol+px, irow]: 0 );
// test.ShowImage();
// patternSearch.ShowImage();
patternSearch.SetName( "PatternSearch" );
//

image corr := CrossCorrelate(test,patternSearch)
// corr.ShowImage()
number mx,my,mv
mv = max(corr,mx,my)
mx -= trunc(sx/2)       // because we've placed the pattern in the 
my -= trunc(sy/2)       // top/left of the search-mask
if( mx <= 0 ) mx += sx;
Result("\n\n Pattern = " + px + " / " + py )
Result("\n max = " + mv + " at " + mx + "/" + my )

Answer 3

根据要求，这是一个剪辑，展示了如何在＆＃34; raw＆＃34;数据流。我没有声称下面的脚本是最快或最优雅的解决方案，它只是显示相应的命令如何工作。（您可以在在线F1帮助的＆＃34;文件输入和输出＆＃34; 部分中找到它们。）

这个想法＆＃39;我已经加入了它：只需在流中搜索搜索模式的最后一个值。只有在找到时，查看给定距离的起始值是否也匹配。仅在这种情况下，检查整个模式。对于 long 搜索模式，这应该是一种有用的方法，但对于非常短的搜索模式，它可能不是那么理想。

{
    number patternSize = 8
    number dataSize = 24000
    number patternPos = trunc( random() * ( dataSize - patternSize ) )

    number const = 200
    number dataTypeSizeByte  = 4
    number stream_byte_order = 0

    // Prepare test-Dummies
        image searchSet := IntegerImage( "search", dataTypeSizeByte, 0, patternSize )
        searchSet = const * sin( icol/iwidth *  Pi() )
        // searchSet.ShowImage()

        image dataSet := IntegerImage( "data", dataTypeSizeByte, 0, dataSize ) 
        dataSet = const * random() * 0.3
        dataSet.Slice1( patternPos, 0, 0, 0, patternSize, 1 ) = searchSet
        // dataSet.ShowImage()

    // Prepare Data as RawStream
        object buffer = NewMemoryBuffer( dataSize * dataTypeSizeByte )
        object stream = NewStreamFromBuffer(buffer)
        dataSet.ImageWriteImageDataToStream( stream, stream_byte_order )
        stream.StreamSetPos(0,0)

    // Prepare aux. Tags for streaming
        TagGroup tg = NewTagGroup();
        tg.TagGroupSetTagAsUInt32( "UInt32_0", 0 )

    // Prepare values to search for 
        number startValue = searchSet.GetPixel(0,0)
        number lastValue =  searchSet.GetPixel(patternSize-1,0)

    // search for the pattern
        // Search for the LAST value of the pattern only.
        // If found, check if the FIRST value in appropriated distance also matches
        // Only then compare whole pattern.

        number value
        number streamEndPos = stream.StreamGetSize() 
        number streamPos = (patternSize-1) * dataTypeSizeByte // we can skip the first few tests
        stream.StreamSetPos(0, streamPos )  
        while( streamPos < streamEndPos )
        {
            tg.TagGroupReadTagDataFromStream( "UInt32_0", stream, stream_byte_order )
            streamPos = stream.StreamGetPos()

            tg.TagGroupGetTagAsUInt32( "UInt32_0", value )  // use appropriate data type!
            if ( lastValue == value )
            {
                result("\n Pattern might end at: "+streamPos/dataTypeSizeByte)

                // shift to start-value (relative) to check first value!
                stream.StreamSetPos(1, -1 * patternSize * dataTypeSizeByte )    
                tg.TagGroupReadTagDataFromStream( "UInt32_0", stream, stream_byte_order )
                tg.TagGroupGetTagAsUInt32( "UInt32_0", value )  
                if ( startValue == value )
                {
                    result("\t (Start also fits!) " )

                    // Now check all of it!
                    stream.StreamSetPos(1, -1 * dataTypeSizeByte )  
                    image compTemp := IntegerImage( "SectionData", dataTypeSizeByte, 0, patternSize )
                    compTemp.ImageReadImageDataFromStream( stream, stream_byte_order )

                    if ( 0 == sum( abs(compTemp - searchSet) ) )
                    {
                        number foundPos = (stream.StreamGetPos()/dataTypeSizeByte - patternSize)
                        Result("\n Correct starting position: " + patternPos )
                        Result("\n Found starting position  : " + foundPos )
                        OKDialog( "Found subset at position : " + foundPos )
                        exit(0)
                    }       
                }
                stream.StreamSetPos(0, streamPos )  
            }   
    }
    OKDialog("Nothing found.")
}

查找模式图像（二进制文件）

3 个答案: