Question

我有一个关于从字符串开头删除零的问题。我用过

=trim(left(substitute(A1,"0"," "),3))

在string = '0060' PPC手机中我希望结果等于 60 。但是这个功能给了我6个。

并非所有记录都以双零开头。可以有一个，两个或三个零。

Answer 1

作为UDF（用户定义函数）

Function Strip0(r As Range) As Variant
    Dim i As Long
    Dim s As String
    s = CStr(r.Value)
    Do While Left$(s, 1) = "0"
        s = Mid$(s, 2)
    Loop
    Strip0 = s
End Function

Answer 2

代码越长，但在一系列值上快速运行（永久更改它们），而不是持续使用UDF。

使用变量数组和regexp来提高效率。

Sub KillLeadingZeroes()
    Dim rng1 As Range
    Dim rngArea As Range
    Dim lngRow As Long
    Dim lngCol As Long
    Dim lngCalc As Long
    Dim objReg As Object
    Dim X()


    On Error Resume Next
    Set rng1 = Application.InputBox("Select range for the replacement of leadoimg zeroes", "User select", Selection.Address, , , , , 8)
    If rng1 Is Nothing Then Exit Sub
    On Error GoTo 0

    'See Patrick Matthews excellent article on using Regular Expressions with VBA
    Set objReg = CreateObject("vbscript.regexp")
    objReg.Pattern = "^0+"
    objReg.Global = False

   'Speed up the code by turning off screenupdating and setting calculation to manual
   'Disable any code events that may occur when writing to cells
    With Application
        lngCalc = .Calculation
        .ScreenUpdating = False
        .Calculation = xlCalculationManual
        .EnableEvents = False
    End With

    'Test each area in the user selected range

    'Non contiguous range areas are common when using SpecialCells to define specific cell types to work on
    For Each rngArea In rng1.Areas
        'The most common outcome is used for the True outcome to optimise code speed
        If rngArea.Cells.Count > 1 Then
           'If there is more than once cell then set the variant array to the dimensions of the range area
           'Using Value2 provides a useful speed improvement over Value. On my testing it was 2% on blank cells, up to 10% on non-blanks
            X = rngArea.Value2
            For lngRow = 1 To rngArea.Rows.Count
                For lngCol = 1 To rngArea.Columns.Count
                    'replace the leading zeroes
                    X(lngRow, lngCol) = objReg.Replace(X(lngRow, lngCol), vbNullString)
                Next lngCol
            Next lngRow
            'Dump the updated array sans leading zeroes back over the initial range
            rngArea.Value2 = X
        Else
            'caters for a single cell range area. No variant array required
            rngArea.Value = objReg.Replace(rngArea.Value, vbNullString)
        End If
    Next rngArea

    'cleanup the Application settings
    With Application
        .ScreenUpdating = True
        .Calculation = lngCalc
        .EnableEvents = True
    End With

    Set objReg = Nothing
End Sub

Answer 3

如果空格始终跟在第一个数字后面，则以下内容应该有效：

=TEXT(LEFT(A1, FIND(" ", A1)), "#")

如果无法保证 space 条件，则需要UDF。

从字符串VBA或Function的开头删除零

3 个答案: