Question

我正在尝试开发一个操作系统。设计是这样的：我有一个加载在0x7c00的引导程序，它加载第二阶段并在0x7e00跳转到它。第二阶段也处于实模式并且执行许多操作，例如加载gdt，启用A20并切换到保护模式。它还在0x8000处加载一个非常简单的32位内核。现在的问题是我无法调用或jmp到0x8000，因为内核似乎没有加载（我在 VirtualBox 中进行了内存转储）。我已经在第二阶段完成了 FAR JMP 来设置 CS 寄存器。我正在 VirtualBox 中测试我的操作系统。

我的启动加载程序代码：

org 0x7c00
bits 16
Start:
      jmp Reset
      bpbOEM DB "SKULLOS " 
      bpbBytesPerSector:    DW 512
      bpbSectorsPerCluster:     DB 1
      bpbReservedSectors:   DW 1
      bpbNumberOfFATs:      DB 2
      bpbRootEntries:       DW 224
      bpbTotalSectors:      DW 2880
      bpbMedia:                 DB 0xF0
      bpbSectorsPerFAT:         DW 9
      bpbSectorsPerTrack:   DW 18
      bpbHeadsPerCylinder:  DW 2
      bpbHiddenSectors:         DD 0
      bpbTotalSectorsBig:     DD 0
      bsDriveNumber:            DB 0
      bsUnused:                 DB 0
      bsExtBootSignature:   DB 0x29
      bsSerialNumber:           DD 0xa0a1a2a3
      bsVolumeLabel:            DB "MOS FLOPPY "
      bsFileSystem:             DB "SKFS    "
Set:
      mov al , 02h
      mov ah , 00h
      int 10h
      jmp Print
Print:
      mov al , 'A'
      mov bl , 0Fh
      mov cx , 01h
      mov ah , 09h
      int 10h
      jmp Reset
Reset:
      ; mov dl , 0x00
        mov [0x500] , dl
        mov ah , 0x00
        int 0x13
        jc Reset
        mov ax , 0x7E0 
        mov es , ax
        xor bx , bx
        mov ah , 0x02
        mov al , 1
        mov ch , 0
        mov cl , 2
        mov dh , 0
        mov dl , [0x500]
        int 0x13
        jmp 0x0000 :0x7e00
        times 510-($-$$) db 0
        db 0x55
        db 0xAA

第二阶段的代码：

    org 0x7E00
    bits 16
    Start:
          jmp Setup
    ;;;;;;;;;;;;;stack;;;;;;;;;;
    Setup: 
          cli
          xor ax , ax
          mov ds , ax
          mov es , ax
          mov ax , 0x9000
          mov ss , ax
          mov sp , 0xFFFF
          sti
          jmp Set
   ;;;;;;;;;;;;;video;;;;;;;;;;;
   Set: 
          mov al , 03h
          mov ah , 00h
          int 10h
          mov ah , 09h
          mov al , 'A'
          mov bh , 00h
          mov bl , 0x0F
          mov cx , 01h
          int 10h
          jmp loadgdt
   ;;;;;;;;;;;;gdt;;;;;;;;;;;;;;;
   gdt_start:
   null: 
          dd 0
          dd 0
   code:
          dw 0FFFFh
          dw 0
          db 0
          db 10011010b
          db 11001111b
          db 0
   data:
          dw 0FFFFh
          dw 0
          db 0
          db 10010010b
          db 11001111b
          db 0
   end:
   load: dw end - gdt_start -1
         dd null
   ;;;;;;;;;;;;;loadgdt;;;;;;;;;;
   loadgdt:
         lgdt [load]
         jmp A20
   ;;;;;;;;;;;;A20;;;;;;;;;;;;;;;
   A20:
         mov ax , 0x2401
         int 0x15
         jc A20
         jmp Reset
   ;;;;;;;;;;;;;floppy;;;;;;;;;;;
   Reset:
         mov ah , 00h
         mov dl , [0x500]
         int 13h
         jc Reset
         jmp Read
   Read:
         mov ah , 02h
         mov al , 01h
         mov ch , 00h
         mov cl , 03h
         mov dh , 00h
         mov dl , [0x500]
         mov ax , 0x800
         mov es , ax
         xor bx , bx
         int 13h
         jc Read
         jmp Begin
   Begin:  
         mov ah , 09h
         mov al , 'G'
         mov bh , 00h
         mov bl , 0x0F
         mov cx , 01h
         int 10h
         jmp protected
   ;;;;;;;;;;;switching to protected;;;;
   protected: 
             mov ah , 09h
             mov al , 'P'
             mov bh , 00h
             mov bl , 0x0F
             mov cx , 01h
             int 10h
             xor ax, ax
             mov ds, ax    
             cli
             mov eax, cr0
             or eax , 1
             mov cr0 , eax
             jmp (code-gdt_start):transfer_control
   ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
   bits 32 
   transfer_control:
                    mov ax, (data-gdt_start)        
                    mov ds, ax
                    mov ss, ax
                    mov es, ax
                    mov esp, 90000h
                    mov [0xB8000], word 0x0F58  ; Print 'X' 
                    call 0x8000    
                    hlt
   ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
   times 512-($-$$) db 0

内核代码：

org 0x8000
bits 32
jmp Start
Start:
      mov ax , 0x10
      mov ds , ax
      mov ss, ax
      mov es, ax
      mov esp, 90000h
      mov [0xB8002], word 0x0F58   ; Print 'X'
      ret
times 512-($-$$) db 0

目前，只有一个＆＃39; X＆＃39;正在印刷。但是，两个＆＃39; X＆＃39;应该打印。用于创建软盘的命令：

      dd seek=0 if=boot of=os.img
      dd seek=1 if=second_stage of=os.img
      dd seek=2 if=third_stage of=os.img

Answer 1

阅读阶段3的问题

在第二阶段，你加载第三阶段：

   Read:
         mov ah , 02h      ; Setup AH
         mov al , 01h      ; Setup AL
         mov ch , 00h
         mov cl , 03h
         mov dh , 00h
         mov dl , [0x500]
         mov ax , 0x800    ; Destroy contents of AX 
         mov es , ax       ; Setup ES=0x800
         xor bx , bx
         int 13h

我已经标出了有问题的线条。您有效地设置 AX 以准备读取，然后使用0x800覆盖值以设置 ES 。在设置 AH 和 AL 之前，请先设置 ES 。将代码修改为：

   Read:
         mov ax , 0x800 
         mov es , ax       ; Setup ES=0x800
         mov ah , 02h      ; Setup AH
         mov al , 01h      ; Setup AL
         mov ch , 00h
         mov cl , 03h
         mov dh , 00h
         mov dl , [0x500]
         xor bx , bx
         int 13h

这可能会阻止您的第二阶段正确加载第三阶段。

其他问题

在引导程序的末尾，你有：

    db 0xAA
    db 0x55

这是倒退的，应该是：

    db 0x55
    db 0xAA

你可以把它写成：

    dw 0xAA55

问题似乎是在定义这些字节时没有考虑小的字节序。

您正确跳过引导加载程序中的BIOS参数块，但BPB需要从引导扇区的第4个字节开始。 jmp Reset指令只有3个字节长。您可以在跳转后放置nop，以便BPB从第4个字节开始。

变化：

  jmp Reset
  bpbOEM DB "SKULLOS "

要：

  jmp Reset
  nop         ; BPB needs to start at 4th byte (jmp instruction takes 3 bytes)
  bpbOEM DB "SKULLOS "

mov sp , 0xFFFF应该是mov sp, 0x0000。这只是一个小小的挑剔。将堆栈放在 WORD 边界（偶数地址）上可以在8086处理器上表现更好。由于你不是很长时间处于真实模式，所以根本不重要。通常你会在你的情况下使用mov sp, 0x0000，因为推送的第一个 WORD 将是0x9000：0xfffe，因为首先从SP中减去2，然后推送 WORD 到堆栈上。有效地，当SP = 0x0000时，堆栈将以包裹到64k段的顶部开始。

如果标签位于 JMP 之后，则不需要 JMP 从标签到标签。说明如下：

    jmp Set 
Set:

除了浪费空间并占用CPU周期之外什么都不做。我注意到你在很多地方都这样做了。这不是你问题的一部分，只是一个观察。 FAR JUMP jmp (code-gdt_start):transfer_control后跟标签很好，因为它用于正确设置CS描述符（对于保护模式）

使用int 13h进行磁盘访问时，您应该使用BIOS传递给引导加载程序的引导驱动器号作为 DL 的值。您的第一和第二阶段的代码如下：

mov dl , 00h

这总是假设您正在读取第一张软盘（ A：）。如果您想在软盘 A：以外的启动驱动器上使用您的代码，您将要删除此

无法跳转或调用在0x8000加载的内核

1 个答案:

阅读阶段3的问题

其他问题