Question

我正在尝试创建一个包含两个FileChooserButtons的窗口。第一个应该帮助用户选择一个目录，因此我使用的是动作Select_folder;第二是允许用户选择文件。

问题是我希望第二个根据用户在第一个文件夹中做出的选择来更改当前文件夹。

我最初的想法是使用Signal.connect，如下所示：

Signal.connect(chooser1, "selection_changed", folder_changed, null)

然而，这让我得到以下编译错误：

exercise4_1.gs:62.55-62.68: error: Cannot create delegate without target for instance method or closure
        Signal.connect(chooser1, "selection_changed", folder_changed, null)
                                                      ^^^^^^^^^^^^^^
Compilation failed: 1 error(s), 0 warning(s)

我还尝试在vala邮件列表中根据此mail communication添加（回调）folder_changed，但无济于事。

这是整个代码：

[indent=4]

uses
    Gtk
    GLib

class TestWindow : Window
    chooser1:Gtk.FileChooserButton
    chooser2:Gtk.FileChooserButton
    construct()

        // General characteristics of the window
        title = "File chooser"
        window_position = WindowPosition.CENTER
        destroy.connect(Gtk.main_quit)
        chooser1 = new FileChooserButton(
                                            "Choose a Folder",
                                            FileChooserAction.SELECT_FOLDER
                                            )
        chooser2 = new FileChooserButton(
                                             "Chooser a Folder",
                                             FileChooserAction.OPEN
                                             )
        chooser1.set_current_folder(Environment.get_home_dir())
        chooser2.set_current_folder(Environment.get_home_dir())

        Signal.connect(chooser1, "selection_changed", folder_changed, null)

        var box = new Gtk.Box(Gtk.Orientation.VERTICAL, 0)
        box.pack_start(chooser1, true, true,0)
        box.pack_start(chooser2, true, true,0)
        add(box)


    def folder_changed()
        var folder = chooser1.get_filename()
        chooser2.set_current_folder(folder)


init
    Gtk.init (ref args)
    var test = new TestWindow ()
    test.show_all ()
    Gtk.main ()

我当然缺乏对这种特殊语法的理解，但由于我被卡住了，我会很感激指针让我脱离它。
作为一个额外的，不太重要的一点，最佳做法是什么：分割和缩进长行或在代码中允许它们？

Answer 1

Gtk的回调需要包含生成信号的对象的参数。 Genie和Vala也对GLib信号提供语法支持，使信号更易于使用。以下是基于您的代码的示例：

[indent=4]
uses
    Gtk

class TestWindow:Window
    _file_chooser:FileChooserButton

    construct()
        title = "File chooser"
        window_position = WindowPosition.CENTER
        destroy.connect( Gtk.main_quit )

        var folder_chooser = new FileChooserButton(
                                         "Choose a Folder",
                                         FileChooserAction.SELECT_FOLDER
                                        )
        folder_chooser.set_current_folder( Environment.get_home_dir() )
        folder_chooser.selection_changed.connect( folder_changed )

        _file_chooser = new FileChooserButton(
                                        "Chooser a File",
                                        FileChooserAction.OPEN
                                        )
        _file_chooser.set_current_folder( Environment.get_home_dir() )

        var box = new Box( Orientation.VERTICAL, 0 )
        box.pack_start( folder_chooser, true, true, 0 )
        box.pack_start( _file_chooser, true, true, 0 )
        add( box )

    def folder_changed( folder_chooser_widget:FileChooser )
        folder:string = folder_chooser_widget.get_uri()
        _file_chooser.set_current_folder_uri( folder )

init
    Gtk.init( ref args )
    var test = new TestWindow()
    test.show_all()
    Gtk.main()

需要注意几点：

信号名称"selection_changed"已成为folder_chooser的属性，然后您connect。 Vala编译器在编译时执行转换为GLib.Signal
FileChooserButton，folder_chooser已从班级范围中删除。现在可以通过作为参数传递给回调来访问它。因此它被定义为回调函数的参数
您会注意到回调的参数需要FileChooser类型而不是FileChooserButton类型。这是因为selection_changed信号是FileChooser接口的一部分，FileChooserButton然后实现。这有效地提供了FileChooserButton多种类型
虽然声明了_file_chooser，所以它在类的整个范围内都可用，但只能通过使用下划线在类中访问它

使用Signal.connect()更接近Gtk的C API。如果您需要这样做，那么以下工作将基于您的原始代码：

[indent=4]
uses
    Gtk

class TestWindow:Window
    chooser1:FileChooserButton
    chooser2:FileChooserButton
    construct()

        // General characteristics of the window
        title = "File chooser"
        window_position = WindowPosition.CENTER
        destroy.connect( Gtk.main_quit )
        chooser1 = new FileChooserButton(
                                         "Choose a Folder",
                                         FileChooserAction.SELECT_FOLDER
                                        )
        chooser2 = new FileChooserButton(
                                        "Chooser a Folder",
                                        FileChooserAction.OPEN
                                        )
        chooser1.set_current_folder( Environment.get_home_dir() )
        chooser2.set_current_folder( Environment.get_home_dir() )

        Signal.connect( 
                      chooser1, 
                      "selection_changed", 
                      (GLib.Callback)folder_changed,
                      self
                      )

        var box = new Box( Orientation.VERTICAL, 0 )
        box.pack_start( chooser1, true, true, 0 )
        box.pack_start( chooser2, true, true, 0 )
        add( box )

    [CCode( instance_pos = 2 )]
    // or [CCode( instance_pos = -1 )] to always be last
    def folder_changed( folder_chooser:Widget )
        folder:string = chooser1.get_uri()
        chooser2.set_current_folder_uri( folder )

init
    Gtk.init( ref args )
    var test = new TestWindow()
    test.show_all()
    Gtk.main()

需要注意几点：

是的，您确实需要将回调转发给GLib.Callback，就像您在链接到的邮件中找到的那样
您需要的实例数据是您为Window创建的FileChooserButton对象，因此将null更改为self可在此处使用
Vala会将实例数据作为第一个参数，因此要覆盖默认值，您必须使用CCode属性，在这种情况下为[CCode( instance_pos = 2 )]
生成信号的对象仍然是回调函数的第一个参数，因此即使在此示例中未使用它，它仍然在定义中。这被定义为Widget类型，但您可以将其更改为FileChooser以使用get_uri()调用

对于您的代码格式问题，我更喜欢拆分长行，如您所见。我不确定Genie还有一个商定的“最佳实践”。

signal.connect语法

1 个答案: